Add a section of magit repositories

[ipocentro87]

Hi all, I've been trying to add a custom section listing the magit repositories in the dashboard, similarly to what magit-list-repositories provides.
I did find a solution to make it work, however it's a bit ugly as I override some dashboard functions and replaced the projects section instead of creating a new one. Here's my solution:

;; Override dashboard-projects-backend-load-projects to return the list of magit repositories 
(defun dashboard-projects-backend-load-projects ()
  (magit-list-repos))

;; My own custom select-repo function
(defun select-repo (abs-path)
  ;; custom code here
  )

(defun dashboard-projects-backend-switch-function ()
  "Return the function to switch to a project.
Custom variable `dashboard-projects-switch-function' variable takes preference
over custom backends."
  (or dashboard-projects-switch-function
      (cl-case dashboard-projects-backend
        (`projectile 'select-repo) ;; change with select-repo 
        (`project-el
         (lambda (project)
           "This function is used to switch to `PROJECT'."
           (let ((default-directory project))
             (project-find-file))))
        (t
         (display-warning '(dashboard)
                          "Invalid value for `dashboard-projects-backend'"
                          :error)))))

Is there any cleaner solution?
Thanks 🙏

[ricardoricho]

Hi,
I think it's related to #565 and the ability to extend dashboard, maybe a section in the README file or an entry in FAQ could help.
The easiest way to create a new section is using dashboard-insert-section, that is a macro (I don't know why)

(dashboard-insert-section SECTION-NAME LIST LIST-SIZE SHORTCUT-ID SHORTCUT-CHAR ACTION &rest WIDGET-PARAMS)

In the case of this "Magit" section, you need to define this "insert section" function:

(defun dashboard-insert-magit (list-size)
  "Insert LIST-SIZE number of magit repositories in dashboard."
  (dashboard-insert-section
   "Magit"  ;; SECTION-NAME
   (magit-list-repos) ;; LIST
   list-size ;; LIST-SIZE
   'magit ;; SHORCUT-ID
   (dashboard-get-shortcut 'magit)  ;; SHORTCUT CHAR
   `(lambda (&rest _) (magit-status ,el)) ;; ACTION
   (format "%s" el)  ;; WIDGET-PARAMS
))

For dashboard-get-shorcut to work, you need to add magit to shortcuts list.

(add-to-list 'dashboard-item-shortcuts
             '(magit . "b"))

Then, you have to add this "generator" to dashboard-item-generators

(add-to-list 'dashboard-item-generators '(magit . dashboard-insert-magit))

Now users can customize their dashboard-items

(add-to-list 'dashboard-items '(magit . 7))` 

Hope this help.