How do I sample world space coordinate uv's in a custom material shader?

[speakk]

(Note: There is a similar thread, but that is for extended material which has some of this functionality built in, it seems.)

My intent is to have this material in use for my tiled meshes, but so that the texture flows from one tile to the next freely
(and yet seems to be "part of the world", so not screen space uv, but specifically world space uv).

So basically, sampling a texture based on the world space uv, projected onto the mesh uv.

[speakk]

Here is the solution that seems to work quite well:

#import bevy_pbr::{
    mesh_view_bindings::globals,
    mesh_bindings::mesh,
    mesh_functions,
    forward_io::{
        Vertex,
        VertexOutput,
    },
    view_transformations::position_world_to_clip,
}

@group(2) @binding(0) var<uniform> material_color: vec4<f32>;
@group(2) @binding(1) var noise_texture_1: texture_2d<f32>;
@group(2) @binding(2) var noise_sampler_1: sampler;

@vertex
fn vertex(vertex: Vertex) -> VertexOutput {
    var out: VertexOutput;
    var world_from_local = mesh_functions::get_world_from_local(vertex.instance_index);
    out.world_position = mesh_functions::mesh_position_local_to_world(world_from_local, vec4<f32>(vertex.position, 1.0));
    out.position = position_world_to_clip(out.world_position.xyz);
    out.uv = vertex.uv;
    return out;
}

@fragment
fn fragment(
    mesh: VertexOutput,
) -> @location(0) vec4<f32> {
    // Use world position's x and z axes for UVs
    let world_position = mesh.world_position;

    // Map x and z from world coordinates to UV range (0.0, 1.0)
    let uv_world_space = vec2<f32>(
        fract(world_position.x * 0.1), // Example scaling factor for tiling effect
        fract(world_position.z * 0.1)
    );

    // Sample the texture using world space UVs
    let texture_color = textureSample(noise_texture_1, noise_sampler_1, uv_world_space);

    // Return final color
    return material_color * texture_color;
}