Tweaked tree-sitter query classification

lib/linguist/heuristics.yml

@@ -748,21 +748,23 @@ disambiguations:
     pattern: '^#+\s+(NAME|SYNOPSIS|DESCRIPTION)'
 - extensions: ['.scm']
   rules:
-  - language: Scheme
-    pattern:
-    - '(?:''[\(\*#]|\w->\w|\.\.\.[\s\)]|\([+\-:<>\/=~\)]|~>|[#`]\(|#:\w)'
-    - '^\s*\((?:define\*?|import|library|lambda)'
-    negative_pattern:
-    - '\(#[\w-]+[!\?]'
-    - '[\)\]"_]\s*(?:[\*\+\?]|@\w)'
   - language: Tree-sitter Query
     pattern:
     - '\(#[\w-]+[!\?]'
-    - '[\)\]"_]\s*(?:[\*\+\?]|@\w)'
+    - '(?:[\)\]]\s*[\*\+\?](?:\s|$))'
     - '(?:^\s*\w+:\s*[\(\[\"])'
     - '\(#(?:set!|(?:not-)?(?:any-of|match)\?)'
+    - '@[\w.-]+(?:\)\s|$)'
     negative_pattern:
     - '\([+\-:<>\/=~\)]'
+  - language: Scheme
+    pattern:
+    - '(?:''[\(\*#]|\w->\w|\.\.\.[\s\)]|\([+\-:<>\/=~\)]|~>|[#`]\(|#:\w)'
+    - '^\s*\((?:define\*?|import|library|lambda)'
+    negative_pattern:
+    - '\(#[\w-]+[!\?]'
+    - '(?:[\)\]]\s*[\*\+\?](?:\s|$))'
+    - '@[\w.-]+(?:\)\s|$)'
 - extensions: ['.sol']
   rules:
   - language: Solidity

samples/Tree-sitter Query/asm_highlights.scm

@@ -0,0 +1,66 @@
+; General
+(label
+  [
+    (ident)
+    (word)
+  ] @label)
+
+(reg) @variable.builtin
+
+(meta
+  kind: (_) @function.builtin)
+
+(instruction
+  kind: (_) @function.builtin)
+
+(const
+  name: (word) @constant)
+
+; Comments
+[
+  (line_comment)
+  (block_comment)
+] @comment @spell
+
+; Literals
+(int) @number
+
+(float) @number.float
+
+(string) @string
+
+; Keywords
+[
+  "byte"
+  "word"
+  "dword"
+  "qword"
+  "ptr"
+  "rel"
+  "label"
+  "const"
+] @keyword
+
+; Operators & Punctuation
+[
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "|"
+  "^"
+  "&"
+] @operator
+
+[
+  "("
+  ")"
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ","
+  ":"
+] @punctuation.delimiter

samples/Tree-sitter Query/asm_injections.scm

@@ -0,0 +1,5 @@
+([
+  (line_comment)
+  (block_comment)
+] @injection.content
+  (#set! injection.language "comment"))

samples/Tree-sitter Query/func_highlights.scm

@@ -0,0 +1,167 @@
+; Include
+"#include" @keyword.import
+
+(include_path) @string
+
+; Preproc
+"#pragma" @keyword.directive
+
+(pragma_directive
+  [
+    "version"
+    "not-version"
+    "test-version-set"
+  ] @keyword.directive)
+
+; Keywords
+[
+  "asm"
+  "impure"
+  "inline"
+  "inline_ref"
+  "method_id"
+  "type"
+] @keyword
+
+"return" @keyword.return
+
+; Conditionals
+[
+  "if"
+  "ifnot"
+  "else"
+  "elseif"
+  "elseifnot"
+  "until"
+] @keyword.conditional
+
+; Exceptions
+[
+  "try"
+  "catch"
+] @keyword.exception
+
+; Repeats
+[
+  "do"
+  "forall"
+  "repeat"
+  "while"
+] @keyword.repeat
+
+; Qualifiers
+[
+  "const"
+  "global"
+  (var)
+] @keyword.modifier
+
+; Variables
+(identifier) @variable
+
+; Constants
+(const_var_declarations
+  name: (identifier) @constant)
+
+; Functions/Methods
+(function_definition
+  name: (function_name) @function)
+
+(function_application
+  function: (identifier) @function)
+
+(method_call
+  method_name: (identifier) @function.method.call)
+
+; Parameters
+(parameter) @variable.parameter
+
+; Types
+(type_identifier) @type
+
+(primitive_type) @type.builtin
+
+; Operators
+[
+  "="
+  "+="
+  "-="
+  "*="
+  "/="
+  "~/="
+  "^/="
+  "%="
+  "~%="
+  "^%="
+  "<<="
+  ">>="
+  "~>>="
+  "^>>="
+  "&="
+  "|="
+  "^="
+  "=="
+  "<"
+  ">"
+  "<="
+  ">="
+  "!="
+  "<=>"
+  "<<"
+  ">>"
+  "~>>"
+  "^>>"
+  "-"
+  "+"
+  "|"
+  "^"
+  "*"
+  "/"
+  "%"
+  "~/"
+  "^/"
+  "~%"
+  "^%"
+  "/%"
+  "&"
+  "~"
+] @operator
+
+; Literals
+[
+  (string)
+  (asm_instruction)
+] @string
+
+[
+  (string_type)
+  (underscore)
+] @character.special
+
+(number) @number
+
+; Punctuation
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "("
+  ")"
+  "()"
+] @punctuation.bracket
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ";"
+  ","
+  "->"
+] @punctuation.delimiter
+
+; Comments
+(comment) @comment @spell