Lesson14: CallAnything.sol - bool: false

[DorianDaSilva]

Timestamp: 22:56:45

Issue: When trying to call callTransferFunctionDirectly() using contract address in remix it returns bool: false instead of true

Same issue repeats itself with function callTransferFunctionDirectlySig(address someAddress, uint256 amount) but bool doesn't even show in the transaction receipt.

Not sure what I missed (PS: Solidity version has no impact on result on my end)

====================================================================================

callAnything.sol

pragma solidity ^0.8.9;

contract CallAnything {
    address public s_someAddress;
    uint256 public s_amount;

    function transfer(address someAddress, uint256 amount) public {
        s_someAddress = someAddress;
        s_amount = amount;
    }

    function getSelectorOne() public pure returns(bytes4 selector){
        selector = bytes4(keccak256(bytes("transfer(address, uint256)")));
    }

    function getDataToCallTransfer(address someAddress, uint256 amount) public pure returns(bytes memory){
        return abi.encodeWithSelector(getSelectorOne(), someAddress, amount);
    }

    function callTransferFunctionDirectly(address someAddress, uint256 amount) public returns(bytes4, bool){
        (bool success, bytes memory returnData) = address(this).call(
            //getDataToCallTransfer(someAddress, amount);
            abi.encodeWithSelector(getSelectorOne(), someAddress, amount)
        );
        return (bytes4(returnData), success);
    }
    
    function callTransferFunctionDirectlySig(address someAddress, uint256 amount) public returns(bytes4, bool){
        (bool success, bytes memory returnData) = address(this).call(
            //getDataToCallTransfer(someAddress, amount);
            abi.encodeWithSignature("transfer(address, uint256)", someAddress, amount)
        );
        return (bytes4(returnData), success);
    }
}

[simpleitis]

Did you get a fix? I am also facing the same issue

[castlenick]

copy/pasting your code into Remix, it works if I remove the space in the assignment of selector in getSelectorOne()

i.e., this:

    function getSelectorOne() public pure returns(bytes4 selector){
        selector = bytes4(keccak256(bytes("transfer(address,uint256)")));
    }

instead of this:

    function getSelectorOne() public pure returns(bytes4 selector){
        selector = bytes4(keccak256(bytes("transfer(address, uint256)")));
    }

the compiler won't notice because it's just a string input. I had a similar issue (missing end parenthesis)