problem with PubSub

[clifinger]

Hello guys,

Can you help me, I try to make pubSub working but I am newbie, when I create user, I never receive "user_created".
Where I need to put the handle_info please?

defmodule SignalWeb.Live.Admin.UserLive do
  use Backpex.LiveResource,
    adapter_config: [
      schema: Signal.Accounts.User,
      repo: Signal.Repo,
      update_changeset: &Signal.Accounts.User.update_changeset/3,
      create_changeset: &Signal.Accounts.User.registration_changeset/3
    ],
    layout: {SignalWeb.Layouts, :admin},
    pubsub: [
      name: Signal.PubSub,
      topic: "users",
      event_prefix: "user_"
    ]

  @impl Backpex.LiveResource
  def singular_name, do: "User"

  @impl Backpex.LiveResource
  def plural_name, do: "Users"

  @impl Backpex.LiveResource
  def fields do
    [
      email: %{
        module: Backpex.Fields.Text,
        label: "Email"
      },
      password: %{
        module: SignalWeb.Live.Admin.Fields.PasswordField,
        label: "Password",
        only: [:edit, :new]
      },
      password_confirmation: %{
        module: SignalWeb.Live.Admin.Fields.PasswordField,
        label: "Password Confirmation",
        only: [:edit, :new]
      }
    ]
  end

  @impl Phoenix.LiveView
  def handle_info(event, socket) do
    IO.inspect({"Event received", event})
    {:noreply, socket}
  end
end

Thank you

[Flo0807]

Hey, we changed a few things related to PubSub and handle_info/2 callbacks. The major change is that LiveResources are no longer real LiveViews, so you need to attach handle_info/2 callbacks via an on mount hook. Here is an example LiveResource:

defmodule DemoWeb.UserLive do
  use Backpex.LiveResource,
    adapter_config: [
      schema: Demo.User,
      repo: Demo.Repo,
      update_changeset: &Demo.User.changeset/3,
      create_changeset: &Demo.User.changeset/3,
    ],
    layout: {DemoWeb.Layouts, :admin},
    on_mount: __MODULE__,
    pubsub: [
      server: Demo.PubSub,
      topic: "users"
    ]

  def on_mount(:default, _params, _session, socket) do
    socket = Phoenix.LiveView.attach_hook(socket, :handle_info, :handle_info, &handle_info/2)

    {:cont, socket}
  end

  def handle_info(event, socket) do
    dbg(event)

    {:halt, socket}
  end

  ...
end