Error: incorrect data length (argument="gasLane", value={"type":"BigNumber","hex":"0x2386f26fc10000"}, code=INVALID_ARGUMENT, version=abi/5.7.0)

[devcaii]

Hey guys, been having this issue for a bit so thought id come on here and see if anyone can help. I've fiddled around with it a bit and got a few different error codes, but they all relate to the args and the bignumber hex. Heres all my code down below.

Raffle.sol

// SPDX-License-Identifer: MIT
pragma solidity ^0.8.18;

import "@chainlink/contracts/src/v0.8/VRFConsumerBaseV2.sol";
import "@chainlink/contracts/src/v0.8/interfaces/VRFCoordinatorV2Interface.sol";
import "@chainlink/contracts/src/v0.8/interfaces/KeeperCompatibleInterface.sol";

error Raffle__NotEnoughETHEntered();
error Raffle__TransferFailed();
error Raffle__NotOpen();
error Raffle__UpkeepNotNeeded(uint256 currentBalance, uint256 numPlayers, uint256 raffleState);

contract Raffle is VRFConsumerBaseV2, KeeperCompatibleInterface {
	/* Type declaration */
	enum RaffleState {
		OPEN,
		CALCULATING
	}
	/** State variables */
	uint256 private immutable i_entranceFee;
	address payable[] private s_players;
	VRFCoordinatorV2Interface private immutable i_vrfCoordinator;
	bytes32 private immutable i_gasLane;
	uint64 private immutable i_subscriptionId;
	uint16 private constant REQUEST_CONFIRMATIONS = 3;
	uint32 private immutable i_callbackGasLimit;
	uint32 private constant NUM_WORDS = 1;

	/* Lottery Variables */
	address private s_recentWinner;
	RaffleState private s_raffleState;
	uint256 private s_lastTimeStamp;
	uint256 private immutable i_interval;

	/* Events */
	event RaffleEnter(address indexed player);
	event RequestedRaffleWinner(uint256 requestId);
	event WinnerPicked(address indexed winner);

	constructor(
		uint256 entranceFee,
		address vrfCoordinatorV2,
		bytes32 gasLane,
		uint64 subscriptionId,
		uint32 callbackGasLimit,
		uint256 interval
	) VRFConsumerBaseV2(vrfCoordinatorV2) {
		i_entranceFee = entranceFee;
		i_vrfCoordinator = VRFCoordinatorV2Interface((vrfCoordinatorV2));
		i_gasLane = gasLane;
		i_subscriptionId = subscriptionId;
		i_callbackGasLimit = callbackGasLimit;
		s_raffleState = RaffleState.OPEN;
		s_lastTimeStamp = block.timestamp;
		i_interval = interval;
	}

	function enterRaffle() public payable {
		if (msg.value < i_entranceFee) {
			revert Raffle__NotEnoughETHEntered();
		}
		if (s_raffleState != RaffleState.OPEN) {
			revert Raffle__NotOpen();
		}
		s_players.push(payable(msg.sender));
		emit RaffleEnter(msg.sender);
	}

	// This is the function that the chainlink keeper nodes call
	// they look for the upkeep needed to return true
	function checkUpkeep(
		bytes memory /* checkData */
	) public override returns (bool upkeepNeeded, bytes memory /* performData */) {
		bool isOpen = RaffleState.OPEN == s_raffleState;
		bool timePassed = ((block.timestamp - s_lastTimeStamp) > i_interval);
		bool hasPlayers = (s_players.length > 0);
		bool hasBalance = address(this).balance > 0;
		upkeepNeeded = (isOpen && timePassed && hasPlayers && hasBalance);
	}

	function performUpkeep(bytes calldata /* performData */) external {
		(bool upkeepNeeded, ) = checkUpkeep("");
		if (!upkeepNeeded) {
			revert Raffle__UpkeepNotNeeded(
				address(this).balance,
				s_players.length,
				uint256(s_raffleState)
			);
		}

		s_raffleState = RaffleState.CALCULATING;
		uint256 requestId = i_vrfCoordinator.requestRandomWords(
			i_gasLane, // gasLane
			i_subscriptionId,
			REQUEST_CONFIRMATIONS,
			i_callbackGasLimit,
			NUM_WORDS
		);
		emit RequestedRaffleWinner(requestId);
	}

	function fulfillRandomWords(
		uint256 /* requestId */,
		uint256[] memory randomWords
	) internal override {
		uint256 indexOfWinner = randomWords[0] % s_players.length;
		address payable recentWinner = s_players[indexOfWinner];
		s_recentWinner = recentWinner;
		s_raffleState = RaffleState.OPEN;
		s_players = new address payable[](0);
		s_lastTimeStamp = block.timestamp;
		(bool success, ) = recentWinner.call{value: address(this).balance}("");
		if (!success) {
			revert Raffle__TransferFailed();
		}
		emit WinnerPicked(recentWinner);
	}

	/* View / Pure functions */
	function getEntranceFee() public view returns (uint256) {
		return i_entranceFee;
	}

	function getPlayers(uint256 _index) public view returns (address) {
		return s_players[_index];
	}

	function getRecentWinner() public view returns (address) {
		return s_recentWinner;
	}

	function getRaffleState() public view returns (RaffleState) {
		return s_raffleState;
	}

	function getNumWords() public view returns (uint256) {
		return NUM_WORDS;
	}

	function getNumPlayers() public view returns (uint256) {
		return s_players.length;
	}

	function getLatestTimestamp() public view returns (uint256) {
		return s_lastTimeStamp;
	}

	function getRequestConfirmations() public pure returns (uint256) {
		return REQUEST_CONFIRMATIONS;
	}
}

00-deploy-mocks.js

const { network } = require("hardhat");
const { developmentChains } = require("../helper-hardhat-config");

const BASE_FEE = ethers.utils.parseEther("0.25");
const GAS_PRICE_LINK = 1e9; // calculated value based on the gas price of the chain

module.exports = async function ({ getNamedAccounts, deployments }) {
	const { deploy, log } = deployments;
	const { deployer } = await getNamedAccounts();
	const args = [BASE_FEE, GAS_PRICE_LINK];

	if (developmentChains.includes(network.name)) {
		log("local network detected");
		await deploy("VRFCoordinatorV2Mock", {
			from: deployer,
			log: true,
			args: args,
		});
		log("mocks deployed");
		log("--------------------------------");
	}
};

module.exports.tags = ["all", "mocks"];

01-deploy-raffle.js

const { network } = require("hardhat");
const { developmentChains, networkConfig } = require("../helper-hardhat-config");
const { verify } = require("../helper-hardhat-config");

const VRF_SUB_FUND_AMOUNT = ethers.utils.parseEther("30");

module.exports = async ({ getNamedAccounts, deployments }) => {
	const { deploy, log } = deployments;
	const { deployer } = await getNamedAccounts();
	const chainId = network.config.chainId;
	let vrfCoordinatorV2Address, subscriptionId;
	if (developmentChains.includes(network.name)) {
		const vrfCoordinatorV2Mock = await ethers.getContract("VRFCoordinatorV2Mock");

		vrfCoordinatorV2Address = vrfCoordinatorV2Mock.address;

		// create the subscription
		const transactionResponse = await vrfCoordinatorV2Mock.createSubscription();
		const transactionReciept = await transactionResponse.wait(1);
		subscriptionId = transactionReciept.events[0].args.subId;
		//fund the subscription
		await vrfCoordinatorV2Mock.fundSubscription(subscriptionId, VRF_SUB_FUND_AMOUNT);
	} else {
		vrfCoordinatorV2Address = networkConfig[chainId]["vrfCoordinatorV2"];
		subscriptionId = networkConfig[chainId]["subscriptionId"];
	}
	const entranceFee = networkConfig[chainId]["entranceFee"];
	console.log(entranceFee);
	const gasLane = networkConfig[chainId]["entranceFee"];
	const interval = networkConfig[chainId]["interval"];
	const callbackGasLimit = networkConfig[chainId]["callbackGasLimit"];
	const args = [
		entranceFee,
		vrfCoordinatorV2Address,
		gasLane,
		subscriptionId,
		callbackGasLimit,
		interval,
	];

	console.log(args);
	const raffle = await deploy("Raffle", {
		from: deployer,
		args: args,
		log: true,
		waitConfirmations: network.config.blockConfirmations || 1,
	});
	log("hey");

	if (!developmentChains.includes(network.name) && process.env.ETHERSCAN_API_KEY) {
		log("verifying");
		await verify(raffle.address, args);
	}
	log("-----------------------------");
};

module.exports.tags = ["all", "raffle"];

hardhat config

require("@nomiclabs/hardhat-waffle");
require("@nomiclabs/hardhat-etherscan");
require("hardhat-deploy");
require("solidity-coverage");
require("hardhat-gas-reporter");
require("hardhat-contract-sizer");
require("dotenv").config();

const SEPOLIA_PRIVATE_KEY = process.env.SEPOLIA_PRIVATE_KEY;
const SEPOLIA_RPC_URL = process.env.SEPOLIA_RPC_URL;

/** @type import('hardhat/config').HardhatUserConfig */
module.exports = {
	defaultNetwork: "hardhat",
	networks: {
		hardhat: {
			chainId: 31337,
			blockConfirmations: 1,
		},
		sepolia: {
			chainId: 11155111,
			blockConfirmations: 6,
			url: SEPOLIA_RPC_URL,
			accounts: [SEPOLIA_PRIVATE_KEY],
		},
	},
	solidity: "0.8.18",
	namedAccounts: {
		deployer: {
			default: 0,
		},
		player: {
			default: 1,
		},
	},
};

helper hardhat config

const networkConfig = {
	11155111: {
		name: "sepolia",
		vrfCoordinatorV2: "0x8103B0A8A00be2DDC778e6e7eaa21791Cd364625",
		entranceFee: ethers.utils.parseEther("0.01"),
		gasLane: "0x474e34a077df58807dbe9c96d3c009b23b3c6d0cce433e59bbf5b34f823bc56c",
		subscriptionId: "0",
		callbackGasLimit: "500000",
		interval: "30",
	},
	31337: {
		name: "hardhat",
		entranceFee: ethers.utils.parseEther("0.01"),
		gasLane: "0x474e34a077df58807dbe9c96d3c009b23b3c6d0cce433e59bbf5b34f823bc56c",
		callbackGasLimit: "500000",
		interval: "30",
	},
};

const developmentChains = ["hardhat", "localhost"];

module.exports = { networkConfig, developmentChains };

Any help or insight would be amazing. I couldnt find many people with similar issues. I checked if the args were in the same order as my constructorargs in solidity, since another person got a similar error from that, and they were.

The full error is

Error: ERROR processing /Users/cai/Documents/Code/solidity-learning/back-end/deploy/01-deploy-raffle.js:
Error: incorrect data length (argument="gasLane", value={"type":"BigNumber","hex":"0x2386f26fc10000"}, code=INVALID_ARGUMENT, version=abi/5.7.0)
    at Logger.makeError (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/logger/src.ts/index.ts:269:28)
    at Logger.throwError (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/logger/src.ts/index.ts:281:20)
    at Logger.throwArgumentError (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/logger/src.ts/index.ts:285:21)
    at FixedBytesCoder.Coder._throwError (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/abi/src.ts/coders/abstract-coder.ts:68:16)
    at FixedBytesCoder.encode (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/abi/src.ts/coders/fixed-bytes.ts:23:47)
    at /Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/abi/src.ts/coders/array.ts:71:19
    at Array.forEach (<anonymous>)
    at pack (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/abi/src.ts/coders/array.ts:54:12)
    at TupleCoder.encode (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/abi/src.ts/coders/tuple.ts:54:20)
    at AbiCoder.encode (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/@ethersproject/abi/src.ts/abi-coder.ts:111:15)
    at DeploymentsManager.executeDeployScripts (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/hardhat-deploy/src/DeploymentsManager.ts:1225:19)
    at processTicksAndRejections (node:internal/process/task_queues:95:5)
    at runNextTicks (node:internal/process/task_queues:64:3)
    at listOnTimeout (node:internal/timers:533:9)
    at processTimers (node:internal/timers:507:7)
    at DeploymentsManager.runDeploy (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/hardhat-deploy/src/DeploymentsManager.ts:1055:5)
    at SimpleTaskDefinition.action (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/hardhat-deploy/src/index.ts:438:5)
    at Environment._runTaskDefinition (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/hardhat/src/internal/core/runtime-environment.ts:330:14)
    at Environment.run (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/hardhat/src/internal/core/runtime-environment.ts:163:14)
    at SimpleTaskDefinition.action (/Users/cai/Documents/Code/solidity-learning/back-end/node_modules/hardhat-deploy/src/index.ts:584:32)

[pratokko]

Hello you are assigning the gasLane to entranceeFee
replace this line

const gasLane = networkConfig[chainId]["entranceFee"];

with this

const gasLane = networkConfig[chainId]["gasLane"];

[devcaii]

cheers mate, such a stupid mistake haha. Well atleast now i wont make it again. Thanks a lot