一种获取 CMake 信息的方法

[SineStriker]

看了一下这个文件：xmake/modules/package/manager/cmake/find_package.lua
注意到目前 xmake 是直接手撕 vcproj 来获取目标的信息的，这样通用性差，而且容易出问题。

我想了一种结合 CMake 和 ninja 的方式：

假设我们要获取一个 C++ 库 QWindowKit 的信息，首先准备下面几个文件：

1. main.cpp

#include <stdio.h>

int main(int argc, char *argv[]) {
    printf("Hello, World!\n");
    return 0;
}

2. main-info.json.in：

{
    "includedirs": "${INFO_INCLUDE_DIRS}",
    "linkdirs": "${INFO_LINK_DIRS}",
    "defines": "${INFO_COMPILE_DEFINITIONS}",
    "flags": "${INFO_COMPILE_OPTIONS}",
    "ldflags": "${INFO_LINK_OPTIONS}",
    "links": "${INFO_LINK_LIBRARIES}"
}

3. CMakeLists.txt

cmake_minimum_required(VERSION 3.15)

project(main)

# Prevent CMake from adding extra flags
set(CMAKE_C_FLAGS "")
set(CMAKE_C_FLAGS_DEBUG "")
set(CMAKE_C_FLAGS_RELEASE "")

set(CMAKE_CXX_FLAGS "")
set(CMAKE_CXX_FLAGS_DEBUG "")
set(CMAKE_CXX_FLAGS_RELEASE "")
set(CMAKE_CXX_FLAGS_INIT "")
set(CMAKE_CXX_FLAGS_DEBUG_INIT "")
set(CMAKE_CXX_FLAGS_RELEASE_INIT "")

set(CMAKE_EXE_LINKER_FLAGS "")
set(CMAKE_EXE_LINKER_FLAGS_DEBUG "")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "")
set(CMAKE_EXE_LINKER_FLAGS_INIT "")
set(CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT "")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE_INIT "")

if(MSVC)
    set(CMAKE_MSVC_RUNTIME_LIBRARY "")
endif()

if(WIN32)
    # https://github.com/Kitware/CMake/blob/e66e0b2cfefaf61fa995a0aa117df31e680b1c7e/Source/cmLocalGenerator.cxx#L1604
    # https://github.com/Kitware/CMake/blob/e66e0b2cfefaf61fa995a0aa117df31e680b1c7e/Modules/Platform/Windows-MSVC.cmake#L404
    set(CMAKE_CXX_CREATE_WIN32_EXE "")
    set(CMAKE_CXX_CREATE_CONSOLE_EXE "")
endif()

# Find package
find_package(QWindowKit CONFIG REQUIRED COMPONENTS Core Widgets Quick)

# Add target
add_executable(${PROJECT_NAME} main.cpp)

# Link libraries
target_link_libraries(${PROJECT_NAME} PRIVATE QWindowKit::Core)

# Generate information
set(INFO_INCLUDE_DIRS $<TARGET_PROPERTY:${PROJECT_NAME},INCLUDE_DIRECTORIES>)
set(INFO_LINK_DIRS $<TARGET_PROPERTY:${PROJECT_NAME},LINK_DIRECTORIES>)
set(INFO_COMPILE_DEFINITIONS $<TARGET_PROPERTY:${PROJECT_NAME},COMPILE_DEFINITIONS>)
set(INFO_COMPILE_OPTIONS $<TARGET_PROPERTY:${PROJECT_NAME},COMPILE_OPTIONS>)
set(INFO_LINK_OPTIONS $<TARGET_PROPERTY:${PROJECT_NAME},LINK_OPTIONS>)
set(INFO_LINK_LIBRARIES $<TARGET_PROPERTY:${PROJECT_NAME},LINK_LIBRARIES>)

configure_file("main-info.json.in" "${CMAKE_BINARY_DIR}/main-info.json.tmp")
file(GENERATE OUTPUT "${CMAKE_BINARY_DIR}/main-info.json" INPUT "${CMAKE_BINARY_DIR}/main-info.json.tmp")

执行命令：

cmake --no-warn-unused-cli -B build -G Ninja \
    -DCMAKE_BUILD_TYPE:STRING=Debug \
    -DQT_DIR:STRING=C:/Qt/5.15.2/msvc2019_64/lib/cmake/Qt5 \
    -DQt5_DIR:STRING=C:/Qt/5.15.2/msvc2019_64/lib/cmake/Qt5 \ 
    -DQWindowKit_DIR:STRING=C:/qwindowkit/build/install/lib/cmake/QWindowKit \
    -DCMAKE_EXPORT_COMPILE_COMMANDS:BOOL=TRUE

等待 CMake Configure 完成后，build 目录会生成build.ninja和main-info.json。

1. main-info.json

{
    "includedirs": "C:/qwindowkit/build/install/include/QWindowKit;C:/Qt/5.15.2/msvc2019_64/include/;C:/Qt/5.15.2/msvc2019_64/include/QtCore;C:/Qt/5.15.2/msvc2019_64/.//mkspecs/win32-msvc;C:/Qt/5.15.2/msvc2019_64/include/;C:/Qt/5.15.2/msvc2019_64/include/QtGui;C:/Qt/5.15.2/msvc2019_64/include//QtANGLE",
    "linkdirs": "",
    "defines": "QWK_CORE_STATIC;QT_CORE_LIB;QT_GUI_LIB",
    "flags": "",
    "ldflags": "",
    "links": "QWindowKit::Core;Qt5::Core"
}

2. build.ninja

# ...

#############################################
# Order-only phony target for main

build cmake_object_order_depends_target_main: phony || .

build CMakeFiles\main.dir\main.cpp.obj: CXX_COMPILER__main_unscanned_Debug C$:\Users\truef\Documents\GitHub\xmake-learning\extract-cmake\main.cpp || cmake_object_order_depends_target_main
  DEFINES = -DQT_CORE_LIB -DQT_GUI_LIB -DQWK_CORE_STATIC
  FLAGS = -std:c++17 -MDd
  INCLUDES = -external:IC:\Users\truef\Documents\GitHub\qwindowkit\build\install\include\QWindowKit -external:IC:\Qt\5.15.2\msvc2019_64\include -external:IC:\Qt\5.15.2\msvc2019_64\include\QtCore -external:IC:\Qt\5.15.2\msvc2019_64\.\mkspecs\win32-msvc -external:IC:\Qt\5.15.2\msvc2019_64\include\QtGui -external:IC:\Qt\5.15.2\msvc2019_64\include\QtANGLE -external:W0
  OBJECT_DIR = CMakeFiles\main.dir
  OBJECT_FILE_DIR = CMakeFiles\main.dir
  TARGET_COMPILE_PDB = CMakeFiles\main.dir\
  TARGET_PDB = main.pdb


#############################################
# Link the executable main.exe

build main.exe: CXX_EXECUTABLE_LINKER__main_Debug CMakeFiles\main.dir\main.cpp.obj | C$:\Users\truef\Documents\GitHub\qwindowkit\build\install\lib\QWKCored.lib C$:\Qt\5.15.2\msvc2019_64\lib\Qt5Guid.lib C$:\Qt\5.15.2\msvc2019_64\lib\Qt5Cored.lib
  FLAGS = -MDd
  LINK_FLAGS = /subsystem:console
  LINK_LIBRARIES = C:\Users\truef\Documents\GitHub\qwindowkit\build\install\lib\QWKCored.lib  uxtheme.lib  C:\Qt\5.15.2\msvc2019_64\lib\Qt5Guid.lib  C:\Qt\5.15.2\msvc2019_64\lib\Qt5Cored.lib  kernel32.lib user32.lib gdi32.lib winspool.lib shell32.lib ole32.lib oleaut32.lib uuid.lib comdlg32.lib advapi32.lib
  OBJECT_DIR = CMakeFiles\main.dir
  POST_BUILD = cd .
  PRE_LINK = cd .
  TARGET_COMPILE_PDB = CMakeFiles\main.dir\
  TARGET_FILE = main.exe
  TARGET_IMPLIB = main.lib
  TARGET_PDB = main.pdb

# ...

下面需要结合 CMake 输出的信息和 Ninja 中的信息来综合筛选。

• includedirs, linkdirs, defines: main-info.json里应该是完整的
• links: 从main-info.json里是获取不到完整的依赖库列表的的，因为里面可能包含 CMake 目标名字而不是路径，但是从build.ninja的LINK_LIBRARIES里可以获取到。
• flags, ldflags: main-info.json里很有可能包含无法解析的生成表达式，所以需要看build.ninja的FLAGS和LINK_FLAGS

提取顺序：

1. 如果main-info.json里获取到的信息完全不包含生成表达式（$<CONFIG>这种），那么就直接用
2. 如果包含生成表达式，那么从build.ninja里获取

这样，获取到的信息大概率是精确的，除了会多一些可能没必要链接的系统库。

注意事项：

• 执行 CMake 时要选 Ninja 作为生成器，最好手动传入CMAKE_CXX_COMPILER这样的工具链信息。
• 对于 flags 和 ldflags 来说，即使我们在CMakeLists.txt中禁用了CMAKE_CXX_FLAGS这些变量，CMake 还是会自作主张加一些参数，比如/subsystem:console、/MDd这种，这种只能看平台相关的 CMake Module，然后提前把相关的变量禁用掉。

---

还有一些其他问题，可能 xmake 没考虑周全。比如，不是所有的库都能通过find_package(XXX CONFIG REQUIRED)直接查找的，比如 Qt 就需要查找两次，而且带上模块名。

find_package(QT NAMES Qt6 Qt5 COMPONENTS Core Gui Widgets)
find_package(Qt${QT_VERSION_MAJOR} COMPONENTS Core Gui Widgets)

[waruqi]

你可以提 pr 过来改进下

[SineStriker]

我有空搞一下

[waruqi]

不过产生 build.ninja 还得额外安装 ninja ，有局限的，find_package 阶段，是没法自动帮用户装这些，只能依赖用户提前安装。

[waruqi]

所以find_package阶段使用的 cmake 也必须是用户自己装的吗？

对

[waruqi]

所以 除非必要，建议直接用 xmake-repo 包，走 cmake::xxx 不推荐，不太可靠，而且繁琐

[SineStriker]

所以 除非必要，建议直接用 xmake-repo 包，走 cmake::xxx 不推荐，不太可靠，而且繁琐

主要是我发现 xmake-repo 里包装的原本的 cmake 库，里面的内容也是有问题的。原 CMake 库定义了哪些宏，其实都在它的 XXXConfig.cmake 里面写着，但 xmake-repo 的包描述却要手动把各种条件加进去，这样显得麻烦又容易出问题。我发现 xmake-repo 里包装的我的库的宏也是有问题的。。。

所以我觉得必须走cmake::xxx把这些信息给 dump 出来，只有 CMake 自己告诉你的才是准的。

[SineStriker]

但也不是完全没办法，反正也只是找库，不实际编译，可以直接生成 c code，临时编译个 ninja 的空壳，骗过 cmake 的检测就行了

#include <stdio.h>

int main(int argc, char *argv[]) {
    printf("1.10.2\n");
    return 0;
}

试了一下这样就能骗过去。

[star-hengxing]

所以 除非必要，建议直接用 xmake-repo 包，走 cmake::xxx 不推荐，不太可靠，而且繁琐

主要是我发现 xmake-repo 里包装的原本的 cmake 库，里面的内容也是有问题的。原 CMake 库定义了哪些宏，其实都在它的 XXXConfig.cmake 里面写着，但 xmake-repo 的包描述却要手动把各种条件加进去，这样显得麻烦又容易出问题。我发现 xmake-repo 里包装的我的库的宏也是有问题的。。。

所以我觉得必须走cmake::xxx把这些信息给 dump 出来，只有 CMake 自己告诉你的才是准的。

cmake 不早点支持 cps（Common Package Specification） 是这样的，而且 cmake config 文件也要看作者写得对不对，比如说，没几个库是能正确处理级联依赖的（所以 conan 的做法是 config 文件全都自己生成，当然信息还是要手动填）