SBC decoded discussion

[aqildad-create]

i am getting framelen: -1 and framelen: -2 what this -1 and -2 ? and what is frame length ?

Also i am getting decoded bytes always zero 0 why ?

I feed manually 16 byte array and display the decoded out put . In same pattern encoder is working

see the minimal code and log

#include "AudioTools.h"
#include "AudioCodecs/CodecSBC.h"
AudioInfo to(44100, 2, 16);
SBCDecoder Decoder;
RingBufferStream streamout;
void setup(void) {
Serial.begin(115200);
AudioLogger::instance().begin(Serial, AudioLogger::Info);
Decoder.begin();
Decoder.setOutputStream(streamout);
static uint8_t buffer[512]={156,185,32,202,0,0,0,0,0,0,0,0,85,85,85,85};
Decoder.write(buffer, 15);
int bytesC = streamout.available () ;
Serial.println("decoded bytes :"+String(bytesC));
streamout.readBytes(buffer, bytesC);

for(int aa=0;aa<bytesC;aa++) // view decoded data
Serial.println(String(aa)+":"+buffer[aa]);
}
void loop() {
}

////////////////////////////

[I] CodecSBC.h : 48 - virtual void audio_tools::SBCDecoder::begin()
[I] CodecSBC.h : 79 - framelen: -1
decoded bytes :0

[pschatzmann]

You're really pulling your own leg here!

Each encoder uses a different logic and this complexity has been abstracted away by my API. It has however the expectation that you constantly feed it data, and it splits the data up automatically dependent on the rule of the encoder.

The underlying SBC encoder expects data of a defined length as input (=code size) and translates it to a result of constant length (=frame size); As indicated in my last anwer you can query the API what these sizes are for the selected parameters.

If you don't get any result you were just breaking this contract and you did not provide enough data to be processed...

[aqildad-create]

Thanks for the answer .

Actually i have data coming from Espnow . Out of 256 bytes i have 240 bytes of audio data and 16bytes some other information .
Esp32 receiver split 256 bytes and send 240 bytes to your audio decoder(Which is SBC DECODER ) and then uncompressed data to i2s dac . And at same time process other work with remaining 16 bytes . i don't want to mess with your ESp now example as my ESPNOW is working and also i have WIFI connected with to it , Any how ESPnow is different topic , and i will discus about ESPnow in some other threats .

For now i have array for about 240 bytes , i want to pas to SBC decoder and then out to i2s stream . I try this but fall in above minimal code .

YOU SAID THIS " you can query the API what these sizes are for the selected parameters " .. I am confuse how to query these sizes ? also their is fix bytes array to feed to SBC decoder if yes what is that size ? If yes i will merge multiple 240 bytes to complete the required size .

For now my problem is how feed 240 or other amount of bytes to SBC decoder and then out data to i2s ?? If you provide minimal code for this I will really thank full and also i go through all your example OF DECODER but cant find a way put of this . your expert opinion is required .

[pschatzmann]

No, that's not at all what you are doing: You pass it only 15 bytes and not 240!
You can query the code size by calling bytesUncompressed() and you get the frame size by calling bytesCompressed() method.

I do not know by heart what the actual values are, nor do I care!

The important thing to take out of it is to note that the values can change and depend on the parameters that you provide (via the constructor).

[pschatzmann]

If you want to send information of different type thru the wire you could implement your own framing protocol. I suggest that you get some inspiration by looking at the SimpleContainer.h

[aqildad-create]

THIS BELOW IMAGE I WANT TO ACHEVE .

THE FRST PART IS COMPLETE NOW I FEED THE DATA TO PART 2 DECODER
BUT OUT PUT OF DECODER IS UNCHANGED ( I STILL DONT KNOW HOW TO GET OUT ARRAY FROM DECODER AND WHY ITS UNCHANGED )

int bytesC = streamout.available() ; -------------> WHY THIS RETURN ZERO ?
streamout.readBytes(buffer, 512);----------------> WHY THE BUFFER I GET IS SAME AS I WRTE NO CHANGE WHY ?
RingBufferStream --------------------------------> DOES RING BUFFER STREAM ALSO WORK WTH DECODER OUT PUT? IF YES WHY THE ARRAY IS UNCHANGED ?

BELOW IS THE MNMAL CODE

#include "AudioTools.h"
#include "AudioCodecs/CodecSBC.h"
AudioInfo to(44100, 2, 16);
RingBufferStream streamout;
SBCDecoder Decoder;
void setup(void) {
Serial.begin(115200);
AudioLogger::instance().begin(Serial, AudioLogger::Info);
Decoder.begin();
Decoder.setOutputStream(streamout);
static uint8_t buffer[512]={156,185,32,202,0,0,0,0,0,0,0,0,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85,85};
Decoder.write(buffer, 240);
int frameLength=Decoder.frameLength () ;int codeSize =Decoder.codeSize () ;
Serial.println(String(frameLength)+"/"+String(codeSize));

int bytesC = streamout.available () ;
Serial.println("decoded bytes :"+String(bytesC));
//int bytesCompressed=Decoder.bytesCompressed(); //---------- THROUGH ERROR
//int bytesUncompressed =Decoder.bytesUncompressed(); //-------THROUGH ERROR
//Serial.println("bytesCompressed :"+String(bytesCompressed)+ "bytesUncompressed :"+String(bytesUncompressed));
streamout.readBytes(buffer, bytesC);
for(int aa=0;aa<512;aa++) // view decoded data
Serial.print(String(buffer[aa])+" ");
}
void loop() {
}

[I] CodecSBC.h : 48 - virtual void audio_tools::SBCDecoder::begin()
[I] CodecSBC.h : 120 - channels: 2
[I] CodecSBC.h : 139 - sample_rate: 44100
[I] CodecSBC.h : 164 - input_buffer: 76-----------------------------------------> WHAT IS NPUT BUFFER I AM CONFUSE ?
[I] CodecSBC.h : 79 - framelen: 76----------------------------------------------> WHAT IS FRAME LENGTH ?
76/512
decoded bytes :0
156 185 32 202 0 0 0 0 0 0 0 0 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 85 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0

[pschatzmann]

I don't understand why you want to reinvent the wheel again: This is exactly what this test example is doing!

If you want to look at the resulting data just replace the AudioKitStream with a CsvStream<int16_t>!

[aqildad-create]

Wth CsvStream I can only view/looK the data either in seral or plotter .i need to perform some mathematical operation with the data so that why i need resulting data in some sort of array

[pschatzmann]

What kind of operation would you want to do ?

[aqildad-create]

I my application encoder is in ESP1 and decoder running in ESP2 . ( Its not issue )

problem is with out put of encoder i need to add some more data then send to ESPNow -- ESP2 Spilt data and Send to decoder .

[aqildad-create]

THATS WHY I NEED OUT OUT OF ENCODER IN ARRAY

[pschatzmann]

I already gave you the solution for this: If you want to send information of different type thru the wire you could implement your own framing protocol. I suggest that you get some inspiration by looking at the SimpleContainer.h

As an alternative you could use IP instead of ESPNow and send the data via 2 different connections on different ports. Of if it's just small amount of data send it via UDP

[aqildad-create]

this some what i need to start .I need to have bufferstream in mid of encoder and decoder . and copy data from buffer stream 1 to buffer stream 2 .

I try it like below but the out is not proper sine wave . How to get proper SINE wave with bufferstreams in mid?

#include "AudioTools.h"
#include "AudioCodecs/CodecSBC.h"
//#include "AudioLibs/AudioKit.h"

uint16_t sample_rate = 44100;
uint8_t channels = 1; // The stream will have 2 channels
AudioInfo to(44100, channels, 16);
SineWaveGenerator<int16_t> sineWave( 32000); // subclass of SoundGenerator with max amplitude of 32000
GeneratedSoundStream<int16_t> sound( sineWave); // Stream generated from sine wave
CsvStream<int16_t> out;
EncodedAudioStream decoder(&out, new SBCDecoder()); // encode and write
RingBufferStream decoderin;
RingBufferStream encoderOUT;
StreamCopy copierdecoder(decoder, decoderin);
EncodedAudioStream encoder(&encoderOUT, new SBCEncoder()); // encode and write
StreamCopy copierencoder(encoder, sound);

void setup() {
Serial.begin(115200);
AudioLogger::instance().begin(Serial, AudioLogger::Warning);

// start I2S
Serial.println("starting I2S...");
auto cfgi = out.defaultConfig(TX_MODE);
cfgi.sample_rate = sample_rate;
cfgi.channels = channels;
cfgi.bits_per_sample = 16;
out.begin(cfgi);

// Setup sine wave
auto cfgs = sineWave.defaultConfig();
cfgs.sample_rate = sample_rate;
cfgs.channels = channels;
cfgs.bits_per_sample = 16;
sineWave.begin(cfgs, N_B4);

// start decoder
decoder.begin();

// start encoder
encoder.begin( cfgi);

Serial.println("Test started...");
}

static uint8_t buffer[1024];
void loop() {

copierencoder.copy();
encoderOUT.readBytes(buffer, 1024);
decoderin.write(buffer, 1024);
copierdecoder.copy();

}

[pschatzmann]

Actually, after a second thought you have an ugly bug in your logic!

It needs to be
int copied = encoderOUT.readBytes(buffer, 1024);
decoderin.write(buffer, copied);

[pschatzmann]

by the way, I think your detour via 2 RingBufferStreams is unnecessary.
The following should work

EncodedAudioStream encoder(&sineWave, new SBCEncoder()); // to read encoded data
EncodedAudioStream decoder(&out, new SBCDecoder()); // decode to out
int frameSize=0;
int frameCopyCount = 1; // or any other bigger number
...
void begin() {
    ...
    encoder.begin( cfgi);
    frameSize=encoder.bytesCompressed();
    ...
}

and in the loop:

void loop() {
    // copy full frames
    int copyBytes = frameSize*frameCopyCount;
    static uint8_t buffer[copyBytes];
    int copied = encoder.readBytes(buffer, copyBytes);
    decoder.write(buffer, copied);
}

I think it is advisable, not to split up individual frames.

[aqildad-create]

yes it look nice and more clean .

I will work on it further and get back to you soon . thanks for your important time.

[aqildad-create]

tred as dscussed above but bellow 2 concerns

1- IT COMPILE BUT DIDNOT START PLOTTNG. I THINK WE NEED TO ADD COPIER IN LOOP ?

2- Also separately i run with frameSize=encoder.bytesCompressed(); but it through error may be version issue right ?
see the mage or error

#include "AudioTools.h"
#include "AudioCodecs/CodecSBC.h"
//#include "AudioLibs/AudioKit.h"

uint16_t sample_rate = 44100;
uint8_t channels = 1; // The stream will have 2 channels
AudioInfo to(44100, channels, 16);
SineWaveGenerator<int16_t> sineWave( 32000); // subclass of SoundGenerator with max amplitude of 32000
GeneratedSoundStream<int16_t> sound( sineWave); // Stream generated from sine wave
CsvStream<int16_t> out;

EncodedAudioStream encoder(&sound, new SBCEncoder()); // to read encoded data
EncodedAudioStream decoder(&out, new SBCDecoder()); // decode to out
int frameSize=0;
int frameCopyCount = 1; // or any other bigger number

void setup() {
Serial.begin(115200);
AudioLogger::instance().begin(Serial, AudioLogger::Warning);

// start I2S
Serial.println("starting I2S...");
auto cfgi = out.defaultConfig(TX_MODE);
cfgi.sample_rate = sample_rate;
cfgi.channels = channels;
cfgi.bits_per_sample = 16;
out.begin(cfgi);

// Setup sine wave
auto cfgs = sineWave.defaultConfig();
cfgs.sample_rate = sample_rate;
cfgs.channels = channels;
cfgs.bits_per_sample = 16;
sineWave.begin(cfgs, N_B4);

// start decoder
decoder.begin();

// start encoder
encoder.begin(cfgi);
// frameSize=encoder.bytesCompressed();
Serial.println("Test started...");
}

void loop() {

const int copyBytes =1024;//= frameSize*frameCopyCount;
static uint8_t buffer[copyBytes];
int copied = encoder.readBytes(buffer, copyBytes);
decoder.write(buffer, copied);

}
//------------------------------------------------
LOG
entry 0x400805f0
starting I2S...
Test started...
.
.
.

[pschatzmann]

Update to the latest version or use the name used in your version...

[aqildad-create]

Ok i will update the version later but what about it didn't start plotting ?

…

On Mon, Apr 3, 2023, 13:38 Phil Schatzmann ***@***.***> wrote: Update to the latest version or use the name used in your version... — Reply to this email directly, view it on GitHub <#745 (reply in thread)>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/APTMWZTQP2XVVS6WUAXJGDTW7KD7RANCNFSM6AAAAAAWQFSCJY> . You are receiving this because you authored the thread.Message ID: <pschatzmann/arduino-audio-tools/repo-discussions/745/comments/5507321@ github.com>

[pschatzmann]

Actually I never tested the reading from an EncodedAudioStream with an encoder. So far I always used this with a decoder, so I assumed that this would work as well.

I just committed an correction that supports both cases.

[pschatzmann]

Here is my test that works

#include "AudioTools.h"
#include "AudioCodecs/CodecSBC.h"

AudioInfo info(44100, 2, 16);
// input
SineWaveGenerator<int16_t> gen( 32000); // subclass of SoundGenerator with max amplitude of 32000
GeneratedSoundStream<int16_t> sineStream( gen); // Stream generated from sine wave
// output
CsvStream<int16_t> csv;
// encoding
SBCEncoder enc;
SBCDecoder dec;
EncodedAudioStream encStream(sineStream, enc); // to read encoded data
EncodedAudioStream decStream(csv, dec); // decode to out
int frameSize=0;
int frameCopyCount = 10; // or any other factor

void setup() {
  Serial.begin(115200);
  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // Setup sine wave
  gen.begin(info, N_B4);
  sineStream.begin(info);

  // start encoder
  encStream.begin(info);
  frameSize=enc.bytesCompressed();
  Serial.print("Frame Size ");
  Serial.println(frameSize);

  // start decoder
  decStream.begin(info);

  // setup output
  csv.begin(info);

  Serial.println("Test started...");
}

void loop() {
    // copy full frames
    int copyBytes = frameSize*frameCopyCount;
    uint8_t buffer[copyBytes];
    int copied = encStream.readBytes(buffer, copyBytes);
    decStream.write(buffer, copied);
}