Missing Data after 0.35 Seconds

[frohro]

@pschatzmann I am hoping to use this for my class this next quarter. I left it when this quarter started in early January, hoping some progress on it would occur this last quarter, and a little has. Unfortunately, I have forgotten a lot about what I was doing before, too. The problem I am having is missing data every so often. It does not happen for the first 0.35 seconds after I plug in the Pico. (I start Audacity recording, then plug in the Pico.) Then, after 0.35 seconds, it starts missing data points every so often. Here is my simple code:

#include <cmath>
#include "Adafruit_TinyUSB.h"

const float sampleRate = 48000.0;
const float frequencyLeft = 1000.0;
const float frequencyRight = 500.0;
const float amplitude = 32000.0;
const float twoPi = 2.0 * M_PI;

Adafruit_USBD_Audio usb;

size_t readCB(uint8_t* data, size_t len, Adafruit_USBD_Audio& ref) {
  int16_t* data16 = (int16_t*)data;
  size_t samples = len / sizeof(int16_t);
  size_t result = 0;
  static float phaseLeft = 0.0;
  static float phaseRight = 0.0;
  float phaseIncrementLeft = twoPi * frequencyLeft / sampleRate;
  float phaseIncrementRight = twoPi * frequencyRight / sampleRate;

  for (size_t j = 0; j < samples; j += 2) {
    data16[j] = amplitude * sin(phaseLeft); // Left channel
    data16[j + 1] = amplitude * sin(phaseRight); // Right channel
    phaseLeft += phaseIncrementLeft;
    phaseRight += phaseIncrementRight;
    if (phaseLeft >= twoPi) phaseLeft -= twoPi;
    if (phaseRight >= twoPi) phaseRight -= twoPi;
    result += sizeof(int16_t) * 2;
  }
  return result;
}

void setup() {
  Serial.begin(115200);

  // Start USB device as Microphone
  usb.setReadCallback(readCB);
  usb.begin(sampleRate, 2, 16); // Set sample rate to 48000 Hz

  if (TinyUSBDevice.mounted()) {
    TinyUSBDevice.detach();
    delay(10);
    TinyUSBDevice.attach();
  }
}

void loop() {
  // optionally use LED to display status
  usb.updateLED();
}

Here is a screenshot of it working just after getting plugged in (The red is before it was plugged in.):

Here is a screenshot after it has been plugged in for more than 0.35 seconds:

It happens about every millisecond or so. It is hard to see in the time domain, but in frequency, it is quite apparent. (I was careful to make my window over an even number of cycles so leakage wouldn't be a problem.)

What is the best way to approach fixing this issue?

Thanks,

Rob

[frohro]

So, I moved this to core1, and it is now hard to see or not happening at all.

#include <cmath>
#include "Adafruit_TinyUSB.h"

const float sampleRate = 48000.0;
const float frequencyLeft =1000.0;
const float frequencyRight = 500.0;
const float amplitude = 32000.0;
const float twoPi = 2.0 * M_PI;

Adafruit_USBD_Audio usb;

bool core1_separate_stack = true;

size_t readCB(uint8_t* data, size_t len, Adafruit_USBD_Audio& ref) {
  int16_t* data16 = (int16_t*)data;
  size_t samples = len / sizeof(int16_t);
  size_t result = 0;
  static float phaseLeft = 0.0;
  static float phaseRight = 0.0;
  float phaseIncrementLeft = twoPi * frequencyLeft / sampleRate;
  float phaseIncrementRight = twoPi * frequencyRight / sampleRate;

  for (size_t j = 0; j < samples; j += 2) {
    data16[j] = amplitude * sin(phaseLeft); // Left channel
    data16[j + 1] = amplitude * sin(phaseRight); // Right channel
    phaseLeft += phaseIncrementLeft;
    phaseRight += phaseIncrementRight;
    if (phaseLeft >= twoPi) phaseLeft -= twoPi;
    if (phaseRight >= twoPi) phaseRight -= twoPi;
    result += sizeof(int16_t) * 2;
  }
  return result;
}

void setup1() {
  Serial.begin(115200);

  // Start USB device as Microphone
  usb.setReadCallback(readCB);
  usb.begin(sampleRate, 2, 16); // Set sample rate to 48000 Hz

  if (TinyUSBDevice.mounted()) {
    TinyUSBDevice.detach();
    delay(10);
    TinyUSBDevice.attach();
  }
}

void loop1() {
  // optionally use LED to display status
  usb.updateLED();
}

void setup() {}
void loop() {}

[pschatzmann]

Oh, Cool!

If this helps, maybe overclocking also makes a difference...