[CUDA][HIP] Move adapter specific testing out of CTS

This patch moves the `test-adapter-cuda` and `test-adapter-hip` test
suites out of the `test/conformance` directory. The goal of this move is
to ensure that all adapters will be tested with the same set and number
of conformance tests, making conformance pass rates directly comparable
between adapters. Up to now the CUDA and HIP adapters have included
additional unit tests of internals which skews pass rates.

Author: kbenzie

.github/workflows/cmake.yml

@@ -203,6 +203,10 @@ jobs:
       run: LD_LIBRARY_PATH=${{github.workspace}}/dpcpp_compiler/lib
         cmake --build ${{github.workspace}}/build -j $(nproc)
 
+    - name: Test adapter specific
+      working-directory: ${{github.workspace}}/build
+      run: ctest -C ${{matrix.build_type}} --output-on-failure -L "adapter-specific" --timeout 180
+
     # Temporarily disabling platform test for L0, because of hang
     # See issue: #824
     - name: Test L0 adapter

source/adapters/cuda/CMakeLists.txt

@@ -3,8 +3,6 @@
 # See LICENSE.TXT
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
-set(CUDA_DIR "${CMAKE_CURRENT_SOURCE_DIR}" CACHE PATH "CUDA adapter directory")
-
 set(TARGET_NAME ur_adapter_cuda)
 
 add_ur_adapter(${TARGET_NAME}

source/adapters/hip/CMakeLists.txt

@@ -3,8 +3,6 @@
 # See LICENSE.TXT
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
-set(HIP_DIR "${CMAKE_CURRENT_SOURCE_DIR}" CACHE PATH "HIP adapter directory")
-
 set(TARGET_NAME ur_adapter_hip)
 
 # Set default UR HIP platform to AMD

test/CMakeLists.txt

@@ -16,6 +16,7 @@ enable_testing()
 
 add_subdirectory(python)
 add_subdirectory(loader)
+add_subdirectory(adapters)
 add_subdirectory(conformance)
 add_subdirectory(unified_malloc_framework)
 add_subdirectory(usm)

test/adapters/CMakeLists.txt

@@ -0,0 +1,46 @@
+# Copyright (C) 2023 Intel Corporation
+# Part of the Unified-Runtime Project, under the Apache License v2.0 with LLVM Exceptions.
+# See LICENSE.TXT
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+
+function(add_adapter_test name)
+    cmake_parse_arguments(args
+        ""                      # options
+        "FIXTURE"               # one value keywords
+        "SOURCES;ENVIRONMENT"   # multi value keywords
+        ${ARGN})
+
+    set(target test-adapter-${name})
+    add_ur_executable(${target} ${args_SOURCES}
+        ${PROJECT_SOURCE_DIR}/test/conformance/source/environment.cpp
+        ${PROJECT_SOURCE_DIR}/test/conformance/source/main.cpp
+    )
+
+    set(fixtures "PLATFORM;DEVICES;KERNELS")
+    if(NOT args_FIXTURE IN_LIST fixtures)
+        message(FATAL_ERROR
+            "FIXTURE must be one of: ${fixtures}. Found: ${args_FIXTURE}")
+    endif()
+
+    target_compile_definitions(${target} PRIVATE
+        ${args_FIXTURE}_ENVIRONMENT)
+    target_link_libraries(${target} PRIVATE
+        ${PROJECT_NAME}::loader
+        ${PROJECT_NAME}::headers
+        ${PROJECT_NAME}::testing
+        ${PROJECT_NAME}::common
+        GTest::gtest)
+
+    add_test(NAME ${target} COMMAND $<TARGET_FILE:${target}>)
+    set_tests_properties(${target} PROPERTIES
+        LABELS "adapter-specific;${name}"
+        ENVIRONMENT "${args_ENVIRONMENT}")
+endfunction()
+
+if(UR_BUILD_ADAPTER_CUDA)
+    add_subdirectory(cuda)
+endif()
+
+if(UR_BUILD_ADAPTER_HIP)
+    add_subdirectory(hip)
+endif()

test/adapters/cuda/CMakeLists.txt

@@ -0,0 +1,27 @@
+# Copyright (C) 2023 Intel Corporation
+# Part of the Unified-Runtime Project, under the Apache License v2.0 with LLVM Exceptions.
+# See LICENSE.TXT
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+
+add_adapter_test(cuda
+    FIXTURE DEVICES
+    SOURCES
+        fixtures.h
+        context_tests.cpp
+        urContextGetNativeHandle.cpp
+        urDeviceGetNativeHandle.cpp
+        urDeviceCreateWithNativeHandle.cpp
+        urEventGetNativeHandle.cpp
+        urEventCreateWithNativeHandle.cpp
+        kernel_tests.cpp
+        memory_tests.cpp
+    ENVIRONMENT
+        "UR_ADAPTERS_FORCE_LOAD=\"$<TARGET_FILE:ur_adapter_cuda>\""
+)
+
+target_include_directories(test-adapter-cuda PRIVATE
+    ${PROJECT_SOURCE_DIR}/source
+    ${PROJECT_SOURCE_DIR}/source/adapters/cuda
+)
+
+target_link_libraries(test-adapter-cuda PRIVATE cudadrv)