Using FFT resultArray;

[OSBringer]

Hi Phil I recently started to work with FFT in this library.
I want to get the result of biggest 5 magnitudes(from 0 to size() ) of the audio signal. My goal is then to calculate energy of these top peaks for further analysis.
I am using the example bellow:

 #include "AudioTools.h"
#include "AudioLibs/AudioKit.h"
#include "AudioLibs/AudioRealFFT.h" // or AudioKissFFT
AudioKitStream kit;  // Audio source
AudioRealFFT fft; // or AudioKissFFT

StreamCopy copier(fft, kit);  // copy mic to tfl
int channels = 2;
int samples_per_second = 44100;
int bits_per_sample = 16;
float value=0;


// display fft result
void fftResult(AudioFFTBase &fft){
  int diff;
   AudioFFTResult magx[5];
fft.resultArray(magx);
  //auto result = fft.result();
  Serial.print("\n_________\n");
  for (int i = 0; i <5; i++)
  {
    Serial.print(i  );
    Serial.print(" => ");  
    Serial.print(   magx[i].magnitude);
    Serial.print("\n");
  
  }
  Serial.print("_________\n");


    
}

void setup() {
  Serial.begin(115200);
  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // setup Audiokit
  auto cfg = kit.defaultConfig(RX_MODE);
  cfg.input_device = AUDIO_HAL_ADC_INPUT_LINE2;
  cfg.channels = channels;
  cfg.sample_rate = samples_per_second;
 cfg.sd_active = true;
  cfg.bits_per_sample = bits_per_sample;
  kit.begin(cfg);

  // Setup FFT
  auto tcfg = fft.defaultConfig();
  tcfg.length = 8192;
  tcfg.channels = channels;
  tcfg.sample_rate = samples_per_second;
  tcfg.bits_per_sample = bits_per_sample;
  tcfg.callback = &fftResult;
  fft.begin(tcfg);
  
}

void loop() { 
  copier.copy();
} 

The result of looping through magx gives result:

I dont think i use the resultArray() correctly, but cant quite seem to figure it out.

[pschatzmann]

Are the corresponding frequencies also the same ?
If so, there might be a bug in the sort...

[OSBringer]

Yes they are

[pschatzmann]

Can you test if the following change in AudioFFTBase helps:

        /// make sure that we do not reuse already found results
        template<int N>
        bool insertSorted(AudioFFTResult(&result)[N], AudioFFTResult tmp){
            for (int j=0;j<N;j++){
                // insert value if it is > then existing values
                if (tmp.magnitude>result[j].magnitude){
                    // shift existing values right
                    for (int i=N-2;i>=j;i--){
                        result[i+1] = result[i];
                    }
                    // insert new value
                    result[j]=tmp;
                    // -> insert value only once
                    break;
                }
            }
            return true;
        }

[pschatzmann]

I committed the correction and added a test case.

[OSBringer]

Hi Phil thanks for helping.
The test case you mentioned works well. 👍
I've tried using it with the kit mic instead of sine generator input, and it crashes at setup.
The code that i use

#include "AudioTools.h"
#include "AudioLibs/AudioKit.h"
#include "AudioLibs/AudioRealFFT.h" // or AudioKissFFT
AudioKitStream kit;  // Audio source
AudioRealFFT fft; // or AudioKissFFT

StreamCopy copier(fft, kit);  // copy mic to tfl
int channels = 2;
int samples_per_second = 44100;
int bits_per_sample = 16;
float value=0;



// display fft result
void fftResult(AudioFFTBase &fft){
  int diff;
  AudioFFTResult resultsX[4096];
  fft.resultArray(resultsX);
  //auto result = fft.result();
  float energy = 0 ;
  Serial.print("\n_________\n");
  for (int i = 0; i <4096; i++)
  {
    Serial.print(i  );
    if (resultsX[i].magnitude > 100) {
    Serial.print("MAG => ");  
    Serial.print(   resultsX[i].magnitude);
  
    Serial.print("\n");
    Serial.print("FREQUENCY => ");  
    Serial.print(   resultsX[i].frequency);
    Serial.print("\n");
    energy += (resultsX[i].magnitude/100) * (resultsX[i].magnitude/100);
    }
  }
  Serial.print("_________\n");
  Serial.print("Energy  : ");
  Serial.print(energy);
    
}

void setup() {
  Serial.begin(115200);

  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // setup Audiokit
  auto cfg = kit.defaultConfig(RX_MODE);
  cfg.input_device = AUDIO_HAL_ADC_INPUT_LINE2;
  cfg.channels = channels;
  cfg.sample_rate = samples_per_second;
  cfg.bits_per_sample = bits_per_sample;
  kit.begin(cfg);

  // Setup FFT
  auto tcfg = fft.defaultConfig();
  tcfg.length = 8192;
  //tcfg.stride = 2;
  tcfg.channels = channels;
  tcfg.sample_rate = samples_per_second;
  tcfg.bits_per_sample = bits_per_sample;
  tcfg.window_function = new BufferedWindow(new Hann());

  tcfg.callback = &fftResult;
  fft.begin(tcfg);

  
}

void loop() { 
  copier.copy();
}

Serial output:

I ve tried with smaller resultArray of 10 or so and it seem to work, that however may not fulfill my focus with the project.
It seem like some memory error that i am not sure how to overcome. Do you have any ideas?

[pschatzmann]

Are you really sure that you need 4096 frequency bins: This uses a lot of memory !
It is also a bad idea to add some slow functionality (Serial.prints) to the callback: fftResult. You would need to just store the result there and move the slow output to the loop!

ps.
In order to identify the root cause of your error you will need to analyse the stacktrace.

[OSBringer]

You are probably right with the bins.
What I am trying to achieve is:

• Calculate the energy of the last 10 results of FFT (with Hann window func)
• Calculate the standard deviation of energy of 3 highest peaks in the signal
• Calculate Ratio of signal under 1000Hz and above 1000Hz
• Calculate Mean intensity of signal
  I dont think i yet understand how the DSP really works in this cases.

[pschatzmann]

In this case you could also consider to reduce the sample rate considerably. With 44100 you measure the spectrum between 0 and 22100 hz

[OSBringer]

I dont know if that might be a good idea for the project, since i need to analyze human hearable sounds from around 0Hz-20kHz.

[OSBringer]

I noticed a problem where when using Hann window function the magnitudes are all 0, or when using it buffered for all results from resultArray the magnitudes are the same.
Using the code(with buffered hann) above with just 10 results (resultX[10])
Output:

[pschatzmann]

Did you verfy your result first w/o using any window?

[OSBringer]

Yes

[pschatzmann]

I committed some corrections. Here are the related tests:

Hann window;
window.begin(100);
for (int j=0;j<100;j++){
    cout << window.factor(j) << " ";   
}
0 0.0010872 0.00434441 0.0097585 0.0173077 0.0269616 0.0386813 0.0524197 0.0681213 0.0857231 0.105154 0.126336 0.149184 0.173605 0.199502 0.226769 0.255298 0.284974 0.315676 0.347281 0.379663 0.41269 0.44623 0.480147 0.514306 0.548568 0.582795 0.61685 0.650596 0.683896 0.716617 0.748626 0.779796 0.81 0.839117 0.867029 0.893625 0.918796 0.942443 0.964469 0.984785 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 0.984785 0.964469 0.942443 0.918796 0.893625 0.867029 0.839117 0.81 0.779796 0.748626 0.716617 0.683896 0.650596 0.61685 0.582795 0.548568 0.514306 0.480147 0.44623 0.41269 0.379663 0.347281 0.315676 0.284974 0.255298 0.226769 0.199502 0.173605 0.149184 0.126336 0.105154 0.0857231 0.0681213 0.0524197 0.0386813 0.0269616 0.0173077 0.0097585 0.00434441 0.0010872 0 

Hann window;
BufferedWindow window1(&window);
window1.begin(100);
for (int j=0;j<100;j++){
    cout << window1.factor(j) << " ";   
}

0 0.0010872 0.00434441 0.0097585 0.0173077 0.0269616 0.0386813 0.0524197 0.0681213 0.0857231 0.105154 0.126336 0.149184 0.173605 0.199502 0.226769 0.255298 0.284974 0.315676 0.347281 0.379663 0.41269 0.44623 0.480147 0.514306 0.548568 0.582795 0.61685 0.650596 0.683896 0.716617 0.748626 0.779796 0.81 0.839117 0.867029 0.893625 0.918796 0.942443 0.964469 0.984785 1 1 1 1 1 1 1 1 0 1 1 1 1 1 1 1 1 1 0.984785 0.964469 0.942443 0.918796 0.893625 0.867029 0.839117 0.81 0.779796 0.748626 0.716617 0.683896 0.650596 0.61685 0.582795 0.548568 0.514306 0.480147 0.44623 0.41269 0.379663 0.347281 0.315676 0.284974 0.255298 0.226769 0.199502 0.173605 0.149184 0.126336 0.105154 0.0857231 0.0681213 0.0524197 0.0386813 0.0269616 0.0173077 0.0097585 0.00434441 0.0010872 0