Lesson 4: Declaration Error: Undeclared Identifier

[rarddd]

Hi I am having an issue w/ compiling my code. I am getting a declaration error, and I don't know where to start.

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

contract FundMe{

    uint256 public minimumUsd = 50 * 1e18;

    address[] public funders;
    mapping(address => uint256) public addressToAmountFunded;

    function fund() public payable{
      require (msg.value.getConversionRate() >= minimumUsd, "Didn't send enough");   
      funders.push(msg.sender);
      addressToAmountFunded[msg.sender] = msg.value;
    }
    
    constructor() {
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xAc559F25B1619171CbC396a50854A3240b6A4e99);
    }
    function getPrice() public view returns (uint256) {
        // ABI
        // Address 0xAc559F25B1619171CbC396a50854A3240b6A4e99
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xAc559F25B1619171CbC396a50854A3240b6A4e99);
        (,int price,,,) = priceFeed.latestRoundData();
        return uint256(price * 1e10);
    }
        
    function getVersion() public view returns (uint256) {
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xAc559F25B1619171CbC396a50854A3240b6A4e99);
        return priceFeed.version();
        return uint256(price * 1e10);
    }

    function getConversionRate(uint256 ethAmount) public view returns (uint256) {
        uint256 ethPrice = getPrice();
        uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1e18;
        return ethAmountInUsd;
    }

    //function withdraw(){}
}

Issue is one line 34, I have additional things in the code like constructor or array because I decided to cotinue with the video because I got stuck for a little bit. Any help? Thanks.

When I remove the "return uint256(price * 1e10);" I get this result.

[SidharthK2]

Please attach a screenshot of the error with code

[krakxn]

@rarddd Problem lies here:

function getVersion() public view returns (uint256) {
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xAc559F25B1619171CbC396a50854A3240b6A4e99);
        return priceFeed.version();
        return uint256(price * 1e10);
    }

In the above, remove the extraneous return uint256(price * 1e10);, doing so will fix the issue.

[alymurtazamemon]

@rarddd Provide more info about the error, I am seeing that you are using a different address, are you using a different ETH/USD address than Rinkeby because it is different? And second thing, you are returning multiple times in getVersion function.

[rarddd]

Ok thank you I will change it.

[othaime-en]

Hey @rarddd I'm seeing there is a problem in the function declaration here

function getVersion() public view returns (uint256) {
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xAc559F25B1619171CbC396a50854A3240b6A4e99);
        return priceFeed.version();
        return uint256(price * 1e10);
    }

You've said your function will return one uint256 value but you are returning two.
Either delete the extra return value return uint256(price * 1e10);
OR add an extra uint256 parameter in the returns sections i.e. function getVersion() public view returns (uint256, uint256){}

[rarddd]

I will try adding an extra uint256 parameter tomorrow, ty.

[othaime-en]

Hey @rarddd there's a couple issues with your code as it is. The error you are getting here require (msg.value.getConversionRate() >= minimumUsd, "Didn't send enough"); is because you are trying to use the .getConversionRate() as if it were a library function attached to the type uint256 which in your case, you haven't attached any library function on the uint256 type.
So to make this work, you're gonna have to do a couple things.

1. You need to rewrite your FundMe.sol and move all the price conversion functionalities (getPrice(), getConversionRate() ) into another file in the form of a library
2. Then import that library file into your FundMe.sol
3. And attach the library functions to the type uint256 through the using keyword within your FundMe contract.

In the end, you code should look like this.
PriceConverter.sol This is the new library file we have created

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

// Why is this a library and not abstract?
// Why not an interface?
library PriceConverter {
    // We could make this public, but then we'd have to deploy it
    function getPrice() internal view returns (uint256) {
        // Rinkeby ETH / USD Address
        // https://docs.chain.link/docs/ethereum-addresses/
        AggregatorV3Interface priceFeed = AggregatorV3Interface(
            0x8A753747A1Fa494EC906cE90E9f37563A8AF630e
        );
        (, int256 answer, , , ) = priceFeed.latestRoundData();
        // ETH/USD rate in 18 digit
        return uint256(answer * 10000000000);
    }

    // 1000000000
    function getConversionRate(uint256 ethAmount) internal view returns (uint256) {
        uint256 ethPrice = getPrice();
        uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1000000000000000000;
        // the actual ETH/USD conversion rate, after adjusting the extra 0s.
        return ethAmountInUsd;
    }
}

FundMe.sol The new FundMe.sol should look like this.

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./PriceConverter.sol";  // Importing the library file
import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

contract FundMe{
    using PriceConverter for uint256; // Attaching the library file into our

    uint256 public minimumUsd = 50 * 1e18;

    address[] public funders;
    mapping(address => uint256) public addressToAmountFunded;

    function fund() public payable{
      require (msg.value.getConversionRate() >= minimumUsd, "Didn't send enough");   
      funders.push(msg.sender);
      addressToAmountFunded[msg.sender] = msg.value;
    }
    function getVersion() public view returns (uint256) {
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0xAc559F25B1619171CbC396a50854A3240b6A4e99);
        return priceFeed.version();
        // Remove this: return uint256(price * 1e10);
    }

    //function withdraw(){}
}

Try this and tell me if it works.

[othaime-en]

If you don't get what is happening here, I strongly suggest you start over lesson 4. In fact, either way, you should start over the lesson since you got lost in the way.

[rarddd]

Thank you appreciate it, I'll review lesson 4.