build: Fix OPAL_CHECK_COMPILER_VERSION_ID escaping

Fix escapling and simplify handling of literals in the OPAL_CHECK_-
COMPILER_VERSION_ID macro.  The macros were under-escaped,, which
was not causing problems but was also wrong.  The use of m4_lower()
meant that the argument to the helper macros had to be a string
literal, so enforce that requirement explicitly and then remove
the evals that are unnecessary given the lack of shell expansion.

Signed-off-by: Brian Barrett <bbarrett@amazon.com>

Author: bwbarrett

config/opal_check_compiler_version.m4

@@ -2,6 +2,8 @@ dnl -*- shell-script -*-
 dnl
 dnl Copyright (c) 2009      Oak Ridge National Labs.  All rights reserved.
 dnl Copyright (c) 2021 Cisco Systems, Inc.  All rights reserved.
+dnl Copyright (c) 2021      Amazon.com, Inc. or its affiliates.  All Rights
+dnl                         reserved.
 dnl
 dnl $COPYRIGHT$
 dnl
@@ -27,86 +29,92 @@ AC_DEFUN([OPAL_CHECK_COMPILER_VERSION_ID],
 
 
 AC_DEFUN([OPAL_CHECK_COMPILER], [
-    lower=m4_tolower($1)
-    AC_CACHE_CHECK([for compiler $lower], opal_cv_compiler_[$1],
+    AS_LITERAL_IF([$1], [],
+                  [m4_fatal([OPAL_CHECK_COMPILER argument must be a literal])])
+    lower=m4_tolower([$1])
+    AC_CACHE_CHECK([for compiler $lower], [opal_cv_compiler_$1],
     [
             CPPFLAGS_orig=$CPPFLAGS
-            CPPFLAGS="-I${OPAL_TOP_SRCDIR}/opal/include/opal $CPPFLAGS"
+            CPPFLAGS="-I${OPAL_TOP_SRCDIR}/opal/include $CPPFLAGS"
             AC_RUN_IFELSE([AC_LANG_PROGRAM([[
 #include <stdio.h>
 #include <stdlib.h>
-#include "opal_portable_platform.h"
+#include "opal/opal_portable_platform.h"
 ]],[[
     FILE * f;
     f=fopen("conftestval", "w");
     if (!f) exit(1);
     fprintf (f, "%d", PLATFORM_COMPILER_$1);
             ]])], [
-                eval opal_cv_compiler_$1=`cat conftestval`;
+                opal_cv_compiler_$1=`cat conftestval`
             ], [
-                eval opal_cv_compiler_$1=0
+                opal_cv_compiler_$1=0
             ], [
-                eval opal_cv_compiler_$1=0
+                opal_cv_compiler_$1=0
             ])
             CPPFLAGS=$CPPFLAGS_orig
     ])
-    AC_DEFINE_UNQUOTED([OPAL_BUILD_PLATFORM_COMPILER_$1], $opal_cv_compiler_[$1],
+    AC_DEFINE_UNQUOTED([OPAL_BUILD_PLATFORM_COMPILER_$1], [$opal_cv_compiler_$1],
                        [The compiler $lower which OMPI was built with])
 ])dnl
 
 AC_DEFUN([OPAL_CHECK_COMPILER_STRING], [
-    lower=m4_tolower($1)
-    AC_CACHE_CHECK([for compiler $lower], opal_cv_compiler_[$1],
+    AS_LITERAL_IF([$1], [],
+                  [m4_fatal([OPAL_CHECK_COMPILER_STRING argument must be a literal])])
+    lower=m4_tolower([$1])
+    AC_CACHE_CHECK([for compiler $lower], [opal_cv_compiler_$1],
     [
             CPPFLAGS_orig=$CPPFLAGS
-            CPPFLAGS="-I${OPAL_TOP_SRCDIR}/opal/include/opal $CPPFLAGS"
+            CPPFLAGS="-I${OPAL_TOP_SRCDIR}/opal/include $CPPFLAGS"
             AC_RUN_IFELSE([AC_LANG_PROGRAM([[
 #include <stdio.h>
 #include <stdlib.h>
-#include "opal_portable_platform.h"
+#include "opal/opal_portable_platform.h"
 ]],[[
     FILE * f;
     f=fopen("conftestval", "w");
     if (!f) exit(1);
     fprintf (f, "%s", PLATFORM_COMPILER_$1);
             ]])], [
-                eval opal_cv_compiler_$1=`cat conftestval`;
+                opal_cv_compiler_$1=`cat conftestval`
             ], [
-                eval opal_cv_compiler_$1=UNKNOWN
+                opal_cv_compiler_$1=UNKNOWN
             ], [
-                eval opal_cv_compiler_$1=UNKNOWN
+                opal_cv_compiler_$1=UNKNOWN
             ])
             CPPFLAGS=$CPPFLAGS_orig
     ])
-    AC_DEFINE_UNQUOTED([OPAL_BUILD_PLATFORM_COMPILER_$1], $opal_cv_compiler_[$1],
+    AC_DEFINE_UNQUOTED([OPAL_BUILD_PLATFORM_COMPILER_$1], [$opal_cv_compiler_$1],
                        [The compiler $lower which OMPI was built with])
 ])dnl
 
 
 AC_DEFUN([OPAL_CHECK_COMPILER_STRINGIFY], [
-    lower=m4_tolower($1)
-    AC_CACHE_CHECK([for compiler $lower], opal_cv_compiler_[$1],
+    AS_LITERAL_IF([$1], [],
+                  [m4_fatal([OPAL_CHECK_COMPILER_STRINGIFY argument must be a literal])])
+    lower=m4_tolower([$1])
+    AC_CACHE_CHECK([for compiler $lower], [opal_cv_compiler_$1],
     [
             CPPFLAGS_orig=$CPPFLAGS
-            CPPFLAGS="-I${OPAL_TOP_SRCDIR}/opal/include/opal $CPPFLAGS"
+            CPPFLAGS="-I${OPAL_TOP_SRCDIR}/opal/include $CPPFLAGS"
             AC_RUN_IFELSE([AC_LANG_PROGRAM([[
 #include <stdio.h>
 #include <stdlib.h>
-#include "opal_portable_platform.h"
+#include "opal/opal_portable_platform.h"
 ]],[[
     FILE * f;
     f=fopen("conftestval", "w");
     if (!f) exit(1);
     fprintf (f, "%s", _STRINGIFY(PLATFORM_COMPILER_$1));
             ]])], [
-                eval opal_cv_compiler_$1=`cat conftestval`;
+                opal_cv_compiler_$1=`cat conftestval`
             ], [
-                eval opal_cv_compiler_$1=UNKNOWN
+                opal_cv_compiler_$1=UNKNOWN
             ], [
-                eval opal_cv_compiler_$1=UNKNOWN
+                opal_cv_compiler_$1=UNKNOWN
             ])
             CPPFLAGS=$CPPFLAGS_orig
     ])
-    AC_DEFINE_UNQUOTED([OPAL_BUILD_PLATFORM_COMPILER_$1], $opal_cv_compiler_[$1],
+    AC_DEFINE_UNQUOTED([OPAL_BUILD_PLATFORM_COMPILER_$1], [$opal_cv_compiler_$1],
                        [The compiler $lower which OMPI was built with])
 ])dnl