Lesson4:Getting gas estimation error

[saurav3232]

The Fundme.sol code

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;
import "./PriceConvertor.sol";
contract FundMe{
    using PriceConvertor for uint256;
    uint256 public minimumUsd = 50 * 1e18;
    
    // Store the address of all the users who are funding
    address [] public funders;
    // Maintain a map of funders with their funding amount
    mapping(address => uint256) public addressToAmountFunded;
    // Payable ensures that the function can send and receive Ether.
    address public owner;
    constructor(){
        owner = msg.sender;
    }
    function fund() public payable{
        // Want to be able to set a minimum fund amount in USD
        // 1.How do we send eth to this account
        require (msg.value.getConversionRate()>=minimumUsd,"Didn't send enough!");
        // The transaction will revert back if available fund is not enough that is the amount spend on gas will be returned
        funders.push(msg.sender);
        // The below line signifies that the current funder if does multiple funds then 
        // the funds will be added to the current map[funder]
        addressToAmountFunded[msg.sender]+=msg.value;
    }
    // function that can be called only by the owner
    function withdraw() public payable onlyOwner{
        
        for(uint256 funderIndex= 0; funderIndex<funders.length;funderIndex++)
        {
            address funder=funders[funderIndex];
            addressToAmountFunded[funder]=0;
        }
        // Reset the array(It will point to a new address with 0 funders in it
        funders = new address[](0);
        // actually withdraw the funds

        // transfer
        // msg.sender-->address type
        // payable(msg.sender)-->payable address
        // payable(msg.sender).transfer(address(this).balance);//-->automatically revert the 
        // transaction if gas amount is greater than 23000
        
        // send
        // bool sendSuccess = payable(msg.sender).send(address(this).balance);
       // require(sendSuccess,"Send failed");//Only revert if we add require statement
        // call
        (bool callSuccess, ) = payable(msg.sender).call{value:address(this).balance}("");
        require(callSuccess,"Call failed");
    }
    modifier onlyOwner{
        // requires the owner  
        // The sequence of the code and '_' matters as bcz when we include the modifier
        // In any function first the require statemnt will run and then rest of the code
        // represented by the '_'
        require(msg.sender == owner, "Sender is not owner");
        _;
    }
}

The PriceConvertor.sol code:

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;
// Using the chainlink to use the api to get price of eth to Usd
import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";
library PriceConvertor{
    function getPrice() internal view returns(uint256){
        // ABI 
        // Address 0xD4a33860578De61DBAbDc8BFdb98FD742fA7028e
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xD4a33860578De61DBAbDc8BFdb98FD742fA7028e);
        // (uint80 roundId, int price, uint startedAt, uint timeStamp, uint80 answeredInRound)= priceFeed.latestRoundData();
        // we won't require all the above specified so we can leave them as ','
        (, int256 price,,,)= priceFeed.latestRoundData();
        // ETH in terms of USD
        // 3000.0000000 
        return uint256(price*1e10);//1**10==1000000000
    }
    function getVersion() internal view returns (uint256){
        AggregatorV3Interface priceFeed= AggregatorV3Interface(0xD4a33860578De61DBAbDc8BFdb98FD742fA7028e);
        return priceFeed.version();
    }
    function getConversionRate(uint256 ethAmount) internal view returns (uint256) {
        uint256 ethPrice = getPrice();
        uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1e18;
        return ethAmountInUsd; 
    }
}

The Error while deploying

> Gas estimation errored with the following message (see below). The transaction execution will likely fail. Do you want to force sending?
execution reverted

I have 0.236 eth in goerili test net

[pacelliv]

Make sure the input Value for Wei is in zero, recompile, and hit deploy.

[saurav3232]

Yes I have already tried it, I am using 0.04 eth(converted to Wei) to deploy the contract on goeril testnet ,Can you please test the code on your end and verify the same

[pacelliv]

I deployed your contracts with no problem.

Before deploying your contract the Value input should look like this:

After the deployment you will specify the ethAmount you will send to fund your contract by calling the fund function.

[pacelliv]

@saurav3232 with current ETH price 0.04 is not enough, increase the amount.

[saurav3232]

Oh I was deploying with the eth amount, that was the problem, Thank you so much!