Saving uploaded multipart file to a temporary location functional.

Author: sagrawal31

README.md

@@ -0,0 +1,3 @@
+# Multi File Upload
+
+A plugin for multi purpose file upload functionality.

grails-app/controllers/com/wizpanda/file/UploadController.groovy

@@ -0,0 +1,62 @@
+package com.wizpanda.file
+
+import grails.util.Holders
+
+/**
+ * Endpoint for uploading file(s) to a temporary location. Used for AJAX based file upload.
+ *
+ * @author Shashank Agrawal
+ * @since 0.0.1
+ */
+class UploadController {
+
+    static allowedMethods = [index: "POST"]
+    static responseFormats = ["json"]
+    static scope = "singleton"
+
+    FileUploadService fileUploadService
+
+    /**
+     * This endpoint accepts the file in binary form, uploaded by the AJAX based application.
+     *
+     * @example
+     *
+     * When single file is uploaded:
+     * <pre>
+     *      params.file = (a single CommonsMultipartFile)
+     * </pre>
+     *
+     * Then, the response should be:
+     * <pre>
+     *      {
+     *          filepath: "./temp/my-avatar.png",
+     *          filename: "my-avatar.png"
+     *      }
+     * </pre>
+     *
+     * Note: By default this endpoint is blocked to allow upload. You need to set following to your config in order
+     * to allow uploading files using this endpoint:
+     *
+     * <pre>
+     *     wizpanda.plugins.kernel.allow.file.upload = true
+     * </pre>
+     *
+     * This is done because if you install this plugin and forget to protect this endpoint then someone may bloat
+     * your server by uploading junk files.
+     */
+    def index() {
+        if (!Holders.getFlatConfig()["wizpanda.plugins.kernel.allow.file.upload"]) {
+            log.warn "App is not allowing to upload files"
+            return
+        }
+
+        log.debug "Temporary upload with $params"
+
+        File file = fileUploadService.saveUploadedFile(params.file)
+        Map result = [filepath: file.getPath(), filename: file.getName()]
+
+        // Work around for IE
+        response.contentType = "text/plain"
+        respond(result)
+    }
+}

grails-app/services/com/wizpanda/file/FileUploadService.groovy

@@ -0,0 +1,72 @@
+package com.wizpanda.file
+
+import org.springframework.context.MessageSource
+import org.springframework.web.multipart.commons.CommonsMultipartFile
+
+import java.nio.file.Files
+
+class FileUploadService {
+
+    MessageSource messageSource
+
+    /**
+     * Save the uploaded multipart file to a temporary location.
+     *
+     * @param multipartFile
+     * @return Saved file with a metaclass method "getOriginalFilename" to get the actual uploaded file name
+     * @throws FileNotFoundException
+     * @throws IOException
+     */
+    File saveUploadedFile(CommonsMultipartFile multipartFile) throws FileNotFoundException, IOException {
+        if (!multipartFile || multipartFile.isEmpty()) {
+            log.debug "Received file is either empty or does not exists"
+            throw new FileNotFoundException(messageSource.getMessage("kernel.uploaded.file.empty", null, null))
+        }
+
+
+        InputStream inputStream
+        FileOutputStream fileOutputStream
+
+        byte[] fileRead = new byte[1024]
+
+        try {
+            String originalFilename = multipartFile.getOriginalFilename()
+
+            log.debug "Uploaded file's name [$originalFilename]"
+
+            // Remove special characters other than "a-z" "A-Z" "0-9" "." "-" or "_"
+            String fileName = originalFilename.replaceAll("[^a-zA-Z0-9//._-]+", "").toLowerCase()
+
+            File temporaryDirectory = Files.createTempDirectory(null).toFile()
+            File temporaryFile = new File(temporaryDirectory, fileName)
+
+            log.debug "File [$fileName] will be saved in [${temporaryDirectory.absolutePath}]"
+
+            inputStream = multipartFile.getInputStream()
+            fileOutputStream = new FileOutputStream(temporaryFile)
+
+            int i = inputStream.read(fileRead)
+
+            while (i != -1) {
+                fileOutputStream.write(fileRead, 0, i)
+                i = inputStream.read(fileRead)
+            }
+
+            // A dynamic method to get the original name of the file which was received
+            temporaryFile.metaClass.getOriginalFilename = { ->
+                return originalFilename
+            }
+
+            return temporaryFile
+        } catch (FileNotFoundException e) {
+            log.error "Problem saving file", e
+            throw e
+        } catch (IOException e) {
+            log.error "Exception saving file", e
+            throw e
+        } finally {
+            fileOutputStream?.close()
+            inputStream?.close()
+        }
+    }
+}