[Contract Verification][forge] Invalid or missing module name: invalid digit in in string

[nhtyy]

Team or Project

No response

ZK chain

Era

Environment

Mainnet

Block Explorer

ZKsync explorer (e.g. https://explorer.zksync.io)

Issue Type

• Plugin
• Block Explorer

Contract Address

0x8f588eb5EdBFE22e10e9421c8c5DF80F05460672

Compiler Type

Multi-part contract

zkSolc Version

zksolc-1.5.11

Solc Version

0.8.20

Contract Name

SP1VerifierGateway

Contract Code

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {ISP1Verifier, ISP1VerifierWithHash} from "./ISP1Verifier.sol";
import {ISP1VerifierGateway, VerifierRoute} from "./ISP1VerifierGateway.sol";
import {Ownable} from "../lib/openzeppelin-contracts/contracts/access/Ownable.sol";

/// @title SP1 Verifier Gateway
/// @author Succinct Labs
/// @notice This contract verifies proofs by routing to the correct verifier based on the verifier
/// selector contained in the first 4 bytes of the proof. It additionally checks that to see that
/// the verifier route is not frozen.
contract SP1VerifierGateway is ISP1VerifierGateway, Ownable {
    /// @inheritdoc ISP1VerifierGateway
    mapping(bytes4 => VerifierRoute) public routes;

    constructor(address initialOwner) Ownable(initialOwner) {}

    /// @inheritdoc ISP1Verifier
    function verifyProof(
        bytes32 programVKey,
        bytes calldata publicValues,
        bytes calldata proofBytes
    ) external view {
        bytes4 selector = bytes4(proofBytes[:4]);
        VerifierRoute memory route = routes[selector];
        if (route.verifier == address(0)) {
            revert RouteNotFound(selector);
        } else if (route.frozen) {
            revert RouteIsFrozen(selector);
        }

        ISP1Verifier(route.verifier).verifyProof(programVKey, publicValues, proofBytes);
    }

    /// @inheritdoc ISP1VerifierGateway
    function addRoute(address verifier) external onlyOwner {
        bytes4 selector = bytes4(ISP1VerifierWithHash(verifier).VERIFIER_HASH());
        if (selector == bytes4(0)) {
            revert SelectorCannotBeZero();
        }

        VerifierRoute storage route = routes[selector];
        if (route.verifier != address(0)) {
            revert RouteAlreadyExists(route.verifier);
        }

        route.verifier = verifier;

        emit RouteAdded(selector, verifier);
    }

    /// @inheritdoc ISP1VerifierGateway
    function freezeRoute(bytes4 selector) external onlyOwner {
        VerifierRoute storage route = routes[selector];
        if (route.verifier == address(0)) {
            revert RouteNotFound(selector);
        }
        if (route.frozen) {
            revert RouteIsFrozen(selector);
        }

        route.frozen = true;

        emit RouteFrozen(selector, route.verifier);
    }
}

Constructor Arguments

an address

Hardhat Verify Plugin Version

No response

Repo Link (Optional)

https://github.com/succinctlabs/sp1-contracts/tree/main

Additional Details

When deploying to Era, I see this error

 Failed to parse verification ID: {"status":"0","message":"NOTOK","result":"Error! Missing Or invalid Module name"} - error: invalid digit found in string; waiting 5 seconds before trying again (0 tries remaining)

Tried to remove the digits from the path and contract name but it didnt work!

Command:

CHAINS=ZKSYNC forge script script/deploy/SP1VerifierGatewayPlonk.s.sol --verify --verifier zksync --verifier-url $ERA_SCAN_URL_ZKSYNC --broadcast --zksync --private-key=$PRIVATE_KEY --sender ... --fork-url $RPC_ZKSYNC

[nhtyy]

This seems like an issue using the wrong path?

I have tried
https://explorer.zksync.io/api & https://explorer.zksync.io/contract_verification

[MexicanAce]

@nhtyy The verifier url should be https://zksync2-mainnet-explorer.zksync.io/contract_verification for mainnet

[nhtyy]

Could you also provide the Sepolia url please.

[uF4No]

• Sepolia contract verification URL: https://explorer.sepolia.era.zksync.dev/contract_verification
• Mainnet contract verification URL: https://zksync2-mainnet-explorer.zksync.io/contract_verification