DeclarationError: Undeclared identifier. --> contracts/DynamicSvgNft.sol:46:17: | 46 | require(_exists(tokenId), "Done");

[legendydx]

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.8;
import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";
import "base64-sol/base64.sol";

contract DynamicSvgNft is ERC721 {
uint256 private s_tokenCounter;
string private i_lowImageURI;
string private i_highImageURI;
string private constant base64EncodedSvgPrefix = "data:image/svg+xml;base64,";

AggregatorV3Interface public immutable i_priceFeed;
mapping(uint256 => int256) private s_tokenIdToHighValues;

event CreatedNFT(uint256 indexed tokenId, int256 highValue);

constructor(
    address priceFeedAddress,
    string memory lowSvg,
    string memory highSvg
) ERC721("Dynamic SVG NFT", "DSN") {
    s_tokenCounter = 0;
    i_lowImageURI = svgImageURI(lowSvg);
    i_highImageURI = svgImageURI(highSvg);
    i_priceFeed = AggregatorV3Interface(priceFeedAddress);
}

function svgImageURI(string memory svg) public pure returns (string memory) {
    string memory svgBase64Encoded = Base64.encode(bytes(string(abi.encodePacked(svg))));
    return string(abi.encodePacked(base64EncodedSvgPrefix, svgBase64Encoded));
}

function mintNft(int256 highValue) public {
    s_tokenIdToHighValues[s_tokenCounter] = highValue;
    _safeMint(msg.sender, s_tokenCounter);
    emit CreatedNFT(s_tokenCounter, highValue);
    s_tokenCounter += 1;
}

function _baseURI() internal pure override returns (string memory) {
    return "data:application/json;base64,";
}

function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
    require(_exists(tokenId), "Done");
    (, int256 price, , , ) = i_priceFeed.latestRoundData();
    string memory imageURI = i_lowImageURI;
    if (price >= s_tokenIdToHighValues[tokenId]) {
        imageURI = i_highImageURI;
    }
    return
        string(
            abi.encodePacked(
                _baseURI(),
                Base64.encode(
                    bytes(
                        abi.encodePacked(
                            '{"name":"',
                            name(),
                            '", "description":"An NFT that changes based on the cahinlink base fee"}'
                            '"attributes": [{"trait_type": "coolness", "value": 100}], "image":"',
                            imageURI,
                            '"}'
                        )
                    )
                )
            )
        );
}

}

[Blockchain-Oracle]

require(_exists(tokenId), "URI Query for nonexistent token");

that above is only avaliable for version 4 of openzellian/contracts

this is the new syntax for version 5

/**
* @dev Reverts if the tokenId doesn't have a current owner (it hasn't been minted, or it has been burned).
* Returns the owner.
*
* Overrides to ownership logic should be done to {_ownerOf}.
*/

address owner = _ownerOf(tokenId);
       if (owner == address(0)) {
           revert ERC721NonexistentToken(tokenId);
       }

@LukaNikolic96 @PatrickAlphaC @JawadLegend

remeber to mark this as anwer
happy coding!