feat: add R SPCS demo

Author: sfc-gh-vtimofeenko

demos/r-spcs/README.md

@@ -0,0 +1,47 @@
+This is a small demo that builds on top of the TTYD demo and shows how
+interactive R can be run in SPCS. The provided code shows how to establish
+connection using ODBC driver and OAUTH authentication that leverages SPCS token.
+
+# Prerequisites
+
+1. SPCS service set up with ttyd service and a network policy that allows access
+   to cache.nixos.org
+
+2. `SNOWFLAKE_SAMPLE_DATA` setup in account
+3. A virtual warehouse accessible to the role that owns SPCS service
+
+# Result
+
+Run following in bash:
+
+```shell
+nix develop "github:sfc-gh-vtimofeenko/spcs-ttyd?dir=demos"
+```
+
+This will start a development shell with Snowflake ODBC driver and R REPL with
+the needed packages pre-installed.
+
+Run following R code to get some sample data from CUSTOMER table in the sample
+data set:
+
+```R
+snowflake_token <- readLines("/snowflake/session/token", warn = FALSE)
+con <- DBI::dbConnect(odbc::odbc()
+                      , "SnowflakeDSII"
+                      # account and server are needed
+                      , token = snowflake_token
+                      , authenticator = 'oauth'
+                      , port = 443
+                      , warehouse = "ADHOC"
+                      , ssl = 'on'
+ )
+data <- dbGetQuery(con,"SELECT * FROM SNOWFLAKE_SAMPLE_DATA.TPCH_SF1.CUSTOMER LIMIT 100")
+head(data)
+
+```
+
+# Further reading
+
+* [Running R-Studio in Snowpark Container Services][1]
+
+[1]: https://medium.com/@gabriel.mullen/running-rstudio-in-snowpark-container-services-1a71128b2474

demos/r-spcs/flake.nix

@@ -0,0 +1,71 @@
+{
+  description = "Description for the project";
+
+  inputs = {
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+  };
+
+  outputs =
+    inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+      ];
+      perSystem =
+        { self'
+        , pkgs
+        , ...
+        }:
+        {
+          packages = rec {
+            default = snowflake-odbc-driver;
+            snowflake-odbc-driver = pkgs.callPackage ./snowflake-odbc-driver.nix { };
+          };
+
+          devShells.default = pkgs.stdenv.mkDerivation {
+            name = "my-snowflake-odbc-project";
+            buildInputs = [
+              self'.packages.snowflake-odbc-driver
+              pkgs.envsubst
+            ];
+            nativeBuildInputs = [
+              pkgs.unixODBC
+              (pkgs.rWrapper.override {
+
+                packages = with pkgs.rPackages; [
+                  DBI
+                  dplyr
+                  dbplyr
+                  odbc
+                ];
+              })
+            ];
+            shellHook =
+              let
+                ODBCINI = pkgs.writeTextDir "odbc.ini" ''
+                  [ODBC Data  Sources]
+                  SnowflakeDSII = Snowflake
+                  [SnowflakeDSII]
+                  SERVER = ''${SNOWFLAKE_HOST}
+                  account = ''${SNOWFLAKE_ACCOUNT}
+                  Port = 443
+                  SSL = on
+                  Locale = en-US
+                  Tracing = 0
+                  # Oauth stuffs
+                  authenticator=OAUTH
+                  token= ''${SNOWFLAKE_TOKEN}
+                '';
+              in
+              ''
+                export SNOWFLAKE_TOKEN=$(cat /snowflake/session/token)
+                envsubst < ${ODBCINI}/odbc.ini > ./odbc.ini
+                # Looks like it needs to be in a writeable location?
+                export ODBCINI=$(realpath ./odbc.ini)
+              '';
+          };
+        };
+    };
+}

demos/r-spcs/snowflake-odbc-driver.nix

@@ -0,0 +1,48 @@
+{ stdenv
+, lib
+, unixODBC
+, openssl
+, fetchurl
+,
+}:
+let
+  version = "3.5.0";
+  sources = {
+    "x86_64-linux" = {
+      url = "https://sfc-repo.snowflakecomputing.com/odbc/linux/${version}/snowflake_linux_x8664_odbc-${version}.tgz";
+      sha256 = "sha256-PaYX3Bgt4zqU9f1lUjYtDct685Fgk6LTQBi2K27j/lQ=";
+    };
+    "aarch64-linux" = {
+      url = "https://sfc-repo.snowflakecomputing.com/odbc/linuxaarch64/${version}/snowflake_linux_aarch64_odbc-${version}.tgz";
+      sha256 = "sha256-MORf5kY5b6059jsr4egPwBc0c3FXMEI8+p446EqY8fk=";
+    };
+  };
+in
+stdenv.mkDerivation {
+  pname = "snowflake-odbc-driver";
+  inherit version;
+  src = fetchurl sources.${stdenv.hostPlatform.system};
+
+  # Basically use precompiled so
+  installPhase = ''
+    mkdir -p $out/lib
+    cp -r lib/* $out/lib
+    cp -r ErrorMessages/en-US $out/lib
+  '';
+
+  postFixup = ''
+    patchelf --set-rpath ${
+      lib.makeLibraryPath [
+        unixODBC
+        openssl
+        stdenv.cc.cc
+      ]
+    } \
+      $out/lib/libSnowflake.so
+  '';
+
+  passthru = {
+    fancyName = "SnowflakeDSIIDriver";
+    driver = "lib/libSnowflake.so";
+  };
+}