Problems with Last Updates

[grender007]

I was working with an ESP32 S3 and a CODEC8388 using AudioTools and AudioDriver, and everything was smooth until a few days ago. I updated both libraries a did a minor change to my code (I'm using FilteredStream and just modified the coefficients of the filter), and the program stop working. I used no filter at all to verify if I still have the same issue and it was the same.
I got multiple I2C errors (all of them are "->p_wire->endTransmission: 2") and the stream of bits I was receiving from the CODEC was all 0's. Something weird is that when I touch with my finger or a piece of wire some of the physical pins of the CODEC, it works (kind of). Does the I2S needs some kind of pull up/down resistors? I also tried with external pull up resistors for the I2C and there was no difference.
Any suggestions?

The code (Based on one of the examples of AudioDriver):

#include "AudioTools.h" // install https://github.com/pschatzmann/arduino-audio-tools
#include "AudioLibs/I2SCodecStream.h"
#include "Communication/ESPNowStream.h"

// I2C
#define SDAPIN 3 // I2C Data, Adafruit ESP32 S3 3, Sparkfun Thing Plus C 23
#define SCLPIN 4 // I2C Clock, Adafruit ESP32 S3 4, Sparkfun Thing Plus C 22
#define I2CSPEED 100000 // Clock Rate
#define ES8388ADDR 0x10 // Address of ES8388 I2C port

// I2S, your configuration for the ES8388 board
#define MCLKPIN 14 // Master Clock
#define BCLKPIN 36 // Bit Clock
#define WSPIN 8 // Word select
#define DOPIN 37 // This is connected to DI on ES8388 (MISO)
#define DIPIN 35 // This is connected to DO on ES8388 (MOSI)

AudioInfo audio_info(8000, 1, 16); // sampling rate, # channels (mono), bit depth

DriverPins my_pins; // board pins
AudioBoard audio_board(AudioDriverES8388, my_pins); // audio board
I2SCodecStream i2s_out_stream(audio_board); // i2s coded
TwoWire myWire = TwoWire(0); // universal I2C interface

uint16_t channels = 1;
FilteredStream<int16_t, float> inFiltered(i2s_out_stream, channels);
// Current specifications of the filter: fc_high = 100, fc_low = 1150, fs = 8000. See MATLAB code for variations of this filter
const float b_coefficients[] = { 0.1158, 0.0000,-0.2317, 0.0000, 0.1158};
const float a_coefficients[] = { 1.0000,-2.6850, 2.6850,-1.2530, 0.2559};

CsvOutput<int16_t> Serial_out(Serial); // ASCII output stream
StreamCopy copier_output(Serial_out, inFiltered);

void setup() {
// Setup logging
Serial.begin(115200);
AudioLogger::instance().begin(Serial, AudioLogger::Warning);
LOGLEVEL_AUDIODRIVER = AudioDriverWarning;
delay(2000);

Serial.println("Setup starting...");

Serial.println("I2C pin ...");
my_pins.addI2C(PinFunction::CODEC, SCLPIN, SDAPIN, ES8388ADDR, I2CSPEED, myWire);
Serial.println("I2S pin ...");
my_pins.addI2S(PinFunction::CODEC, MCLKPIN, BCLKPIN, WSPIN, DOPIN, DIPIN);
Serial.println("Pins begin ...");
my_pins.begin();

Serial.println("Board begin ...");
CodecConfig cfg;
//No output to codec
cfg.output_device = DAC_OUTPUT_LINE1;
//Mic input from adc channel 1
cfg.input_device = ADC_INPUT_LINE1;
//Bits per sample (16 bits)
cfg.i2s.bits = BIT_LENGTH_16BITS;
//Sample Rate (44.1 kHz)
cfg.i2s.rate = RATE_8K; //cfg.i2s.rate = RATE_44K;
audio_board.begin(cfg);
//Additional ADC configuration ---> Everything else is in default mode (See datasheet)
//set to mono mix in ADC channel 1 (lin1/Mic pin) --> 00001000 == 0x08 in ADCControl 3
//es8388_write_reg(ES8388_ADCCONTROL3, 0x08);

Serial.println("I2S begin ...");
auto i2s_config = i2s_out_stream.defaultConfig(RXTX_MODE); //RXTX for douplex //RX for sink //TX for source
i2s_config.copyFrom(audio_info);
i2s_out_stream.begin(i2s_config); // this should apply I2C and I2S configuration

// Setup CSV
Serial.println("CSV begin...");
Serial_out.begin(audio_info);

// Setup filter
inFiltered.setFilter(0, new IIR(b_coefficients, a_coefficients));

Serial.println("Setup completed ...");
delay(5000);
}

// Arduino loop - copy sound to out
void loop() {
copier_output.copy();
}

The output:
Setup starting...
I2C pin ...
I2S pin ...
Pins begin ...
Board begin ...
I2S begin ...
Error: ->p_wire->endTransmission: 2
Error: ->p_wire->endTransmission: 2
Error: ->p_wire->endTransmission: 2
CSV begin...

Setup completed ...

[grender007]

I found the solution! For some reason, I needed to change the order of DOPIN and DIPIN in "my_pins.addI2S(PinFunction::CODEC, MCLKPIN, BCLKPIN, WSPIN, DOPIN, DIPIN);" and everything started working again!