Chapter 7: Can we use AggregatorV3Interface like below in our contract (Different from Patrick code)?

[sanjayojha]

So instead of going like how Patrick told to use AggregatorV3Interface priceFeed by passing it thru constructor of FundMe.sol can we do same with following code?

File FundMe.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.8;

// removing chainlink Aggregator import 
import "./PriceConverter.sol";

error NotOwner();

contract FundMe {
  using PriceConverter for uint256;

  uint256 public constant MINIMUM_USD = 50 * 1e18;

  address[] public funders;
  mapping(address => uint256) public addressToAmountFunded;

  address public immutable OWNER;
  address public s_priceFeed; //I removed the AggregatorV3Interface

  constructor(address PriceFeed) {
    OWNER = msg.sender;
    s_priceFeed = PriceFeed;
  }

  modifier onlyOwner() {
    if (msg.sender != OWNER) {
      revert NotOwner();
    }
    _;
  }

  function Fund() public payable {
   
    require(
      msg.value.getConversionRate(s_priceFeed) >= MINIMUM_USD,
      "ETH is not enough!"
    );
    funders.push(msg.sender);
    addressToAmountFunded[msg.sender] = msg.value;
  }
 ...
}

file PriceConverter.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.8;

import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

library PriceConverter {
  function getPrice(address s_priceFeed) internal view returns (uint256) {
   
    AggregatorV3Interface priceFeed = AggregatorV3Interface(
            s_priceFeed
    );
    (, int256 price, , , ) = priceFeed.latestRoundData();

    // price is upto 8 decimal place. So if price of eth is 1555usd.. it will return 155500000000.
    //lets convert it in wei (1e18).
    return uint256(price * 1e10); // 1**10 (10000000000).
  }

  function getConversionRate(uint256 ethAmount, address priceFeed) internal view returns (uint256) {
    uint256 ethPrice = getPrice(priceFeed);
    uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1e18;
    //we divided to 1e18 because after multiplication it will become 1e36.
    //So we can say that we either changed the wei to eth (ethAmount) or we converted price (ethPrice) to normal (removed 18 decimal)

    return ethAmountInUsd; // this is in 18 decimal place in usd.
  }
}

So I basically remove the AggregatorV3Interface from FundMe.sol and passed the contract address from chainlink as variable in its constructor. Thus removing the dependency of of @chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol from FundMe.sol file.

Or will it make error?

[alymurtazamemon]

@sanjayojha Yes, both ways will work, the purpose is to get the aggregator v3 interface.

[sanjayojha]

@ali-thegilfoyle thank you for confirmation. Purpose of refactoring my code was to keep theimport "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol"; only in PriceConverter.sol file.