OpenDTU automatischer Reset bei Wlan-Verlust #2624

Gelegenheitsbastler · 2025-04-05T15:06:31Z

Gelegenheitsbastler
Apr 5, 2025

Das Problem wurde hier ausführlich erläutert:
#419

Die Wlanverbindung geht verloren und die OpenDTU verbindet sich erst nach einem Reset neu mit dem Wlan.

Da ich diverse Modulwechselrichter mit der OpenDTU betreibe und die Daten aufzeichne ist es mir wichtig, dass die erfassten Daten halbwegs stimmen. Verliert die OpenDTU das Wlan wird der zuletzt übermittelte Wert durchgängig als Ertrag erfasst, was die Statistik massiv verfälscht, da ich diesen Fehler teilweise erst nach vielen Tagen bemerke.

Um das Problem zu lösen habe ich folgende Lösung gebaut:

Ein XIAO ESP32C3 überprüft alle 30 Sekunden, ob die OpenDTU per Wlan erreichbar ist. Ist sie nicht erreichbar wird das Intervall auf 15 Sekunden verkürzt. Nach Ablauf von 2 Minuten ohne erfolgreiche Verbindung wird über GPIO 5 ein LOW an den Reset Pin des ESP der OpenDTU geschickt, wodurch dieser neu bootet.

Um den Reset auch manuell ausführen zu können und einen Überblick über die Geschehnisse zu haben gibt es eine kleine Webseite, auf der die Daten rudimentär angezeigt werden. Die Tabelle zeigt an, ob das Ereignis manuell oder automatisch ausgelöst wurde und wann dies geschah. Damit die Seite überschaubar bleibt kann man die Anzahl der Zeilen einstellen und bei Bedarf auch jeden beliebigen Eintrag manuell löschen.

Als NTP-Server habe ich die FritzBox genommen, damit dieser ESP nicht ins Internet muss. Aber auch jeder andere NTP-Server kann eingetragen werden. Sommer- und Winterzeit sollten automatisch geändert werden. Der Rest des Sketches sollte halbwegs selbsterklärend sein. Die Anzeige der Speicherausnutzung ist eigentlich nur zu Debug Zwecken gedacht. Wer mag kann sie auskommentieren.

Da es noch nicht zu einem längeren Verbindungsabbruch kam, kann ich nicht sagen, ob die Lösung funktioniert. Was ich erfolgreich getestet habe war die manuelle Auslösung.

Vielleicht ist noch jemand ähnlich genervt und möchte das Problem ebenfalls lösen.


#include <WiFi.h>
#include <ESP32Ping.h>
#include <WebServer.h>
#include <ESPmDNS.h>
#include <Update.h>
#include <time.h>
#include <vector>

const char* ssid = "WLAN-Name";
const char* password = "Passwort";
const IPAddress targetIP(192, 168, 111, 222); // IP der OpenDTU  
const int outputPin = 5;        // D3 zum Anschluss an openDTU ESP
const int manualTriggerPin = 7; // D5 optional für manuellen Taster

// Konfigurierbare Variablen
unsigned int pageRefreshInterval = 5; // Auto-Refresh Intervall in Sekunden
unsigned int maxEntries = 10; // Maximale Anzahl der angezeigten Zeilen in der Tabelle

unsigned long lastPingTime = 0;
unsigned long lastSuccessfulPing = 0;
unsigned long lastTriggerTime = 0;
unsigned long manualTriggerCount = 0;
unsigned long failedPingCount = 0;
int pingInterval = 30000;
bool cooldownActive = false;

WebServer server(80);

// NTP Server Konfiguration
const char* ntpServer = "192.168.111.123";
const long gmtOffset_sec = 3600;
const int daylightOffset_sec = 3600;

struct Activation {
  String datetime;
  String type;
};

std::vector<Activation> activationLog;

void handleRoot() {
  char timeStr[20];
  char dateStr[20];
  time_t now;
  struct tm timeinfo;
  
  time(&now);
  localtime_r(&now, &timeinfo);
  strftime(timeStr, sizeof(timeStr), "%H:%M:%S", &timeinfo);
  strftime(dateStr, sizeof(dateStr), "%d.%m.%Y", &timeinfo);

  String dstStatus = timeinfo.tm_isdst ? "Sommerzeit (MESZ)" : "Winterzeit (MEZ)";
  
  unsigned long secondsToNextCheck = (pingInterval - (millis() - lastPingTime)) / 1000;
  
  // Speicherauslastung
  uint32_t freeHeap = ESP.getFreeHeap();
  uint32_t totalHeap = ESP.getHeapSize();
  float memUsage = 100.0 * (1.0 - (float)freeHeap / (float)totalHeap);
  
  String html = "<!DOCTYPE html><html><head><meta charset=\"UTF-8\"><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">";
  html += "<meta http-equiv=\"refresh\" content=\"" + String(pageRefreshInterval) + "\">"; // Konfigurierbares Refresh
  
  html += "<style>body{font-family:Arial;text-align:center;margin-top:50px;}";
  html += "button{background:#4CAF50;border:none;color:white;padding:10px 20px;text-align:center;";
  html += "text-decoration:none;display:inline-block;font-size:16px;margin:4px 2px;cursor:pointer;}";
  html += "input{width:50px;text-align:center;}";
  html += ".progress-container{width:80%;margin:10px auto;background:#ddd;border-radius:5px;}";
  html += ".progress-bar{height:20px;border-radius:5px;background:#4CAF50;text-align:center;color:white;line-height:20px;}";
  html += "</style></head>";
  
  html += "<body><h1>ESP32 Status</h1>";
  html += "<p>Aktuelle Zeit: " + String(timeStr) + " (" + dstStatus + ")</p>";
  html += "<p>Datum: " + String(dateStr) + "</p>";
  
  // Speicherauslastung
  html += "<h3>Speicherauslastung</h3>";
  html += "<div class=\"progress-container\">";
  html += "<div class=\"progress-bar\" style=\"width:" + String(memUsage) + "%;\">" + String(memUsage, 1) + "%</div>";
  html += "</div>";
  html += "<p>Freier Speicher: " + String(freeHeap/1024) + " kB von " + String(totalHeap/1024) + " kB</p>";
  
  html += "<p>Sekunden bis zur nächsten Überprüfung: " + String(secondsToNextCheck) + "</p>";
  html += "<p>Anzahl negativer Überprüfungen: " + String(failedPingCount) + "</p>";
  html += "<p>GPIO 5 Aktivierungen: " + String(manualTriggerCount) + "</p>";
  
  // Tabelle der GPIO 5 Aktivierungen
  html += "<h3>Aktivierungen von GPIO 5</h3>";
  html += "<table border=\"1\" style=\"width:80%;margin:auto;\">";
  html += "<tr><th>Datum und Uhrzeit</th><th>Typ</th><th>Aktion</th></tr>";
  
  // Tabelle einfügen
  for (unsigned int i = 0; i < activationLog.size() && i < maxEntries; i++) {
    html += "<tr><td>" + activationLog[i].datetime + "</td><td>" + activationLog[i].type + "</td>";
    html += "<td><button onclick=\"window.location.href='/delete?id=" + String(i) + "'\">Löschen</button></td></tr>";
  }
  
  html += "</table>";
  
  // Maximalzeilen und Refresh-Interval Einstellung
  html += "<form action=\"/setrefresh\" method=\"POST\">";
  html += "<label for=\"interval\">Seiten-Aktualisierung (Sekunden):</label>";
  html += "<input type=\"number\" id=\"interval\" name=\"interval\" value=\"" + String(pageRefreshInterval) + "\" min=\"1\" max=\"60\">";
  html += "<button type=\"submit\">Speichern</button>";
  html += "</form>";

  html += "<form action=\"/setmaxentries\" method=\"POST\">";
  html += "<label for=\"maxentries\">Maximale Anzahl der Zeilen:</label>";
  html += "<input type=\"number\" id=\"maxentries\" name=\"maxentries\" value=\"" + String(maxEntries) + "\" min=\"1\" max=\"50\">";
  html += "<button type=\"submit\">Speichern</button>";
  html += "</form>";
  
  html += "<button onclick=\"window.location.href='/trigger'\">GPIO 5 manuell auslösen</button>";
  html += "</body></html>";
  
  server.send(200, "text/html", html);
}

void handleSetRefresh() {
  if (server.hasArg("interval")) {
    pageRefreshInterval = server.arg("interval").toInt();
    if(pageRefreshInterval < 1) pageRefreshInterval = 1;
    if(pageRefreshInterval > 60) pageRefreshInterval = 60;
  }
  server.sendHeader("Location", "/");
  server.send(303);
}

void handleSetMaxEntries() {
  if (server.hasArg("maxentries")) {
    maxEntries = server.arg("maxentries").toInt();
    if(maxEntries < 1) maxEntries = 1;
    if(maxEntries > 50) maxEntries = 50;
  }
  server.sendHeader("Location", "/");
  server.send(303);
}

void handleDelete() {
  if (server.hasArg("id")) {
    int id = server.arg("id").toInt();
    if (id >= 0 && id < activationLog.size()) {
      activationLog.erase(activationLog.begin() + id);
    }
  }
  server.sendHeader("Location", "/");
  server.send(303);
}

void handleTrigger() {
  manualTriggerCount++;
  
  // Trigger manuell auslösen
  digitalWrite(outputPin, LOW);
  delay(1000);
  digitalWrite(outputPin, HIGH);

  // Loggen der Aktivierung
  char timeStr[20];
  char dateStr[20];
  time_t now;
  struct tm timeinfo;
  
  time(&now);
  localtime_r(&now, &timeinfo);
  strftime(timeStr, sizeof(timeStr), "%H:%M:%S", &timeinfo);
  strftime(dateStr, sizeof(dateStr), "%d.%m.%Y", &timeinfo);

  Activation newActivation = { String(dateStr) + " " + String(timeStr), "Manuell" };
  activationLog.push_back(newActivation);
  
  server.sendHeader("Location", "/");
  server.send(303);
}

void handleUpdate() {
  server.sendHeader("Connection", "close");
  server.send(200, "text/plain", (Update.hasError()) ? "FAIL" : "OK");
  ESP.restart();
}

void handleUpload() {
  HTTPUpload& upload = server.upload();
  if(upload.status == UPLOAD_FILE_START) {
    Serial.printf("Update: %s\n", upload.filename.c_str());
    if(!Update.begin(UPDATE_SIZE_UNKNOWN)) {
      Update.printError(Serial);
    }
  } else if(upload.status == UPLOAD_FILE_WRITE) {
    if(Update.write(upload.buf, upload.currentSize) != upload.currentSize) {
      Update.printError(Serial);
    }
  } else if(upload.status == UPLOAD_FILE_END) {
    if(Update.end(true)) {
      Serial.printf("Update Success: %u\nRebooting...\n", upload.totalSize);
    } else {
      Update.printError(Serial);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(outputPin, OUTPUT);
  digitalWrite(outputPin, HIGH);
  pinMode(manualTriggerPin, INPUT_PULLUP);

  WiFi.begin(ssid, password);
  while(WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi verbunden");
  Serial.println("IP-Adresse: " + WiFi.localIP().toString());

  if(MDNS.begin("ESP32 Reset openDTU")) {
    Serial.println("mDNS responder gestartet");
  }

  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  Serial.println("\nWarte auf Zeitsynchronisierung...");
  time_t now = 0;
  struct tm timeinfo;
  while (timeinfo.tm_year < (2016 - 1900)) {
    delay(500);
    time(&now);
    localtime_r(&now, &timeinfo);
    Serial.print(".");
  }
  Serial.println("\nZeit erfolgreich synchronisiert");
  
  server.on("/", HTTP_GET, handleRoot);
  server.on("/trigger", HTTP_GET, handleTrigger);
  server.on("/setrefresh", HTTP_POST, handleSetRefresh);
  server.on("/setmaxentries", HTTP_POST, handleSetMaxEntries);
  server.on("/delete", HTTP_GET, handleDelete);
  server.on("/update", HTTP_POST, handleUpdate, handleUpload);
  server.begin();
}

void loop() {
  server.handleClient();
  
  unsigned long currentTime = millis();
  
  if(digitalRead(manualTriggerPin) == LOW) {
    delay(50);
    if(digitalRead(manualTriggerPin) == LOW) {
      manualTriggerCount++;
      digitalWrite(outputPin, LOW);
      delay(1000);
      digitalWrite(outputPin, HIGH);
      while(digitalRead(manualTriggerPin) == LOW);
    }
  }

  if(cooldownActive) {
    if(currentTime - lastTriggerTime >= 60000) {
      cooldownActive = false;
      pingInterval = 30000;
    }
    return;
  }

  if(currentTime - lastPingTime >= pingInterval) {
    lastPingTime = currentTime;
    
    bool reachable = Ping.ping(targetIP);
    
    if(reachable) {
      lastSuccessfulPing = currentTime;
      Serial.println("Ping erfolgreich");
      pingInterval = 30000;
    } else {
      failedPingCount++;
      Serial.println("Ping fehlgeschlagen");
      pingInterval = 15000;
      
      if(currentTime - lastSuccessfulPing >= 120000) {
        Serial.println("Ziel länger als 2 Minuten nicht erreichbar - Trigger GPIO5");
        digitalWrite(outputPin, LOW);
        delay(1000);
        digitalWrite(outputPin, HIGH);
        lastTriggerTime = currentTime;
        cooldownActive = true;
      }
    }
  }
}

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

Uh oh!

Uh oh!

OpenDTU automatischer Reset bei Wlan-Verlust #2624

Uh oh!

{{title}}

Uh oh!

Replies: 0 comments

Select a reply

Uh oh!

Uh oh!

OpenDTU automatischer Reset bei Wlan-Verlust #2624

Uh oh!

Gelegenheitsbastler Apr 5, 2025

Replies: 0 comments

Gelegenheitsbastler
Apr 5, 2025