Fix Issue 20768 - __move_post_blt must recursively call itself on static arrays whose elements are structs or static arrays that recursively contain structs [DIP1014]

NB: this fix disregards DIP1014's advice to either not use hasElaborateMove!T
within __move_post_blt or to use it only once at the start of the function.

Author: n8sh

src/core/internal/moving.d

@@ -29,9 +29,10 @@ Note:
 void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
     if (is(S == struct))
 {
+    import core.internal.traits : hasElaborateMove;
     static foreach (i, M; typeof(S.tupleof))
     {
-        static if (is(M == struct))
+        static if (hasElaborateMove!M)
         {
             __move_post_blt(newLocation.tupleof[i], oldLocation.tupleof[i]);
         }
@@ -48,6 +49,17 @@ void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
     }
 }
 
+void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
+    if (__traits(isStaticArray, S))
+{
+    import core.internal.traits : hasElaborateMove;
+    static if (S.length && hasElaborateMove!(typeof(newLocation[0])))
+    {
+        foreach (i; 0 .. S.length)
+            __move_post_blt(newLocation[i], oldLocation[i]);
+    }
+}
+
 @safe nothrow unittest
 {
     struct A
@@ -111,3 +123,25 @@ void __move_post_blt(S)(ref S newLocation, ref S oldLocation) nothrow
     __move_post_blt(dest, src);
     assert(!doNotMove.movedInto);
 }
+
+@safe nothrow unittest
+{
+    static struct A
+    {
+        bool movedInto;
+        void opPostMove(const ref A oldLocation)
+        {
+            movedInto = true;
+        }
+    }
+    static struct B
+    {
+        A[2] a;
+    }
+    B src, dest;
+    __move_post_blt(dest, src);
+    foreach (ref a; src.a)
+        assert(!a.movedInto);
+    foreach (ref a; dest.a)
+        assert(a.movedInto);
+}