Merge pull request #3065 from n8sh/issue-20767-20768

[DIP1014] __move_post_blt: recursively call on fields that are static arrays & do not recursively call on non-field members
merged-on-behalf-of: Nicholas Wilson <thewilsonator@users.noreply.github.com>

Author: dlang-bot

src/core/internal/moving.d

@@ -29,11 +29,12 @@ Note:
 void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
     if (is(S == struct))
 {
-    static foreach (memberName; __traits(allMembers, S))
+    import core.internal.traits : hasElaborateMove;
+    static foreach (i, M; typeof(S.tupleof))
     {
-        static if (is(typeof(__traits(getMember, S, memberName)) == struct))
+        static if (hasElaborateMove!M)
         {
-            __move_post_blt(__traits(getMember, newLocation, memberName), __traits(getMember, oldLocation, memberName));
+            __move_post_blt(newLocation.tupleof[i], oldLocation.tupleof[i]);
         }
     }
 
@@ -48,6 +49,17 @@ void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
     }
 }
 
+void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
+    if (__traits(isStaticArray, S))
+{
+    import core.internal.traits : hasElaborateMove;
+    static if (S.length && hasElaborateMove!(typeof(newLocation[0])))
+    {
+        foreach (i; 0 .. S.length)
+            __move_post_blt(newLocation[i], oldLocation[i]);
+    }
+}
+
 @safe nothrow unittest
 {
     struct A
@@ -87,3 +99,49 @@ void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
     __move_post_blt(dest, src);
     assert(dest.movedInto && dest.a.movedInto);
 }
+
+@safe nothrow unittest
+{
+    static struct DoNotMove
+    {
+        bool movedInto;
+        void opPostMove(const ref DoNotMove oldLocation)
+        {
+            movedInto = true;
+        }
+    }
+    static DoNotMove doNotMove;
+
+    struct A
+    {
+        @property ref DoNotMove member()
+        {
+            return doNotMove;
+        }
+    }
+    A src, dest;
+    __move_post_blt(dest, src);
+    assert(!doNotMove.movedInto);
+}
+
+@safe nothrow unittest
+{
+    static struct A
+    {
+        bool movedInto;
+        void opPostMove(const ref A oldLocation)
+        {
+            movedInto = true;
+        }
+    }
+    static struct B
+    {
+        A[2] a;
+    }
+    B src, dest;
+    __move_post_blt(dest, src);
+    foreach (ref a; src.a)
+        assert(!a.movedInto);
+    foreach (ref a; dest.a)
+        assert(a.movedInto);
+}