Fix src_root and src_location tests (#164)

Author: tsayukov

util/CMakeLists.txt

@@ -701,10 +701,73 @@ elseif (WIN32 AND CMAKE_SYSTEM_PROCESSOR STREQUAL "AMD64")
   )
 endif()
 
+#[=============================================================================[
+  Since in certain circumstances the __FILE__ macro expands to a relative path,
+  some internal macros that trims the source or binary prefix of the file path
+  may not work properly, if we pass these prefixes as absolute paths via
+  ARCADIA_ROOT and ARCADIA_BUILD_ROOT. This function deduces the proper arcadia
+  root paths, either relative or absolute, and put them in the cached variables
+  ARCADIA_ROOT and ARCADIA_BUILD_ROOT.
+#]=============================================================================]
+function(deduce_arcadia_roots)
+  if (DEFINED CACHE{ARCADIA_ROOT} AND DEFINED CACHE{ARCADIA_BUILD_ROOT})
+    return()
+  endif()
+
+  set(helperDir "${YDB_SDK_BINARY_DIR}/arcadia_roots_helper")
+  set(sourceFile "arcadia_roots_helper.cpp")
+  set(cxxSrcFilePath "${helperDir}/src_cxx_file_path.txt")
+  set(cxxBinFilePath "${helperDir}/bin_cxx_file_path.txt")
+
+  if (NOT EXISTS "${helperDir}/${sourceFile}")
+    set(sourceContent
+[=[
+#include <fstream>
+int main() {
+    std::ofstream file("@cxxFilePath@");
+    file << __FILE__;
+}
+]=]
+    )
+    file(WRITE "${helperDir}/${sourceFile}" "${sourceContent}")
+  endif()
+
+  foreach (varList
+    "${cxxSrcFilePath};${YDB_SDK_SOURCE_DIR};ARCADIA_ROOT"
+    "${cxxBinFilePath};${YDB_SDK_BINARY_DIR};ARCADIA_BUILD_ROOT"
+  )
+    list(GET varList 0 cxxFilePath)
+    list(GET varList 1 sourceDir)
+    list(GET varList 2 arcadiaCacheVariableName)
+
+    configure_file(
+      "${helperDir}/${sourceFile}"
+      "${sourceDir}/${sourceFile}"
+      @ONLY
+    )
+
+    try_run(runResultVar compileResultVar
+      "${helperDir}/build" "${sourceDir}/${sourceFile}"
+    )
+    if ((NOT runResultVar EQUAL "0") OR NOT compileResultVar)
+      message(FATAL_ERROR "Deducing ${arcadiaCacheVariableName} failed.")
+    endif()
+
+    file(READ "${cxxFilePath}" cxxFilePathContent)
+    file(TO_CMAKE_PATH "${cxxFilePathContent}" cxxFilePathContent)
+    get_filename_component(rootDir "${cxxFilePathContent}" DIRECTORY)
+    set(${arcadiaCacheVariableName} "${rootDir}" CACHE INTERNAL "")
+
+    file(REMOVE "${sourceDir}/${sourceFile}")
+  endforeach()
+endfunction()
+
+deduce_arcadia_roots()
+
 # These definitions are needed to `util/system/src_root.h` works properly
 target_compile_definitions(yutil PUBLIC
-  ARCADIA_ROOT=${YDB_SDK_SOURCE_DIR}
-  ARCADIA_BUILD_ROOT=${YDB_SDK_BINARY_DIR}
+  ARCADIA_ROOT=${ARCADIA_ROOT}
+  ARCADIA_BUILD_ROOT=${ARCADIA_BUILD_ROOT}
 )
 
 _ydb_sdk_install_targets(TARGETS yutil)