error: attribute 'wsl' missing

[Milner39]

Bug description

Unable to use nixos-wsl.nixosModules.wsl as a module in a flake.

To Reproduce

Steps to reproduce the behavior: Use this flake:

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-24.11";

    nixos-wsl = {
      url = "github:nix-community/nixos-wsl";
      follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    nixos-wsl,
    ...
  } @ inputs: let

    # Set hostname and username
    hostname = "wsnix";
    username = "finnm";


    # Declare target architecture
    system = "x86_64-linux";

    # Import packages
    pkgs = import nixpkgs { inherit system; };

    # Additional NixOS inputs
    specialArgs = { inherit inputs hostname username; };
  
  in {
    nixosConfigurations.default = nixpkgs.lib.nixosSystem {
      inherit system pkgs specialArgs;

      modules = [
        nixos-wsl.nixosModules.wsl
        ./hosts/default/configuration.nix
      ];
    };
  };
}

Logs

When running: sudo nixos-rebuild switch --flake .#default --show-trace:

       error: attribute 'wsl' missing
       at /nix/store/38bh4pnr2kn76bbi8w2v5piri6jzv6y6-source/flake.nix:37:9:
           36|       modules = [
           37|         nixos-wsl.nixosModules.wsl
             |         ^
           38|         ./hosts/default/configuration.nix

And when using .default:

       error: attribute 'default' missing
       at /nix/store/38bh4pnr2kn76bbi8w2v5piri6jzv6y6-source/flake.nix:37:9:
           36|       modules = [
           37|         nixos-wsl.nixosModules.default
             |         ^
           38|         ./hosts/default/configuration.nix

WSL version

WSL version: 2.4.13.0
Kernel version: 5.15.167.4-1
WSLg version: 1.0.65
MSRDC version: 1.2.5716
Direct3D version: 1.611.1-81528511
DXCore version: 10.0.26100.1-240331-1435.ge-release
Windows version: 10.0.22631.5039

Extra

I'm sure this is just a problem with how I am referencing the module but the documentation for using flakes it not the clearest. I used this starter release thing to get NixOS running in wsl, then stripped out all of the extra packages and options I do not need. I can provide the configuration.nix file if needed but I do not think it is relevant given this error occurs in the flake.nix file.

[Milner39]

Just deleted the old distro and reinstalled the latest official release from this repo, same issue.

[SuperSandro2000]

Try doing nix flake update. Maybe you are on an old commit? I have almost the same code locally and it works for me.

[Milner39]

What commands am I running to do that? Just so I don't f it up. Cheers!

[Milner39]

I ran sudo nix flake update --extra-experimental-features "nix-command flakes" and tried again with sudo nixos-rebuild switch --flake .#default --show-trace and got the same errors.

[SuperSandro2000]

I don't know. The code looks correct, not sure where you're error is. Maybe ask in Matrix.

[Milner39]

What and where is matrix?

[Milner39]

Gonna keep trying, might have to manually add experimental features to the nix config.

[Milner39]

Nope, did not work. Same errors.

[nzbr]

In your inputs definition, you wrote

    nixos-wsl = {
      url = "github:nix-community/nixos-wsl";
      follows = "nixpkgs";
    };

but it should be

    nixos-wsl = {
      url = "github:nix-community/nixos-wsl";
      inputs.nixpkgs.follows = "nixpkgs";
    };

Just putting follows there means that the nixos-wsl input will point to the same files as the nixpkgs one. inputs.nixpkgs.follows overwrites the nixpkgs input of the nixos-wsl flake (and not the nixos-wsl flake itself), so that the nixos-wsl flake will use the same version of nixpkgs as your config

[Milner39]

Good spot, I'll try it out in the morning, thanks so much!

[Milner39]

YES! That was the fix, thanks!