Reusing the radio streaming code from the project

[Raima010]

Hi Vlad. Its is not actually an issue but questions about your Cd player project. You have modified a little bit Pschatzmann´s code which has some issues with internet radio stream buffering and got better results as I understood.
My question is would it be difficult to integrade just your web radio part in a simple Arduino ide sketch as example to test the perforrmance. You use quite deep intergration with the rest of your project so its a little bit tricky to extract only what is needed? Can you give some tips on that or eventually down strip code limited just to Web radio-bluetooth receiver?
Simple arduino sketch for webradio which is given by Pschatzmann looks like this:

#include "Arduino.h"
#include "WiFi.h"
#include "Audio.h"
// Connections ESP32 <-> Amplifier
#define I2S_DOUT 2
#define I2S_BCLK 3
#define I2S_LRC 4
Audio audio;
// Wifi Credentials
String ssid = "YOUR NETWORK";
String password = "YOUR PASSWORD";

void setup() {

Serial.begin(115200);
WiFi.disconnect();
WiFi.mode(WIFI_STA);
WiFi.begin(ssid.c_str(), password.c_str());
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}

audio.setPinout(I2S_BCLK, I2S_LRC, I2S_DOUT);
// Volume (0-100)
audio.setVolume(10);
// Radio stream, e.g. Byte.fm
audio.connecttohost("http://www.byte.fm/stream/bytefm.m3u");

}

void loop()

{
audio.loop();

}

We take in consideration that one would use ESP32 module with PSRAM.

Thank you for your comments.

[vladkorotnev]

The whole radio pipeline is basically located in a separate file, where the AudioRouter's IOPortNub is your I2SStream in the simplest case. (I plan to potentially add other output routes someday later, so I obtain the output port from the router)

So in the simplest case you would just take that class, change the argument to accept an I2SStream instead of the AudioRouter, then instantiate it and call something like pipeline.start("www.example.com/radio.mp3", [](bool loading) { if(loading) Serial.println("NOW LOADING!"); }); and there it goes!

I have to note that if you are not buying your ESP modules from a verified source such as Digikey (I was buying off some seller on Taobao), your mileage may vary. I was getting vastly different reliability among ESPs even in the same batch, although none of them worked with Phil's code at all.

Increasing the Net Buffer to e.g. 2KB makes things more stable, but with some lower bitrate radios it takes a very long while for the buffer to fill up.

One good idea would be to make an automatic buffer increase algorithm so that e.g. originally it only buffers to the 10% mark, upon stutter now it uses 20%, and so on... (please do a PR if you implement this :-)

Be that as it may, this is my daily driver radio now and it works more stable than any other projects I've tried so far (KaRadio and Phil's examples) — but then again, maybe my ESPs or internet are just bad.

Also note that you might have to juggle around the tasks and priorities thereof in this class, since those are balanced out to fit in particular the stuff that's running in the ESPer-CDP firmware.

[Raima010]

Well, I made a try, but can not get it working..
Modified class to accept I2S stream:

class StreamingPipeline {
    public:
        StreamingPipeline(I2SStream *i2sStream):
            bufferNetData(NET_DATA_BUFFER_SIZE),
            bufferPcmData(PCM_DATA_BUFFER_SIZE, 1, portMAX_DELAY, portMAX_DELAY, fastAlloc),
            queueNetData(bufferNetData),
            queuePcmData(bufferPcmData),
            activeCodec(nullptr),
            decoder(&queueNetData, activeCodec),
            copierDownloading(queueNetData, urlStream),
            sndTask("IRASND", 8192, 8, 0),
            codecTask("IRADEC", 40000, 6, 1),
            netTask("IRANET", 20000, 14, 1),
            copierDecoding(decoder, queueNetData),
            copierPlaying(*i2sStream, queuePcmData) {
                outPort = i2sStream;
                semaSnd = xSemaphoreCreateBinary();
                semaNet = xSemaphoreCreateBinary();
                semaCodec = xSemaphoreCreateBinary();
                xSemaphoreGive(semaSnd);
                xSemaphoreGive(semaNet);
                xSemaphoreGive(semaCodec);
        }
....
protected:
        AudioStream * outPort;
        //AudioOutput* outPort;

******************************Arduino IDE sketch
#include "AudioTools.h"
#include "pipeline.h"
#include <WiFi.h>

Static I2SStream i2s;

#define I2S_BCLK   26
#define I2S_LRCLK  25
#define I2S_DOUT   22

void setup() {
  Serial.begin(115200);

  I2SConfig config;
  config.sample_rate = 44100;
  config.bits_per_sample = 16;
  config.channels = 1;
  config.pin_bck = I2S_BCLK;
  config.pin_ws = I2S_LRCLK;
  config.pin_data = I2S_DOUT;

  // Initialize I2S and Pipeline
  i2s.begin(config);
  pipeline.start("http://stream.radioparadise.com/mp3-192", [](bool loading) { if(loading) Serial.println("NOW LOADING!"); });
}

void loop() {
   delay(1000);
}

It compiles, but silently crashes in urlStream.begin(url.c_str());. On the URLStream.h side on "if (!preProcess(urlStr, acceptMime))" where acceptMime gets null pointer. Hardcoding this doesnt help either.

Any Ideas? Or what I am missing here?

[vladkorotnev]

Please use the code formatting (put ``` on the lines before and after) when pasting code, it's very hard to read otherwise

If anything, I cannot find where is your pipeline variable initialized, neither the code that does the WiFi connection and then waits for it to complete (it was there in your original post but not the new one). So maybe the ESP is just not connected to the WiFi which triggers some bug in AudioTools.

[Raima010]

Sorry I took off too much lines to be it more readable but it may take in confution. Here is 100% sketch:

#include "AudioTools.h"
#include "pipeline.h"
#include <WiFi.h>

const char* ssid = "mySSID";
const char* pasword = "myPassword";

static I2SStream i2s;

#define I2S_BCLK   26
#define I2S_LRCLK  25
#define I2S_DOUT   22

void setup() {
  Serial.begin(115200);

   WiFi.mode(WIFI_STA); //Optional
   WiFi.begin(ssid, pasword);
   Serial.println("\nConnecting");
   while(WiFi.status() != WL_CONNECTED){Serial.print(".");delay(100);}                                      
   Serial.println("\nConnected to the WiFi network");
   Serial.print("Local ESP32 IP: ");
   Serial.println(WiFi.localIP());

  // Config object for I2SStream
  I2SConfig config;
  config.sample_rate = 44100;
  config.bits_per_sample = 16;
  config.channels = 1;
  config.pin_bck = I2S_BCLK;
  config.pin_ws = I2S_LRCLK;
  config.pin_data = I2S_DOUT;

  // Initialize I2S and Pipeline
  i2s.begin(config);
  StreamingPipeline pipeline(&i2s);
  pipeline.start("http://stream.radioparadise.com/mp3-192", [](bool loading) { if(loading) Serial.println("NOW LOADING!"); });
}

void loop() {
   delay(1000);

}  

So we get on Serial that wifi is connected. Get into pipeline.h code, and rigt in the function url.begin(url.c_str()) it hangs. There it calls URLStream.h from audiotools and stops with preprocessor with acceptMime nullptr. No more output on Serial, no ESP WDT reboot, nothing more. Wondering if can be some memory issues, core issues or still error in code..
Hardware on I2S with simple sine generator code tested and working.

[vladkorotnev]

You are declaring the StreamingPipeline variable inside of the setup method. So when the pipeline.start() method returns, the setup method ends, and the pipeline variable is deleted, releasing all underlying resources. However the threads started by the pipeline still live on, so if you're lucky you get a crash with a stack trace, otherwise the ESP continues to execute some random place in memory or hangs waiting on some semaphore/spinlock.

Make the pipeline variable static and put it outside of the setup method (e.g. right on the next line after your I2SStream) and it should behave correctly

[Raima010]

Ok some news here, Ive got it working. Here is Arduino sketch and modified pipeline.h

#include "AudioTools.h"
#include "pipeline.h"
#include <WiFi.h>

const char* ssid = "myssid";
const char* pasword = "mypassword";

static I2SStream i2s;
static StreamingPipeline* pipeline = nullptr;

#define I2S_BCLK   26
#define I2S_LRCLK  25
#define I2S_DOUT   22

void setup() {
  Serial.begin(115200);

  WiFi.mode(WIFI_STA); //Optional
  WiFi.begin(ssid, pasword);
  Serial.println("\nConnecting");
  while(WiFi.status() != WL_CONNECTED){Serial.print(".");delay(100);}                                      
  Serial.println("\nConnected to the WiFi network");
  Serial.print("Local ESP32 IP: ");
  Serial.println(WiFi.localIP());

  I2SConfig config;
  config.sample_rate = 44100;
  config.bits_per_sample = 16;
  config.channels = 1;
  config.pin_bck = I2S_BCLK;
  config.pin_ws = I2S_LRCLK;
  config.pin_data = I2S_DOUT;

  i2s.begin(config);
  pipeline = new StreamingPipeline(&i2s);

  pipeline->start("http://ice1.somafm.com/secretagent-128-mp3", [](bool loading) { if(loading) Serial.println("NOW LOADING!"); });
}

void loop() {
delay(1000);
}

****************pipeline.h
//#include <modes/netradio_mode.h>
#include "AudioTools.h"
#include <AudioTools/AudioCodecs/CodecHelix.h>
#include <AudioTools/AudioCodecs/CommonHelix.h>
#include <lwip/sockets.h>
#include <AudioTools/CoreAudio/AudioMetaData/MetaData.h>

void _update_meta_global(MetaDataType type, const char* str, int len) {
    ESP_LOGI("META", "[%d] %.*s", type, len, str);
}

class AllocatorFastRAM : public Allocator {
    void* do_allocate(size_t size) {
      void* result = nullptr;
      if (size == 0) size = 1;
      if (result == nullptr) result = heap_caps_calloc(1, size, MALLOC_CAP_8BIT | MALLOC_CAP_INTERNAL); //MALLOC_CAP_SPIRAM /MALLOC_CAP_INTERNAL
      if (result == nullptr) {
        LOGE("Internal-RAM alloc failed for %zu bytes", size);
        stop();
      }
      // initialize object
      memset(result, 0, size);
      return result;
    }
  };

static AllocatorFastRAM fastAlloc;

/// Size of compressed data buffer in PS-RAM
const size_t NET_DATA_BUFFER_SIZE = 256 * 1024;
/// Size of PCM data buffer in DRAM
const size_t PCM_DATA_BUFFER_SIZE = 8 * 1024;
/// Percent of compressed data buffer that must be full to start playing
const float NET_DATA_ENOUGH_MARK_PCT = 50.0; // %
/// Timeout for net client
const int NET_CLIENT_TIMEOUT = 10000; // ms
/// Timeout to consider no copies from network a stall
const int NET_NO_DATA_TIMEOUT = 10000; // ms
/// Interval for printing periodic stats logs (buffer %'s etc)
const int LOG_STATS_INTERVAL = 3000; // ms

class StreamingPipeline {
    public:
        StreamingPipeline(I2SStream *i2sStream):
            bufferNetData(NET_DATA_BUFFER_SIZE),
            bufferPcmData(PCM_DATA_BUFFER_SIZE, 1, portMAX_DELAY, portMAX_DELAY, fastAlloc),
            queueNetData(bufferNetData),
            queuePcmData(bufferPcmData),
            activeCodec(nullptr),
            decoder(&queueNetData, activeCodec),
            copierDownloading(queueNetData, urlStream),
            sndTask("IRASND", 8192, 8, 0),
            codecTask("IRADEC", 40000, 6, 1),
            netTask("IRANET", 20000, 14, 1),
            copierDecoding(decoder, queueNetData),
            copierPlaying(*i2sStream, queuePcmData) {
                outPort = i2sStream;
                semaSnd = xSemaphoreCreateBinary();
                semaNet = xSemaphoreCreateBinary();
                semaCodec = xSemaphoreCreateBinary();
                xSemaphoreGive(semaSnd);
                xSemaphoreGive(semaNet);
                xSemaphoreGive(semaCodec);
        }
    
        ~StreamingPipeline() {
            if(running) stop();
    
            vSemaphoreDelete(semaSnd);
            vSemaphoreDelete(semaNet);
            vSemaphoreDelete(semaCodec);
        }

        int getNetBufferHealth() {
            if(!running) return 100;
            return trunc(bufferNetData.levelPercent());
        }
    
        void start(const std::string url, std::function<void(bool)> loadingCallback) {
            running = true;
            loadingCallback(true);
            ESP_LOGI(LOG_TAG, "Streamer is starting");
            queueNetData.begin();
            queuePcmData.begin();
            netTask.begin([this, url, loadingCallback]() { 
                    TickType_t last_shart_time = xTaskGetTickCount();
                    
                    urlStream.setMetadataCallback(_update_meta_global);
                    urlStream.httpRequest().setTimeout(NET_CLIENT_TIMEOUT);
                    urlStream.httpRequest().header().setProtocol("HTTP/1.0"); // <- important, because chunked transfer of some servers seems to cause trouble with buffering!
                    urlStream.begin(url.c_str());
                    ESP_LOGI(LOG_TAG, "Streamer did begin URL");
                    

                    const char * _srv_mime = urlStream.httpRequest().reply().get("Content-Type");
                    if(_srv_mime != nullptr) {
                        const std::string srv_mime = _srv_mime;
                        ESP_LOGI(LOG_TAG, "Server reports content-type: %s", srv_mime.c_str());
                        if(srv_mime == "audio/mpeg" || srv_mime == "audio/mp3") {
                            activeCodec = new MP3DecoderHelix();
                        }
                        else if(srv_mime == "audio/aac" || srv_mime == "audio/aacp" /* found on Keygen FM */) {
                            activeCodec = new AACDecoderHelix();
                        }
                        else {
                            ESP_LOGE(LOG_TAG, "Content-type is not supported, TODO show error");
                            loadingCallback(false);
                            vTaskDelay(portMAX_DELAY);
                        }
                        decoder.setDecoder(activeCodec);
                        activeCodec->setNotifyActive(true);
                        activeCodec->addNotifyAudioChange(*outPort);
                        decoder.setOutput(queuePcmData);
                    } else {
                        ESP_LOGE(LOG_TAG, "No content-type reported, TODO show error");
                        loadingCallback(false);
                        vTaskDelay(portMAX_DELAY);
                    }
                    decoder.setNotifyActive(true);
                    decoder.begin();
                    ESP_LOGI(LOG_TAG, "Streamer did begin decoder");
    
                    TickType_t last_successful_copy = xTaskGetTickCount();
                    TickType_t last_stats = xTaskGetTickCount();

                    codecTask.begin([this]() { 
                        while(bufferNetData.levelPercent() < NET_DATA_ENOUGH_MARK_PCT && running) { 
                            delay(125);
                        }
                        
                        if(!running) {
                            ESP_LOGI(LOG_TAG, "Finishing up codec task early");
                            decoder.end();
                            xSemaphoreGive(semaCodec);
                            vTaskDelay(portMAX_DELAY);
                        }
    
                        while(copierDecoding.copy() > 0 && !bufferNetData.isEmpty() && running) {
                            delay(10);
                        }
                        while(bufferNetData.levelPercent() < NET_DATA_ENOUGH_MARK_PCT && running) delay(250);

    
                        if(!running) {
                            ESP_LOGI(LOG_TAG, "Finishing up codec task");
                            decoder.end();
                            xSemaphoreGive(semaCodec);
                            vTaskDelay(portMAX_DELAY);
                        }

                        delay(5);
                        xSemaphoreGive(semaCodec);
                    });

                    sndTask.begin([this, loadingCallback]() { 
                        xSemaphoreTake(semaSnd, portMAX_DELAY);
                        if(!copierPlaying.copy() && running) {
                            ESP_LOGD(LOG_TAG, "copierPlaying underrun!? PCM buffer %.00f%%, net buffer %.00f%%", bufferPcmData.levelPercent(), bufferNetData.levelPercent()); 
                            loadingCallback(true);
                            while(bufferPcmData.isEmpty() && running) { 
                                xSemaphoreGive(semaSnd);
                                delay(100);
                                xSemaphoreTake(semaSnd, portMAX_DELAY);
                            }
                            loadingCallback(false);
                        }
                        xSemaphoreGive(semaSnd);
                        delay(2); 
                        if(!running) { 
                            ESP_LOGI(LOG_TAG, "Finishing up sound task");
                            vTaskDelay(portMAX_DELAY);
                        }
                    });

                    while(true) {
                        xSemaphoreTake(semaNet, portMAX_DELAY);
                        TickType_t now = xTaskGetTickCount();
                        int copied = copierDownloading.copy();
                        if(copied > 0) {
                            last_successful_copy = now;
                            delay(2);
                        } else if(now - last_successful_copy >= pdTICKS_TO_MS(NET_NO_DATA_TIMEOUT)  && (bufferNetData.levelPercent() < 20.0 || bufferPcmData.isEmpty())) {
                            ESP_LOGE(LOG_TAG, "streamer is stalled!? time since last shart = [ %i ms ]", now - last_shart_time);
                            last_shart_time = now;
                            loadingCallback(true);
                            urlStream.end();
                            int retryDelay = 100;
                            do {
                                if(bufferPcmData.isEmpty()) bufferNetData.clear(); // prevent click artifact on restart playback
                                delay(retryDelay);
                                retryDelay += 1000;
                                if(retryDelay > NET_CLIENT_TIMEOUT) retryDelay = NET_CLIENT_TIMEOUT;
                                ESP_LOGE(LOG_TAG, "streamer is trying to begin URL again");
                            } while(!urlStream.begin(url.c_str()));
                            last_successful_copy = now;
                        } else if(copied < 0) {
                            ESP_LOGE(LOG_TAG, "copied = %i ???", copied);
                        } else if(bufferNetData.isFull()) {
                            ESP_LOGW(LOG_TAG, "Net buffer full, no space to receive more data!!");
                            delay(10);
                        } else {
                            // copied nothing, maybe yield to another task
                            delay(10);
                        }
                        if(now - last_stats >= pdTICKS_TO_MS(LOG_STATS_INTERVAL)) {
                            ESP_LOGI(LOG_TAG, "Stats: PCM buffer %.00f%%, net buffer %.00f%%", bufferPcmData.levelPercent(), bufferNetData.levelPercent()); 
                            last_stats = now;
                        }

                        if(!running) {
                            urlStream.end();
                            xSemaphoreGive(semaNet);
                            break;
                        }

                        xSemaphoreGive(semaNet);
                    }
                    ESP_LOGI(LOG_TAG, "Finishing up net task");
                    vTaskDelay(portMAX_DELAY);
                }
            );
        }
    
        void stop() {
            NullStream tmp;
            decoder.setOutput(tmp);
            if(activeCodec != nullptr) {
                activeCodec->setOutput(tmp);
            }

            running = false;
            xSemaphoreTake(semaNet, portMAX_DELAY);
            ESP_LOGI(LOG_TAG, "Streamer finalizing net task");
            netTask.end();
    
            ESP_LOGI(LOG_TAG, "Streamer finalizing sound task");
            xSemaphoreTake(semaSnd, portMAX_DELAY);
            sndTask.end();
    
            // Small shitshow because the codec thread sometimes gets stuck and never exits and leaves the semaphore
            ESP_LOGI(LOG_TAG, "Streamer finalizing codec task");
            bool codecNotStuck = xSemaphoreTake(semaCodec, pdMS_TO_TICKS(1000));
            codecTask.end();

            if(!codecNotStuck) { 
                delay(1000); // give it time to unshit itself to prevent explosions 
            }
            if(activeCodec != nullptr) {
                activeCodec->setOutput(tmp);
                delete activeCodec;
                activeCodec = nullptr;
            }
        }
    
    protected:
        bool running = false;
        ICYStream urlStream;
        StreamCopy copierDownloading;
        StreamCopy copierPlaying;
        StreamCopy copierDecoding;
        AudioDecoder * activeCodec;
        EncodedAudioStream decoder;
        Task sndTask;
        Task codecTask;
        Task netTask;
        BufferRTOS<uint8_t> bufferNetData;
        BufferRTOS<uint8_t> bufferPcmData;
        QueueStream<uint8_t> queueNetData;
        QueueStream<uint8_t> queuePcmData;
        AudioStream * outPort;
        //AudioOutput* outPort;
        SemaphoreHandle_t semaSnd;
        SemaphoreHandle_t semaNet;
        SemaphoreHandle_t semaCodec;

        const char * LOG_TAG = "ISTREAM";
    };

There was some issues with AudioTools libraries which eventually were tweeked wrong with my experiments, and sound was very speed upp with constant buffer underrun. But after audiotools fresh copy installation all started perfect! And it seems its very stable so long with good reserv in buffers:

[  3991][I][pipeline.h:9] _update_meta_global(): [META] [0] Ohn - Down At Larry's
[  5401][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 0%, net buffer 32%
[  8422][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 94%, net buffer 54%
[ 11428][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 63%
[ 14447][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 72%
[ 17453][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 94%, net buffer 84%
[ 20464][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 97%
[ 23568][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 26566][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 29629][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 32711][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 35794][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 38791][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 41854][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 44936][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 47934][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 50945][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 54027][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 57025][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 60005][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 87%, net buffer 99%
[ 63118][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 66117][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 87%, net buffer 100%
[ 69126][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 72125][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 75206][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 78269][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 81352][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 84435][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 87431][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 90494][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 93577][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[ 96574][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[ 99585][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[102667][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[105665][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[108676][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[111758][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[114756][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[117766][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[120849][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[123846][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[126909][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[129992][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[133074][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[136072][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[139135][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[142217][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[145214][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[148225][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[151308][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[153608][I][pipeline.h:9] _update_meta_global(): [META] [0] Secret Agent Dropin - 5men
[154305][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[157316][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[159249][I][pipeline.h:9] _update_meta_global(): [META] [0] Burt Bacharach - The Look Of Love (Instrumental)
[160398][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[163333][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 95%
[166407][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[169490][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[172486][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[175549][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[178632][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[181714][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[227275][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[230355][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[233352][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%
[236415][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[239498][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 81%, net buffer 100%
[242495][I][pipeline.h:223] operator()(): [ISTREAM] Stats: PCM buffer 100%, net buffer 100%

Still one problem. It seems it wont accept https just http? Or problem somewhere? For ex this link https://stream.m-1.fm/m1/MP3320.m3u gives errors:

[  1778][D][NetworkManager.cpp:127] hostByName(): DNS found IPv4 195.12.170.101
[  1893][D][ssl_client.cpp:196] start_ssl_client(): WARNING: Skipping SSL Verification. INSECURE!
[E] MetaDataICY.h : 269 - icy-metaint not defined
[W] ICYStream.h : 73 - url does not provide metadata
[  2463][I][pipeline.h:109] operator()(): [ISTREAM] Streamer did begin URL
[  2478][I][pipeline.h:115] operator()(): [ISTREAM] Server reports content-type: audio/x-mpegurl
[  2487][E][pipeline.h:123] operator()(): [ISTREAM] Content-type is not supported, TODO show error

[vladkorotnev]

M3U is a playlist file, not an audio file, so you need to parse it yourself to get the actual audio stream URL. Or just open it in notepad and take the actual stream URL out by hand. Maybe good idea to do this in the project eventually too, but so far all the stations I've listened to the manual approach worked just fine.

[vladkorotnev]

Just out of curiosity though, you seem to be getting very decent net buffer levels, was that stream not working correctly with the simple AudioTools sample code?

[Raima010]

I have tried several radio streams but all of them more or less had dropouts with audiotools. And it behaves actually like that, sometimes have good percentage in buffer then suddenly begin to go down in percentage and eventually dropps the stream. Some posts we can find on the net like this one schreibfaul1/ESP32-audioI2S#545. Some people came even to decition that it was to litte computational power in ESP32 and so on. In general it looks lite there was problem from the beginning. Several dropouts like in quarter of hour was very irritating and whole concept not to be considered usable. Audiotools have been updated just few days ago where it was fixed some memory issues llike its said. Tried this new vertion also but still dropouts though first imprettion may be its a little bit better. Initially my goal was not digging so deep in this problem just making simple radio/bluetooth board to integrate that in the self powered speaker. So now I tested your alternative approach to same problem and this setup holds the stream. Does not tested it like 24 hours, but no one drop in several hours what is already acceptable.
But here I have also question. If I have taken your pipeline class, does the PSRAM is somewere configured down the line in audiotools or I am not usig it att all now? I see in your project its sonfigured somewhere else?

[vladkorotnev]

If you are using the Arduino framework, PSRAM should be enabled automagically in theory as long as your board definition has the correct flags. Watch for the "PSRAM Enabled" log line when powering on the MCU.

If you are using the ESP IDF, you need to turn it on manually in menuconfig, and then AudioTools will use it by default. (AudioTools usually calls ps_malloc which acts similar to regular malloc but prefers PSRAM)

[Raima010]

One more question. Now when I want to put alltogether with bluetooth option as well. I found that its not easy to switch between modes. Partially maybe that A2DP bluetooth has extensive RAM utilisation as well. When I try to end a2dp object and start pipeline again its not always succesfullt. Tried different methods, worked if all not stable sometimes switches between modes but often stops silently. How you solved this problem? Is there some clean way to switch between radio/BT. Needs Shutt down/restart of BT in some manner?

[vladkorotnev]

I just call the underlying APIs for bluedroid teardown directly which do not deinitialize it but free up some memory: https://github.com/vladkorotnev/cd-player/blob/master/firm/src/mode/bluetooth_mode.cpp#L343-L345

However the SBC codec the ESP32 includes is definitely not of great quality, so my idea for the next revision of the board is to drop support for this and use an external aptX/AAC module

[Raima010]

Very interresting idea what concerns further improvments!:

However the SBC codec the ESP32 includes is definitely not of great quality, so my idea for the next revision of the board is to drop support for this and use an external aptX/AAC module

In the previous question here:

void BluetoothMode::teardown() {
    rootView->set_wait();

    if(a2dp.is_connected()) {
        a2dp.disconnect();
    }
    a2dp.end();
    resources.router->activate_route(Platform::AudioRoute::ROUTE_NONE_INACTIVE);

    // a2dp.end(true) would have called those for us but went too far and actually deinited the controller, we want to just stop it until we come back into this mode again
    esp_bluedroid_disable();
    esp_bt_controller_disable();

    Core::Services::WLAN::start();
}

Still one a2dp.end(); command above? Youy mean we do not want to end a2dp, so it must be commented also? And after all you have Core::Services::WLAN::start(); Can it be ommited or we need to restart directly WLAN for some purpose?

P.S: I see now a2dp.end(); accepts argument as true or false. So you call it without releasing memory, right?

[vladkorotnev]

Yes, otherwise you would not be able to restart it again

I am restarting WiFi in that function because in my application I've found there are performance issues when both bluetooth and wifi are active, so whenever bluetooth is on wifi is off and vice versa

[vladkorotnev]

@Raima010 Just curious as part of investigation — 1. What region is your WiFi router from and the channel it uses? Auto channel mode on/off? 2. Did you do any regional settings on the ESP32 for WiFi channels? 3. Did you buy the ESP32 from a big name vendor like Digikey or Mouser, or from a local shop or Aliexpress?

Tl;dr I started implementing FTP — and this time it's from a LAN server so I thought it MUST work right away with the example code. And it stutters lol, albeit not as badly as net radio.

[Raima010]

Hi! I am using 4g wireless router Archer MR600. Its on Telia gsm network. Channel selection is Auto. No any regional setting I am using no where, all by default. This one I am using ESP32 I bought from local reseller Electrokt.

Must say I didn manage to switch betwee BT and Radio modes cleanly. BT uses a lot of resources so It must be disabled in order to make Radio work. But my concept is control via webserver so I need wifi at the sime time active. Disabling to much resources from BT as I found in espressif documentations makes it not restartable without uC reboot. So I disable completely BT when switching to Radio mode, and reboot in BT mode uC when it is needed. At the same time keep webserver and wi-fi on also. All done from webserver.

Below some pictures of the project. Now awaiting for new pcb, as I used only one mono channel but ESP32 drives strereo channels anyway so we just waist one channel. On new pcb it will be 2 max98357 amplifiers for stereo. Additionally faced problem with power supply because of 50hz mains hum, so power block is disassembled for a moment.

[Raima010]

In your case it also strange behavior, too much mystics here. But somewhere above I also mentioned that Ive been getting strange effect with latest Audiotools library when sound was a lot speed-up and emptied buffer fast as it could not refill again. So I am using a little bit older version, somewhere from 2024 November +/- cant remember exactly. This was installed on time of development. I foud that after I have updated libraries. Problem that we are using a lot of migrating libraries in term of vertions. Wondering if there could be an issue also.

On my side now it works flawlessly. Below is some log.

By the way, it may be worth to check signal RSSI strenght/antenna on ESP32 also.

Log.txt

[Raima010]

So, final kick and now its in stereo. Project complete!

[Raima010]

You have uploaded a modified pipeline.h vertion. Just curious, have you got some better results or ruled out the problem?

[vladkorotnev]

Eliminating the double buffering and adjusting thread affinity seems to have made it much more stable while having faster startup times for me. Albeit I think there also needs to be some adjustment done to the LWIP/Wireless affinity in IDF. Which also kind of implies this code is not really usable in pure Arduino because you cannot control affinity of the system stack in that! (you probably can figure it out in compile-time by checking a bunch of config defines)

[Raima010]

If you want I can send to you compiled bin file to check your harware and eventually software issues as it worked ok for me? Hardware setup doesn matter as it can be monitored on serial if dropouts occur.