Reading the current bitpool value while music is playing

[MarusGradinaru]

Hi,
I am trying to make an ESP32 audio sink with ESP32-A2DP.
And I want to monitor the quality of audio stream to see if it changes. So I need the bitpool value, because this is the only parameter that is changed when playing. So I did as in the following example... Believing that this is the bitpool value. But it's not. It is only the negotiated bitpool that is only updated when connection is establisehd. The real bitpool value it seems it is encoded in every SBC frame that is received, as it states here. I tried to examine the received buffer in void read_data_stream(const uint8_t* data, uint32_t length) but I don't understand what is the format of the data in that buffer... I examined the first 10 bytes and I didn't found the 0x9C flag byte which marks the start of the SBC frame. I could search for it, but it is not guaranteed that the 0x9C I will encounter is the beginning of the SBC frame or just another data byte... So, I want to ask you, is there an easy method to find the bitpool (and other parameters) of the frames I receive ? I don't need every frame ! Just from time to time, like one second or so...

#include <Arduino.h>
#include "AudioTools.h"
#include "BluetoothA2DPSink.h"

void decode_sbc_codec_config(const uint8_t sbc[4]) {
  // Sampling frequency (b7-b4 sbc[0])
  int sample_rate = 0;
  if (sbc[0] & 0x80) sample_rate = 16000;
  else if (sbc[0] & 0x40) sample_rate = 32000;
  else if (sbc[0] & 0x20) sample_rate = 44100;
  else if (sbc[0] & 0x10) sample_rate = 48000;

  // Channel mode (b3-b0 sbc[0])
  int channels = 2;
  bool joint_stereo = false;
  if (sbc[0] & 0x08) channels = 1;         // Mono
  else if (sbc[0] & 0x04) channels = 2;    // Dual channel
  else if (sbc[0] & 0x02) channels = 2;    // Stereo
  else if (sbc[0] & 0x01) {                // Joint Stereo
    channels = 2;
    joint_stereo = true;
  }

  // Blocks (b7–b4 sbc[1])
  int blocks = 0;
  if (sbc[1] & 0x80) blocks = 4;
  else if (sbc[1] & 0x40) blocks = 8;
  else if (sbc[1] & 0x20) blocks = 12;
  else if (sbc[1] & 0x10) blocks = 16;

  // Subbands (b3–b2 sbc[1])
  int subbands = 0;
  if (sbc[1] & 0x08) subbands = 4;
  else if (sbc[1] & 0x04) subbands = 8;

  // Allocation Method (b1-b0 sbc[1])  
  const char* alloc_method =
    (sbc[1] & 0x02) ? "SNR" :
    (sbc[1] & 0x01) ? "Loudness" : "Unknown";

  // Bitpool (sbc[2] sbc[3])
  uint8_t bitpool_min = sbc[2];
  uint8_t bitpool_max = sbc[3];

  // Calculate bitrate 
  int frame_length_min = 0; int frame_length_max = 0;
  if (channels == 1 || (sbc[0] & 0x0C) == 0x0C) {
    // Mono or Dual Channel
    frame_length_min = 4 + (4 * subbands * channels) / 8 + round((blocks * channels * bitpool_min) / 8.0);
    frame_length_max = 4 + (4 * subbands * channels) / 8 + round((blocks * channels * bitpool_max) / 8.0);
  } else {
    // Stereo or Joint Stereo
    int joint = joint_stereo ? subbands : 0;
    frame_length_min = 4 + (4 * subbands * channels) / 8 + round((joint + blocks * bitpool_min) / 8.0);
    frame_length_max = 4 + (4 * subbands * channels) / 8 + round((joint + blocks * bitpool_max) / 8.0);
  }
  float bitrate_min = (8.0f * frame_length_min * sample_rate) / (subbands * blocks);
  float bitrate_max = (8.0f * frame_length_max * sample_rate) / (subbands * blocks);
  int bitrate_min_kbps = (int)(bitrate_min / 1000.0 + 0.5);
  int bitrate_max_kbps = (int)(bitrate_max / 1000.0 + 0.5);

  // Show results
  Serial.println("===== Negotiated SBC Configuration =====");
  Serial.printf("Sample Rate      : %d Hz\n", sample_rate);
  Serial.printf("Channels         : %d (%s)\n", channels, joint_stereo ? "Joint Stereo" : (channels == 1 ? "Mono" : "Stereo"));
  Serial.printf("Blocks per Frame : %d\n", blocks);
  Serial.printf("Subbands         : %d\n", subbands);
  Serial.printf("Allocation       : %s\n", alloc_method);
  Serial.printf("Bitpool Range    : min = %d, max = %d\n", bitpool_min, bitpool_max);
  Serial.printf("Bitrate Estimate : min = %d kbps, max = %d kbps\n", bitrate_min_kbps, bitrate_max_kbps);
  Serial.println("========================================");
}

class BluetoothA2DPSinkEx : public BluetoothA2DPSink {
public:
  BluetoothA2DPSinkEx(I2SStream &stream) : BluetoothA2DPSink(stream) {}  
protected:
  void handle_audio_cfg(uint16_t event, void *p_param) override {
    BluetoothA2DPSink::handle_audio_cfg(event, p_param);
    esp_a2d_cb_param_t *a2d = (esp_a2d_cb_param_t *)p_param;
    if (a2d->audio_cfg.mcc.type == ESP_A2D_MCT_SBC) {
      uint8_t *sbc = a2d->audio_cfg.mcc.cie.sbc;
      decode_sbc_codec_config(sbc);
    }
  }
};

I2SStream i2s;  
BluetoothA2DPSinkEx a2dp_sink(i2s);

void read_data_stream(const uint8_t* data, uint32_t length) {
  static size_t total_bytes = 0;
  static unsigned long lastUpdate = 0;
  total_bytes += length;
  unsigned long now = millis();
  if (now - lastUpdate >= 1000) {
    Serial.printf("Received audio data: %u bytes\n", total_bytes);
    total_bytes = 0;
    lastUpdate = now;
    
    // Show first 10 bytes...
    uint8_t count = (length < 10) ? length : 10;
    Serial.print("Data: ");
    for (uint8_t i = 0; i < count; i++) {
      Serial.printf("%02X ", data[i]);
    }
    Serial.println();
  }
}

void rssi_callback(esp_bt_gap_cb_param_t::read_rssi_delta_param &rssiParam) {
  Serial.print("RSSI: ");
  Serial.print(rssiParam.rssi_delta);
  Serial.println(" dBm");
}

void setup() {
  Serial.begin(115200);
  delay(1000);

  Serial.println("Initializing Bluetooth A2DP...");
  a2dp_sink.set_stream_reader(read_data_stream, false);
  a2dp_sink.set_rssi_active(true);
  a2dp_sink.set_rssi_callback(rssi_callback);  
  a2dp_sink.start("ESP32 Speakers");  
  Serial.println("Bluetooth ready ! Waiting for connections...");
}

unsigned long last_rssi_check = 0;

void loop() {
  if (a2dp_sink.is_connected() && (millis() - last_rssi_check) > 3000) {
    a2dp_sink.update_rssi();          
    last_rssi_check = millis();
  }
  delay(1000);
}

[pschatzmann]

To my knowlege Espressif does not provide any functionality to access the encoded data.
There is only an API to provide PCM,,,

Please let me know if you find any way around this w/o patching the IDF...

[MarusGradinaru]

Can you tell me at least what data is in the void BluetoothA2DPSink::audio_data_callback(const uint8_t *data, uint32_t len) ? It is the whole data received from the Source, with headers and SBC frames, or is just the plain PCM audio data ?

[pschatzmann]

I think I already did in my reply and the first sentence of the Readme gives the info that you receive PCM!

[MarusGradinaru]

Sorry... :( I am verry tired. I don't see well anymore... I worked for days searching a way to read the bitpool value. And I am new to ESP32 and bluetooth stuff...

Ok then... I have another idea. I will configure the BluetoothA2DPSink to negotiate min_bitpool = 53 and max_bitpool = 53. And if the connection is not good and the Source wants to decrease the bitrate it won't be able to do that, and will give an error or something... And then I will know what is the maximum distance that allows good audio quality. But, please, tell me if I can configure the negotiated parameters in BluetoothA2DPSink, to not spend more days to find that is not possible... :(

[pschatzmann]

I never tried ths: suggest that you post your question with Espressif

[MarusGradinaru]

In your library documentation, I saw that you refer to the a2dp_sink example from Espressif. I went there and I found how they configure the SBC negotiation parameters: https://github.com/espressif/esp-idf/blob/adcbdd7da4fca12cd48ca5338e3fa0e8cf6695ce/examples/bluetooth/bluedroid/classic_bt/a2dp_sink/main/main.c#L171
Do you think you can implement this in your library too ? It would be very useful for audiophiles who want to force maximum quality for the sound played with this A2DP Sink... I will be happy to test whatever you ask me to, if you need it.