Talos 1.10+ uses 1.9.2 installer image (& fails)

[p5]

I am downloading the v1.10.1 ISO and booting into it in Proxmox. Unfortunately when I apply the installation with the following, the VM pulls the installer image tagged with :1.9.2. This then fails with, what I assume to be, due to breaking changes from the 1.10.0 release.

How can I force the installer image tag to be the same as the ISO I downloaded?

data "talos_machine_configuration" "control_plane" {
  cluster_name       = var.cluster_name
  cluster_endpoint   = "https://${var.cluster_vip}:6443"
  machine_secrets    = talos_machine_secrets.this.machine_secrets
  machine_type       = "controlplane"
  talos_version      = "v1.10.1"
  kubernetes_version = "1.33.0"
  config_patches = [
    yamlencode({
      machine = {
        install = {
          disk = "/dev/vda"
        }
        network = {
          interfaces = [
            {
              interface = "eth0"
              vip = {
                ip = var.cluster_vip
              }
            }
          ]
        }
      }
    }),
  ]
}

https://download.eternal.sturla.tech/Screen%20Recording%202025-05-08%20at%2000.53.22.mov

[rothgar]

What version of the terraform provider are you using? 0.8.0 added support for Talos 1.10

[p5]

Ah, that might be it - I am pinned to 1.7.2.
Will update and report back in 10ish mins.

Thank you!

[p5]

This seemed to fix the primary problem of the failed install, though I still seem to be on v1.10.0, rather than v1.10.1.
This might just be my lack of understanding for how installs & updates work, so I'll try re-reading the docs in more detail.

Thank you for the help Justin!

[p5]

This second issue was resolved by hardcoding the installer image into the machine config.

data "talos_machine_configuration" "control_plane" {
  cluster_name       = var.cluster_name
  cluster_endpoint   = "https://${var.cluster_vip}:6443"
  machine_secrets    = talos_machine_secrets.this.machine_secrets
  machine_type       = "controlplane"
  talos_version      = "v${var.talos_version}"
  kubernetes_version = var.kubernetes_version
  config_patches = [
    yamlencode(local.common_machine_config),
    yamlencode({
      machine = {
        install = {
          disk  = "/dev/vda"
          image = "ghcr.io/siderolabs/installer:v${var.talos_version}"
        }
        network = {
          interfaces = [
            {
              interface = "eth0"
              vip = {
                ip = var.cluster_vip
              }
            }
          ]
        }
      }
    }),
  ]
}

I am facing some other issues with this newer version, but will keep this discussion scoped to only the "installed image does not match the iso" case.

[frezbo]

when using Terraform if the install image is not specified it'll default to the Talos SDK version shipped with the Terraform provider, so it's necessary to set the install image specifically

[smira]

And also keep in mind if you're on Proxmox and you're using nocloud platform, the installer should come from the Image Factory with a proper platform (navigate to https://factory.talos.dev/ and follow the prompts to see the installer you need).