feat: initial commit

Author: jasonwalsh

.drone.yml

@@ -0,0 +1,19 @@
+kind: pipeline
+name: aws-networking-readonly
+steps:
+  - commands:
+      - apk add git
+      - npm install @semantic-release/changelog -D
+      - npm install @semantic-release/git -D
+      - npx semantic-release@15
+    environment:
+      GITHUB_TOKEN:
+        from_secret: github_token
+    image: node:alpine
+    name: release
+trigger:
+  branch:
+    - main
+  event:
+    - push
+type: kubernetes

.pre-commit-config.yaml

@@ -0,0 +1,5 @@
+repos:
+  - hooks:
+      - id: terraform_docs
+    repo: git://github.com/antonbabenko/pre-commit-terraform
+    rev: v1.50.0

.releaserc

@@ -0,0 +1,24 @@
+{
+  "branches": [
+    "main"
+  ],
+  "plugins": [
+    "@semantic-release/commit-analyzer",
+    "@semantic-release/github",
+    "@semantic-release/release-notes-generator",
+    [
+      "@semantic-release/changelog",
+      {
+        "changelogFile": "docs/CHANGELOG.md"
+      }
+    ],
+    [
+      "@semantic-release/git",
+      {
+        "assets": [
+          "docs/CHANGELOG.md"
+        ]
+      }
+    ]
+  ]
+}

README.md

@@ -0,0 +1,33 @@
+<!-- BEGINNING OF PRE-COMMIT-TERRAFORM DOCS HOOK -->
+## Requirements
+
+| Name | Version |
+|------|---------|
+| aws | ~> 3.64.2 |
+
+## Providers
+
+| Name | Version |
+|------|---------|
+| aws | ~> 3.64.2 |
+
+## Inputs
+
+| Name | Description | Type | Default | Required |
+|------|-------------|------|---------|:--------:|
+| availability\_zones | Select subnets only in the given AZs | `set(string)` | `[]` | no |
+| vpc\_name | The name of the VPC | `string` | n/a | yes |
+
+## Outputs
+
+| Name | Description |
+|------|-------------|
+| dns\_hostnames\_enabled | Indicates if instances launched in this VPC will have public DNS hostnames |
+| dns\_support\_enabled | Indicates if DNS support is enabled for this VPC |
+| private\_subnets | List of private subnets in this VPC |
+| public\_subnets | List of public subnets in this VPC |
+| vpc\_arn | Arn of this VPC |
+| vpc\_cidr\_block | CIDR range for this VPC |
+| vpc\_id | The ID of the VPC |
+
+<!-- END OF PRE-COMMIT-TERRAFORM DOCS HOOK -->

main.tf

@@ -0,0 +1,43 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = "~> 3.64.2"
+    }
+  }
+}
+
+data "aws_availability_zones" "this" {
+  filter {
+    name   = "zone-name"
+    values = var.availability_zones
+  }
+}
+
+data "aws_vpc" "this" {
+  filter {
+    name   = "tag:Name"
+    values = [var.vpc_name]
+  }
+
+  state = "available"
+}
+
+data "aws_subnet_ids" "this" {
+  dynamic "filter" {
+    for_each = length(data.aws_availability_zones.this.names) > 0 ? range(1) : range(0)
+
+    content {
+      name   = "availability-zone"
+      values = data.aws_availability_zones.this.names
+    }
+  }
+
+  vpc_id = data.aws_vpc.this.id
+}
+
+data "aws_subnet" "this" {
+  for_each = data.aws_subnet_ids.this.ids
+
+  id = each.value
+}

outputs.tf

@@ -0,0 +1,34 @@
+output "dns_hostnames_enabled" {
+  description = "Indicates if instances launched in this VPC will have public DNS hostnames"
+  value       = data.aws_vpc.this.enable_dns_hostnames
+}
+
+output "dns_support_enabled" {
+  description = "Indicates if DNS support is enabled for this VPC"
+  value       = data.aws_vpc.this.enable_dns_support
+}
+
+output "private_subnets" {
+  description = "List of private subnets in this VPC"
+  value       = sort([for subnet in data.aws_subnet.this : subnet.id if !subnet.map_public_ip_on_launch])
+}
+
+output "public_subnets" {
+  description = "List of public subnets in this VPC"
+  value       = sort([for subnet in data.aws_subnet.this : subnet.id if subnet.map_public_ip_on_launch])
+}
+
+output "vpc_arn" {
+  description = "Arn of this VPC"
+  value       = data.aws_vpc.this.arn
+}
+
+output "vpc_cidr_block" {
+  description = "CIDR range for this VPC"
+  value       = data.aws_vpc.this.cidr_block
+}
+
+output "vpc_id" {
+  description = "The ID of the VPC"
+  value       = data.aws_vpc.this.id
+}

variables.tf

@@ -0,0 +1,10 @@
+variable "availability_zones" {
+  default     = []
+  description = "Select subnets only in the given AZs"
+  type        = set(string)
+}
+
+variable "vpc_name" {
+  description = "The name of the VPC"
+  type        = string
+}