Lesson 14: DeclarationError: Undeclared identifier. (require(_exists(tokenId), "URI Query for nonexistent token");

[mrMorningstar96]

Hello,
This is my code:

`// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";
import "base64-sol/base64.sol";

contract DynamicSvgNft is ERC721 {
// Gonna show 2 different images based on price of ETH

// mint
// Store our Svg information somewhere
// Logic to say Show 1 or 2 image

uint256 private s_tokenCounter;
string private i_lowImageURI;
string private i_highImageURI;
string private constant base64EncodedSvgPrefix =
    "data:image/svg+xml;base64,";
AggregatorV3Interface internal immutable i_priceFeed;

mapping(uint256 => int256) public s_tokenIdToHighValue;

event CreatedNFT(uint256 indexed tokenId, int256 highValue);

constructor(
    address priceFeedAddress,
    string memory lowSvg,
    string memory highSvg
) ERC721("Dynamic SVG NFT", "DSN") {
    s_tokenCounter = 0;
    i_lowImageURI = svgToImageURI(lowSvg);
    i_highImageURI = svgToImageURI(highSvg);
    i_priceFeed = AggregatorV3Interface(priceFeedAddress);
}

function svgToImageURI(
    string memory svg
) public pure returns (string memory) {
    string memory svgBase64Encoded = Base64.encode(
        bytes(string(abi.encodePacked(svg)))
    );
    // ovo vraca onaj prefix odozgo i enkodira sliku u one brojeve i slova i spaja ta dva u 1 link gde  se moz vidi slikata
    return
        string(abi.encodePacked(base64EncodedSvgPrefix, svgBase64Encoded));
}

function mintNft(int256 highValue) public {
    s_tokenIdToHighValue[s_tokenCounter] = highValue;
    s_tokenCounter = s_tokenCounter + 1;

    _safeMint(msg.sender, s_tokenCounter);

    emit CreatedNFT(s_tokenCounter, highValue);
}

// ovde krecemo da pravimo metadata
function _baseURI() internal pure override returns (string memory) {
    // ovo je prefix za metadata
    return "data:application/json;base64,";
}

function tokenURI(
    uint256 tokenId
) public view override returns (string memory) {
    require(_exists(tokenId), "URI Query for nonexistent token");
    //string memory imageURI = "hi";

    (, int256 price, , , ) = i_priceFeed.latestRoundData();
    string memory imageURI = i_lowImageURI;

    if (price >= s_tokenIdToHighValue[tokenId]) {
        imageURI = i_highImageURI;
    }

    return
        string(
            abi.encodePacked(
                _baseURI(),
                Base64.encode(
                    bytes(
                        abi.encodePacked(
                            '{"name":"',
                            name(),
                            '", "description":"An NFT that changes based on the Chainlink Feed", ',
                            '"attributes": [{"trait_type": "coolness", "value": 100}], "image":"',
                            imageURI,
                            '"}'
                        )
                    )
                )
            )
        );
}

}
`
I am getting this error:

Any help will be appreciated.
Thank you :D

[tai9856]

I don't know why the _exists function is not in the ERC721.sol or wherever it's supposed to be. So I proceed and add this into the ERC721.sol

function _exists(uint256 tokenId) internal view returns (bool) {
        address owner = _ownerOf(tokenId);
        return owner != address(0);
    }

[Blockchain-Oracle]

require(_exists(tokenId), "URI Query for nonexistent token");

that above is only avaliable for version 4 of openzellian/contracts

this is the new syntax for version 5

/**
* @dev Reverts if the tokenId doesn't have a current owner (it hasn't been minted, or it has been burned).
* Returns the owner.
*
* Overrides to ownership logic should be done to {_ownerOf}.
*/

address owner = _ownerOf(tokenId);
       if (owner == address(0)) {
           revert ERC721NonexistentToken(tokenId);
       }

@LukaNikolic96 @PatrickAlphaC

remeber to mark this as anwer
happy coding!