Code only works if I used a older version of this library

[Kaaydong]

So I've been using this library for a while now on a project and recently ran into some issues, so I decided to update this library to the latest version. After updating the library, nothing worked at all. So I made a simple tester to see what happens between the two libraries.

void setup(){

   // ... Other setup with SD card, etc

   audio.setPinout(I2S_BCLK, I2S_LRC, I2S_DOUT); 
   audio.setVolume(10);
   audio.connecttoFS(SD,"Seatbelt.mp3");
}

void loop() {
  // put your main code here, to run repeatedly:
  audio.loop();
}

So when I tested this code with this library I pulled from 9/24/2022, everything works fine. I tried using the most updated version of the library and it seems that the sound doesn't want to play.

So pretty much what I am trying to ask is, what changes to this code needs to be done in order for it to work with the newest version of the library? I tried looking at the updated examples and I can't seem to find a reason why this shouldn't work.

[schreibfaul1]

It is difficult to determine the error. Is the ESP32 Arduino version up to date?

[Kaaydong]

Thanks for the quick reply!
I believe the ESP32 version is up to date. My Board Manager says its version 2.0.6 which I installed just yesterday.

On the off chance that I have to just stick with the older library. Would you be able to help me with my original problem? For some reason, the audio.getAudioFileDuration() method would always return a 0 no matter what I did. The mp3 file in the sample above should have returned 3 or 4.
The reason why I need the audio file duration is because I want be able to audio.loop() and stop around the time the actual sound file is over, using a while loop without having to hardcode the actual duration. Would you know an alternative way to do this?
An example to what I am talking about it this

    long starttime = millis();
    long endtime = starttime;

    while ((endtime - starttime) <= 4000)   // 4000 should be replaced with actual file duration
    {
      audio.loop();
      endtime = millis();
    }

[schreibfaul1]

this example will work

#include "Arduino.h"
#include "Audio.h"
#include "SD_MMC.h"
#include "Ticker.h"

Audio audio(false, 3, 0);

Ticker ticker20;
boolean f_start = false;

#define I2S_LRC     26
#define I2S_DOUT    25
#define I2S_BCLK    27
#define I2S_MCLK     0

#define SD_MMC_D0   2
#define SD_MMC_CLK  14
#define SD_MMC_CMD  15

void tck20(){ // 50 times/sec
    uint32_t t = audio.getAudioCurrentTime();
    if(t == 20 && f_start){
        audio.stopSong();
        Serial.printf("song stopped at %i s\n", t);
        t = 0;
        f_start = 0;
    }
}


void setup() {
    Serial.begin(115200);
    uint32_t idf = ESP_IDF_VERSION_PATCH + ESP_IDF_VERSION_MINOR *10 + ESP_IDF_VERSION_MAJOR * 100;
    uint32_t ard = ESP_ARDUINO_VERSION_PATCH + ESP_ARDUINO_VERSION_MINOR * 10 + ESP_ARDUINO_VERSION_MAJOR * 100;
    log_i("ESP32 IDF Version %d.%d.%d", idf/100%10, idf/10%10 , idf%10);
    log_i("ESP32 Arduino Version %d.%d.%d", ard/100%10, ard/10%10 , ard%10);

    pinMode(SD_MMC_D0, INPUT_PULLUP);

    if(!SD_MMC.begin( "/sdcard", true, false, 20000)){
        Serial.println("Card Mount Failed");
        return;
    }
    Serial.setDebugOutput(true);
    audio.setPinout(I2S_BCLK, I2S_LRC, I2S_DOUT, -1, -1);
    Serial.printf("ARDUINO_LOOP_STACK_SIZE %d words (32 bit)\n", CONFIG_ARDUINO_LOOP_STACK_SIZE);
    ticker20.attach_ms(20, tck20);
    audio.connecttoFS(SD_MMC, "/mp3files/Helikopter117.mp3");
    f_start = true;
}

void loop(){
    audio.loop();
}

// optional
void audio_info(const char *info){
    Serial.print("info        "); Serial.println(info);
}
void audio_id3data(const char *info){  //id3 metadata
    Serial.print("id3data     ");Serial.println(info);
}
void audio_eof_mp3(const char *info){  //end of file
    Serial.print("eof_mp3     ");Serial.println(info);
}

[Kaaydong]

Thank you so much for the help! Turns out that this was all I needed....

void audio_eof_mp3(const char *info){  //end of file
    Serial.print("eof_mp3     ");Serial.println(info);
}

The sketch you sent kind of works for both versions of the library, like sound plays, but there are still problems with the ticker and the id3 data being printed. So at this point it might just be a hardware problem.

Again, thank you so much for the help, and I absolutely love your library it is so helpful!