zinit is not loading all the files for an OMZ plugin (OMZP::gitfast)

[fchastanet]

Hello,

thanks a lot for this tool

I'm trying to install this Omz plugin

zinit lucid depth=1 for \
  wait \
    OMZP::gitfast

But it ends with this error
/home/wsl/.local/share/zinit/snippets/OMZP::gitfast/OMZP::gitfast:source:6: no such file or directory: /home/wsl/.local/share/zinit/snippets/OMZP::gitfast/git-prompt.sh

When I check the content of the folder /home/wsl/.local/share/zinit/snippets/OMZP::gitfast

content of /home/wsl/.local/share/zinit/snippets/OMZP::gitfast/OMZP::gitfast is

# Handle $0 according to the standard:
# https://zdharma-continuum.github.io/Zsh-100-Commits-Club/Zsh-Plugin-Standard.html
0="${ZERO:-${${0:#$ZSH_ARGZERO}:-${(%):-%N}}}"
0="${${(M)0:#/*}:-$PWD/$0}"

source "${0:A:h}/git-prompt.sh"

function git_prompt_info() {
  dirty="$(parse_git_dirty)"
  __git_ps1 "${ZSH_THEME_GIT_PROMPT_PREFIX//\%/%%}%s${dirty//\%/%%}${ZSH_THEME_GIT_PROMPT_SUFFIX//\%/%%}"
}

not all the files have been downloaded from https://github.com/ohmyzsh/ohmyzsh/tree/master/plugins/gitfast by zinit

what am I missing ?

[repkid]

See #504 for more info, but basically Github has discontinued support for git-svn which was used to clone contents of a specific folder. Yesterday I made the following workaround for this issue (only works for OMZ plugins, prezto support should be easy to add though).

Place the following snippet before the zinit calls in .zshrc:

setopt RE_MATCH_PCRE   # _fix-omz-plugin function uses this regex style

# Workaround for zinit issue#504: remove subversion dependency. Function clones all files in plugin
# directory (on github) that might be useful to zinit snippet directory. Should only be invoked
# via zinit atclone"_fix-omz-plugin"
_fix-omz-plugin() {
  if [[ ! -f ._zinit/teleid ]] then return 0; fi
  if [[ ! $(cat ._zinit/teleid) =~ "^OMZP::.*" ]] then return 0; fi
  local OMZP_NAME=$(cat ._zinit/teleid | sed -n 's/OMZP:://p')
  git clone --quiet --no-checkout --depth=1 --filter=tree:0 https://github.com/ohmyzsh/ohmyzsh
  cd ohmyzsh
  git sparse-checkout set --no-cone plugins/$OMZP_NAME
  git checkout --quiet
  cd ..
  local OMZP_PATH="ohmyzsh/plugins/$OMZP_NAME"
  local file
  for file in $(ls -a ohmyzsh/plugins/$OMZP_NAME); do
    if [[ $file == '.' ]] then continue; fi
    if [[ $file == '..' ]] then continue; fi
    if [[ $file == '.gitignore' ]] then continue; fi
    if [[ $file == 'README.md' ]] then continue; fi
    if [[ $file == "$OMZP_NAME.plugin.zsh" ]] then continue; fi
    cp $OMZP_PATH/$file $file
  done
  rm -rf ohmyzsh
}

Each zinit call with OMZP should then be prefaced with atclone"_fix-omz-plugin" resulting in the following for me:

zinit wait lucid for \
  atinit"ZINIT[COMPINIT_OPTS]=-C; zicompinit; zicdreplay" \
    zdharma-continuum/fast-syntax-highlighting \
  atclone"_fix-omz-plugin" \
    OMZP::colored-man-pages \
  atclone"_fix-omz-plugin" \
    OMZP::vscode \
  atclone"_fix-omz-plugin" \
    OMZP::aliases \
  blockf \
    zsh-users/zsh-completions \
  atload"!_zsh_autosuggest_start" \
    zsh-users/zsh-autosuggestions

To make this work when the plugin has already been enabled before applying this fix (and thus downloaded into ~/.local/share/zinit/snippets/) the snippet folder needs to be deleted so that it's cloned again.

[bezhermoso]

@repkid I've also since updated it to remove the ifs, its just Zsh's globbing patterns (man zshexpn)

[repkid]

@bezhermoso Thanks for the pointers, I've only recently switched to zsh and am still learning the syntax. Fish had better documentation even if it's a lot simpler.

[dievilz]

For future reference and to summarize the corrections on this thread, the final version would be:

setopt RE_MATCH_PCRE   # _fix-omz-plugin function uses this regex style

# Workaround for zinit issue#504: remove subversion dependency. Function clones all files in plugin
# directory (on github) that might be useful to zinit snippet directory. Should only be invoked
# via zinit atclone"_fix-omz-plugin"
_fix-omz-plugin() {
  if [[ ! -f ._zinit/teleid ]] then return 0; fi
  if [[ ! $(cat ._zinit/teleid) =~ "^OMZP::.*" ]] then return 0; fi
  local OMZP_NAME=$(cat ._zinit/teleid | sed -n 's/OMZP:://p')
  git clone --quiet --no-checkout --depth=1 --filter=tree:0 https://github.com/ohmyzsh/ohmyzsh
  cd ohmyzsh
  git sparse-checkout set --no-cone plugins/$OMZP_NAME
  git checkout --quiet
  cd ..
  local OMZP_PATH="ohmyzsh/plugins/$OMZP_NAME"
  local file
  for file in ohmyzsh/plugins/$OMZP_NAME/*~(.gitignore|*.plugin.zsh)(D); do
    local filename="${file:t}"
    echo "Copying $file to $(pwd)/$filename..."
    cp $file $filename
  done
  rm -rf ohmyzsh
}

zinit wait lucid for \
  atinit"ZINIT[COMPINIT_OPTS]=-C; zicompinit; zicdreplay" \
    zdharma-continuum/fast-syntax-highlighting \
  atpull"%atclone" atclone"_fix-omz-plugin" \
    OMZP::colored-man-pages \
  atpull"%atclone" atclone"_fix-omz-plugin" \
    OMZP::vscode \
  atpull"%atclone" atclone"_fix-omz-plugin" \
    OMZP::aliases \
  blockf \
    zsh-users/zsh-completions \
  atload"!_zsh_autosuggest_start" \
    zsh-users/zsh-autosuggestions

[dievilz]

Also, I tried this workaround and it totally worked just for the 'wd' OMZ plugin!!!!!!!!

I copy-pasted the function, then I modified the zinit wait lucid blablabla statement with the workaround:

zinit wait lucid light-mode for \
	     OMZP::alias-finder \
	     OMZP::command-not-found \
	     OMZP::composer \
	     OMZP::extract \
	     OMZP::git-auto-fetch \
	     OMZP::git-flow-avh \
	  \
	  if'[[ $(uname -s) == "Darwin" ]]' \
	     OMZP::macos \
		  if'if [[ -d "$(find $ZINIT_SNIPPETS_DIR -maxdepth 1 -name "*macos" -type d)/" ]]; then [[ ! -e "$(find $ZINIT_SNIPPETS_DIR -maxdepth 1 -name "*macos" -type d)/music" ]] && curl -fSL -o "$(find $ZINIT_SNIPPETS_DIR -maxdepth 1 -name "*macos" -type d)/music" "https://raw.githubusercontent.com/ohmyzsh/ohmyzsh/master/plugins/macos/music"; fi' \
		  if'if [[ -d "$(find $ZINIT_SNIPPETS_DIR -maxdepth 1 -name "*macos" -type d)/" ]]; then [[ ! -e "$(find $ZINIT_SNIPPETS_DIR -maxdepth 1 -name "*macos" -type d)/spotify" ]] && curl -fSL -o "$(find $ZINIT_SNIPPETS_DIR -maxdepth 1 -name "*macos" -type d)/spotify" "https://raw.githubusercontent.com/ohmyzsh/ohmyzsh/master/plugins/macos/spotify"; fi' \
	     OMZP::pyenv \
	  atpull"%atclone" atclone"_fix-omz-plugin" \
	     OMZP::wd \
	     zsh-users/zsh-history-substring-search \
	     sei40kr/zsh-fast-alias-tips \
	  \
	  as'completion' \
	     OMZP::docker/completions/_docker \
	  \
	  from'gh-r' as'program' \
	     sei40kr/fast-alias-tips-bin \
	  \
	  atinit'ZINIT[COMPINIT_OPTS]=-C; zicompinit; zicdreplay' \
	     zdharma-continuum/fast-syntax-highlighting \
	  \
	  atload'!_zsh_autosuggest_start' \
	     zsh-users/zsh-autosuggestions \
	  \
	  atpull'zinit creinstall -q .' blockf  \
	     zsh-users/zsh-completions \

[5A6F65]

I have optimized the syntax of _fix-omz-plugin to make it more zsh, no more calls to non-essential external directives (cat, sed, ls) to improve function performance, and it no longer depends on RE_MATCH_PCRE.
Now, in addition to OMZP::xxxx, it also supports OMZ::plugins/xxxx.
I have added a prompt at the beginning (Fixing OMZP::xxxx or OMZ::plugins/xxxx).

_fix-omz-plugin() {
    [[ -f ./._zinit/teleid ]] || return 1
    local teleid="$(<./._zinit/teleid)"
    local pluginid
    for pluginid (${teleid#OMZ::plugins/} ${teleid#OMZP::}) {
        [[ $pluginid != $teleid ]] && break
    }
    (($?)) && return 1
    print "Fixing $teleid..."
    git clone --quiet --no-checkout --depth=1 --filter=tree:0 https://github.com/ohmyzsh/ohmyzsh
    cd ./ohmyzsh
    git sparse-checkout set --no-cone /plugins/$pluginid
    git checkout --quiet
    cd ..
    local file
    for file (./ohmyzsh/plugins/$pluginid/*~(.gitignore|*.plugin.zsh)(D)) {
        print "Copying ${file:t}..."
        cp -R $file ./${file:t}
    }
    rm -rf ./ohmyzsh
}

Usage is exactly the same as above, but I personally prefer using it in the following way:

zinit wait lucid atpull"%atclone" atclone"_fix-omz-plugin" for OMZ::plugins/{extract,sudo}