Can this work with I2S to send the audio data at 48 kHz to a Linux box using the Raspberry Pi Pico or Pico 2 or Pico W or Pico 2W?

[frohro]

@pschatzmann, I have some code that reads a PCM1808 codec using the I2S interface and the Arduino-Pico framework. Having this appear as a USB sound card would make things easier than what I'm doing sending the data over UDP on WiFi, especially if it could solve a sample rate mismatch issue. The Pico presently samples at 48.047 kHz. Will this library solve the sample rate mismatch problems? Will it work at 48 kHz? I have also been looking at your Arduino Audio Library, with similar questions.
Thanks!
Rob

[frohro]

Well, I was able to buid it with the Arduino IDE. I haven't figured out VScode, but would like to. I used the instructions from the Testing/Porting Plans discussion below. I can see the Pico 2 W when I do an lsusb. It shows:
Bus 001 Device 014: ID 239a:cafe Adafruit Pico 2W
I was also able to see it in pavucontrol as an input as expected at 44.1 kHz
I then changed the random noise to a sinusoid so I could see if it worked for sure and tried it at 44.1 kHz, and 48 kHz and it worked fine either way. I could not get 96 kHz to work though. :-)

#include <cmath>
#include "Adafruit_TinyUSB.h"

const float sampleRate = 48000.0;
const float frequencyLeft = 1000.0;
const float frequencyRight = 500.0;
const float amplitude = 32000.0;
const float twoPi = 2.0 * M_PI;

Adafruit_USBD_Audio usb;

size_t readCB(uint8_t* data, size_t len, Adafruit_USBD_Audio& ref) {
  int16_t* data16 = (int16_t*)data;
  size_t samples = len / sizeof(int16_t);
  size_t result = 0;
  static float phaseLeft = 0.0;
  static float phaseRight = 0.0;
  float phaseIncrementLeft = twoPi * frequencyLeft / sampleRate;
  float phaseIncrementRight = twoPi * frequencyRight / sampleRate;

  for (size_t j = 0; j < samples; j += 2) {
    data16[j] = amplitude * sin(phaseLeft); // Left channel
    data16[j + 1] = amplitude * sin(phaseRight); // Right channel
    phaseLeft += phaseIncrementLeft;
    phaseRight += phaseIncrementRight;
    if (phaseLeft >= twoPi) phaseLeft -= twoPi;
    if (phaseRight >= twoPi) phaseRight -= twoPi;
    result += sizeof(int16_t) * 2;
  }
  return result;
}

void setup() {
  Serial.begin(115200);

  // Start USB device as Microphone
  usb.setReadCallback(readCB);
  usb.begin(sampleRate, 2, 16); // Set sample rate to 48000 Hz

  if (TinyUSBDevice.mounted()) {
    TinyUSBDevice.detach();
    delay(10);
    TinyUSBDevice.attach();
  }
}

void loop() {
  // optionally use LED to display status
  usb.updateLED();
}

This worked with a Pico W and a Pico 2 W at 48 kHz. I should also mention that I had to select the Adafruit_TinyUSB USB Stack in the Tools menu after selecting the board.

[frohro]

So my question now is, "How can I make this work in PlatformIO?"

Thanks! This will really make my student's SDR projects this next spring nice!

[pschatzmann]

Did you read the Wiki ?

[frohro]

Thanks! I missed it! It works fine now.

[frohro]

@pschatzmann
Well, further testing seems to indicate that regardless of what you set the sample rate to, it is 44.1kHz. I find that the variable len above is 194, giving 97 samples per buffer. When I set the frequency to 20 times that the frequency of that 20(44100/97), I get this:

Note the signal has a span of -22 kHz to 22 kHz. I can change the sample rate to 48000 or even 96000, by changing the limits in TinyUSB, but it seems the sample rate is not really set by the call to usb.begin(). The harmonics are coming from the basic period of 97 samples that is repeated. For the first 97 samples, you see nice peaks at only +/- 20(44100/97), but then the harmonics appear. The software I am using is quisk. It is an SDR software. Note that there is a delay when samples from the right and left channels get there. You can see this in Audacity too. If the samples got there simultaneously, then they should have exactly the same amplitude, but they don't. The code for this test is:

#include <cmath>
#include "Adafruit_TinyUSB.h"

const float sampleRate = 44100.0;
const float frequencyLeft = 20*454.639;
const float frequencyRight = 20*454.639;
const float amplitude = 30000.0;
const float twoPi = 2.0 * M_PI;

Adafruit_USBD_Audio usb;

size_t readCB(uint8_t* data, size_t len, Adafruit_USBD_Audio& ref) {
  int16_t* data16 = (int16_t*)data;
  Serial.println(len);
  size_t samples = len / sizeof(int16_t);
  size_t result = 0;
  static float phaseLeft = 0.0;
  static float phaseRight = 0.0;
  float phaseIncrementLeft = twoPi * frequencyLeft / sampleRate;
  float phaseIncrementRight = twoPi * frequencyRight / sampleRate;

  for (size_t j = 0; j < samples; j += 2) {
    data16[j] = amplitude * sin(phaseLeft); // Left channel
    data16[j + 1] = amplitude * sin(phaseRight); // Right channel
    phaseLeft += phaseIncrementLeft;
    phaseRight += phaseIncrementRight;
    if (phaseLeft >= twoPi) phaseLeft -= twoPi;
    if (phaseRight >= twoPi) phaseRight -= twoPi;
    result += sizeof(int16_t) * 2;
  }
  return result;
}

void setup() {
  Serial.begin(115200);

  // Start USB device as Microphone
  usb.setReadCallback(readCB);
  usb.begin(sampleRate, 2, 16); 

  if (TinyUSBDevice.mounted()) {
    TinyUSBDevice.detach();
    delay(10);
    TinyUSBDevice.attach();
  }
}

void loop() {
  // optionally use LED to display status
  usb.updateLED();
}

Should I submit an issue for this?

[frohro]

I guess the code above was run with sampleRate at 44100, but I did try 48000, and 96000 after changing a #define that the maximum frequency was 48000. If you change the sampleRate, then len changes. For example, at 44.1kHz len is 91 instead of 97.

[pschatzmann]

Did you update the rate both in the Arduino Sketch and in Audacity as well ?
I was getting my Pico 2 today, so as soon as I have some spare time, I will look into this.

[frohro]

So I played around with this a little bit more, and it seems to work "fine" with sample rates up to 48kHz. I couldn't get it to go at 96 kHz, even after changing the following parameters in adafruit_audio_config.h.

#ifndef AUDIO_FREQ_MAX
#  define AUDIO_FREQ_MAX            96000

What it seems to do is if I pick 96000 sampleRate, it gives me 44100. However, if I pick 48000 sampleRate it actually gives me data at 48000. I grepped the entire project directory for 44100, found only this:

  /// start the processing
  virtual bool begin(unsigned long rate = 44100, int channels = 2,
             int bitsPerSample = 16);

but changing that had no effect.

I started a new discussion for the distortion I'm getting above. I did some testing with Audacity there and posted some movies regarding the distortion.

I went and tried to flash to my Pico 2W, but now I get an error when I try. It was flashing before though, so I need to chase that down.

Neither the distortion nor the sample rate getting reset to 44100 seem to be an issue that requires more speed, so I'm leaving the Pico 2W on the back burner for now.