Set global compile flags for UR targets only

Currently, some of compile flags are set globally for the whole project
including third-party libraries.
Introduce wrapper functions for add_executable and add_library
CMake functions in order to add compile flags only where needed.

Author: PatKamin

CMakeLists.txt

@@ -52,17 +52,7 @@ if(MSVC)
     set(CUSTOM_COMMAND_BINARY_DIR ${CUSTOM_COMMAND_BINARY_DIR}/$<CONFIG>)
 endif()
 
-# CXX flags setup
 if(NOT MSVC)
-    add_compile_options(-fPIC -Wall -Wpedantic
-        $<$<CXX_COMPILER_ID:GNU>:-fdiagnostics-color=always>
-        $<$<CXX_COMPILER_ID:Clang,AppleClang>:-fcolor-diagnostics>)
-    if (CMAKE_BUILD_TYPE STREQUAL "Release")
-        add_compile_options(-D_FORTIFY_SOURCE=2)
-    endif()
-    if(UR_DEVELOPER_MODE)
-        add_compile_options(-Werror -fno-omit-frame-pointer -fstack-protector-strong)
-    endif()
     # Determine if libstdc++ is being used.
     check_cxx_source_compiles("
         #include <array>
@@ -78,14 +68,6 @@ if(NOT MSVC)
         # is available we still need to link this library.
         link_libraries(stdc++fs)
     endif()
-elseif(MSVC)
-    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
-    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP")
-    add_compile_options(/MP /W3 /MD$<$<CONFIG:Debug>:d>)
-
-    if(UR_DEVELOPER_MODE)
-        add_compile_options(/WX /GS)
-    endif()
 endif()
 
 if(UR_ENABLE_TRACING)

cmake/helpers.cmake

@@ -57,6 +57,48 @@ macro(add_sanitizer_flag flag)
     set(CMAKE_REQUIRED_LIBRARIES ${SAVED_CMAKE_REQUIRED_LIBRARIES})
 endmacro()
 
+function(add_ur_target_compile_options name)
+    if(NOT MSVC)
+        target_compile_options(${name} PRIVATE
+            -fPIC
+            -Wall
+            -Wpedantic
+            $<$<CXX_COMPILER_ID:GNU>:-fdiagnostics-color=always>
+            $<$<CXX_COMPILER_ID:Clang,AppleClang>:-fcolor-diagnostics>
+        )
+        if (CMAKE_BUILD_TYPE STREQUAL "Release")
+            target_compile_definitions(${name} PRIVATE -D_FORTIFY_SOURCE=2)
+        endif()
+        if(UR_DEVELOPER_MODE)
+            target_compile_options(${name} PRIVATE
+                -Werror
+                -fno-omit-frame-pointer
+                -fstack-protector-strong
+            )
+        endif()
+    elseif(MSVC)
+        target_compile_options(${name} PRIVATE
+            /MP
+            /W3
+            /MD$<$<CONFIG:Debug>:d>
+        )
+
+        if(UR_DEVELOPER_MODE)
+            target_compile_options(${name} PRIVATE /WX /GS)
+        endif()
+    endif()
+endfunction()
+
+function(add_ur_executable name)
+    add_executable(${name} ${ARGN})
+    add_ur_target_compile_options(${name})
+endfunction()
+
+function(add_ur_library name)
+    add_library(${name} ${ARGN})
+    add_ur_target_compile_options(${name})
+endfunction()
+
 include(FetchContent)
 
 # A wrapper around FetchContent_Declare that supports git sparse checkout.

examples/collector/CMakeLists.txt

@@ -5,7 +5,7 @@
 
 set(TARGET_NAME collector)
 
-add_library(${TARGET_NAME} SHARED
+add_ur_library(${TARGET_NAME} SHARED
     ${CMAKE_CURRENT_SOURCE_DIR}/collector.cpp
 )
 

examples/hello_world/CMakeLists.txt

@@ -5,7 +5,7 @@
 
 set(TARGET_NAME hello_world)
 
-add_executable(${TARGET_NAME}
+add_ur_executable(${TARGET_NAME}
     ${CMAKE_CURRENT_SOURCE_DIR}/hello_world.cpp
 )
 

source/adapters/null/CMakeLists.txt

@@ -5,7 +5,7 @@
 
 set(TARGET_NAME ur_adapter_null)
 
-add_library(${TARGET_NAME}
+add_ur_library(${TARGET_NAME}
     SHARED
         ${CMAKE_CURRENT_SOURCE_DIR}/ur_null.hpp
         ${CMAKE_CURRENT_SOURCE_DIR}/ur_null.cpp

source/common/umf_pools/CMakeLists.txt

@@ -3,7 +3,7 @@
 # See LICENSE.TXT
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
-add_library(disjoint_pool STATIC
+add_ur_library(disjoint_pool STATIC
     disjoint_pool.cpp
     disjoint_pool_config_parser.cpp
 )

source/common/unified_malloc_framework/CMakeLists.txt

@@ -14,11 +14,11 @@ if(UMF_BUILD_SHARED_LIBRARY)
     message(WARNING "Unified Malloc Framework is still an early work in progress."
                      "There are no API/ABI backward compatibility guarantees. There will be breakages."
                      "Do not use the shared library in production software.")
-    add_library(unified_malloc_framework SHARED
+    add_ur_library(unified_malloc_framework SHARED
         ${UMF_SOURCES})
     target_compile_definitions(unified_malloc_framework PUBLIC UMF_SHARED_LIBRARY)
 else()
-    add_library(unified_malloc_framework STATIC
+    add_ur_library(unified_malloc_framework STATIC
         ${UMF_SOURCES})
 endif()
 

source/loader/CMakeLists.txt

@@ -9,7 +9,7 @@ configure_file(
     @ONLY
 )
 
-add_library(ur_loader
+add_ur_library(ur_loader
     SHARED
     ""
     ${CMAKE_CURRENT_BINARY_DIR}/UrLoaderVersion.rc

test/conformance/CMakeLists.txt

@@ -7,7 +7,7 @@ set(UR_CONFORMANCE_TEST_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 
 function(add_conformance_test name)
     set(TEST_TARGET_NAME test-${name})
-    add_executable(${TEST_TARGET_NAME}
+    add_ur_executable(${TEST_TARGET_NAME}
         ${ARGN}
         ${UR_CONFORMANCE_TEST_DIR}/source/environment.cpp
         ${UR_CONFORMANCE_TEST_DIR}/source/main.cpp)

test/conformance/testing/CMakeLists.txt

@@ -3,7 +3,7 @@
 # See LICENSE.TXT
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
-add_library(ur_testing STATIC 
+add_ur_library(ur_testing STATIC 
     source/utils.cpp)
 target_include_directories(ur_testing PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/include)
 target_link_libraries(ur_testing PRIVATE gtest_main unified-runtime::headers)