Lesson 4 Remix Fund Me - Transaction reverted after trying to fund it (Sepolia testnet)

[jacsonikowy]

I'm around 5 hour of video and have this code:

FundMe.sol

// SPDX-License-Identifier: MIT

// Get funds from users
// Withdraw funds
// Set a min funding value in USD

pragma solidity ^0.8.8;

import "./PriceConverter.sol";

contract FundMe {
    using PriceConverter for uint256;

    uint256 public minimumUsd = 50 * 1e18;
    address public owner;

    address[] public funders;
    mapping(address => uint256) public addressToAmountFunded;

    constructor() {
        owner = msg.sender;
    }

    modifier onlyOwner {
        require(owner == msg.sender, "Sender is not owner!");
        _;
    }

    function fund() public payable {
        // Want to be able to set a minimum fund amount in usd
        require(msg.value.getConversionRate() >= minimumUsd, "Minimum is 1 ETH"); // 1e18 == 1 * 10 ** 18 == 1,000,000,000,000,000,000
        // msg.value.getConversionRate();
        // its the same as getConversionRate(msg.value);
        funders.push(msg.sender);
        addressToAmountFunded[msg.sender] += msg.value;
    }

    function withdraw() public onlyOwner {
        
        for (uint256 funderIndex = 0; funderIndex < funders.length; funderIndex = funderIndex + 1) {
            address funder = funders[funderIndex];
            addressToAmountFunded[funder] = 0;
        }

        // resetting the array
        funders = new address[](0);
        
        // actually withdraw the funds

        // transfer - revert - capped to 2300 gas

        // payable(msg.sender).transfer(address(this).balance);

        // send - dont revert transaction - capped to 2300 gas

        // bool sendSuccess = payable(msg.sender).send(address(this).balance);
        // require(sendSuccess, "Send failed");
        
        // call - recommended way to use
        (bool success, /* bytes memory dataReturned */) = payable(msg.sender).call{value: address(this).balance }("");
        require(success, "send failed");
    }

    
}

PriceConverter.sol

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.8;

import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

// cant have state and cant have ether
library PriceConverter {
    function getPrice() internal view returns (uint256){
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419);
        (  
            /* uint80 roundID */,
            int256 answer,
            /*uint startedAt*/,
            /*uint timeStamp*/,
            /*uint80 answeredInRound*/
            ) = priceFeed.latestRoundData();
            
            // Eth in terms of USD
            return uint256(answer * 1e10);
    }

    function getConversionRate(uint256 ethAmount) internal view returns (uint256) {
        uint256 ethPrice = getPrice();
        uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1e18;
        return ethAmountInUsd;
    }
}

The problem is that smart contract is deployed to testnet and when I tried to fund contract it gave me error about gas estimation.

Appreciate any help!

PS. When I was writing this post I noticed that we're looping through a dynamic array - every time someone fund contract with ETH is added to this array. Couldn't a smart contract be a victim of a DoS attack? An attacker could fund smart contract with multiple addresses (or even one doing multiple transactions) and while looping with an enormous length of array I think it could result in OOG. If I'm wrong please correct me and if not - How could I prevent it?

Thanks again!

[jacsonikowy]

Oh, I forgot to add it - I was funding smart contract with 0.2 ETH.

[jacsonikowy]

Okay, I made a stupid mistake. I put the address of Ethereum mainnet instead of Sepolia testnet in AggregatorV3Interface and tried to get a price feed via Remix VM (you can't get a price feed on Remix VM - if someone is having the same problem as me in the future). Closing.