Extract clientgen cmake functions as well

Author: wravery

cmake/cppgraphqlgen-config.cmake

@@ -24,6 +24,8 @@ The following functions are defined to help with code generation and build targe
   update_graphql_schema_files
   add_graphql_schema_target
   add_graphql_schema_no_introspection_target
+  update_graphql_client_files
+  add_graphql_client_target
 #]=======================================================================]
 
 include(CMakeFindDependencyMacro)

cmake/cppgraphqlgen-functions.cmake

@@ -5,6 +5,10 @@ get_filename_component(GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT
   "${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-update-schema-files.cmake"
   ABSOLUTE)
 
+get_filename_component(GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT
+  "${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-update-client-files.cmake"
+  ABSOLUTE)
+
 function(update_graphql_schema_files SCHEMA_TARGET SCHEMA_GRAPHQL SCHEMA_PREFIX SCHEMA_NAMESPACE)
   set_property(DIRECTORY APPEND
     PROPERTY CMAKE_CONFIGURE_DEPENDS ${SCHEMA_TARGET}_schema_files)
@@ -55,3 +59,43 @@ function(add_graphql_schema_no_introspection_target SCHEMA_NO_INTROSPECTION_TARG
   target_include_directories(${SCHEMA_NO_INTROSPECTION_TARGET}_schema PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
   target_link_libraries(${SCHEMA_NO_INTROSPECTION_TARGET}_schema PUBLIC cppgraphqlgen::graphqlservice)
 endfunction()
+
+function(update_graphql_client_files CLIENT_TARGET SCHEMA_GRAPHQL REQUEST_GRAPHQL CLIENT_PREFIX CLIENT_NAMESPACE)
+  set_property(DIRECTORY APPEND
+    PROPERTY CMAKE_CONFIGURE_DEPENDS ${CLIENT_TARGET}_client_files)
+
+  # Collect optional arguments
+  set(ADDITIONAL_CLIENTGEN_ARGS "")
+  if(ARGC GREATER 5)
+    math(EXPR LAST_ARG "${ARGC} - 1")
+    foreach(ARGN RANGE 5 ${LAST_ARG})
+      set(NEXT_ARG "${ARGV${ARGN}}")
+      list(APPEND ADDITIONAL_CLIENTGEN_ARGS "${NEXT_ARG}")
+    endforeach()
+  endif()
+
+  add_custom_command(
+    OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files
+    COMMAND
+      ${CMAKE_COMMAND} "-DCLIENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
+      "-DCLIENT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
+      "-DCLIENTGEN_PROGRAM=$<TARGET_FILE:cppgraphqlgen::clientgen>" "-DCLIENT_TARGET=${CLIENT_TARGET}"
+      "-DSCHEMA_GRAPHQL=${SCHEMA_GRAPHQL}" "-DREQUEST_GRAPHQL=${REQUEST_GRAPHQL}"
+      "-DCLIENT_PREFIX=${CLIENT_PREFIX}" "-DCLIENT_NAMESPACE=${CLIENT_NAMESPACE}"
+      "-DADDITIONAL_CLIENTGEN_ARGS=${ADDITIONAL_CLIENTGEN_ARGS}"
+      -P ${GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT}
+    DEPENDS ${SCHEMA_GRAPHQL} ${REQUEST_GRAPHQL} ${GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT}
+    COMMENT "Generating ${CLIENT_TARGET} client"
+    VERBATIM)
+endfunction()
+
+function(add_graphql_client_target CLIENT_TARGET)
+  add_custom_target(${CLIENT_TARGET}_update_client ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files)
+
+  file(STRINGS ${CLIENT_TARGET}_client_files CLIENT_FILES)
+  add_library(${CLIENT_TARGET}_client STATIC ${CLIENT_FILES})
+  add_dependencies(${CLIENT_TARGET}_client ${CLIENT_TARGET}_update_client)
+  target_include_directories(${CLIENT_TARGET}_client PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+  target_link_libraries(${CLIENT_TARGET}_client PUBLIC cppgraphqlgen::graphqlclient)
+endfunction()

cmake/cppgraphqlgen-update-client-files.cmake

@@ -0,0 +1,58 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+# Normalize the filesystem paths
+get_filename_component(CLIENT_SOURCE_DIR ${CLIENT_SOURCE_DIR} ABSOLUTE)
+get_filename_component(CLIENT_BINARY_DIR ${CLIENT_BINARY_DIR} ABSOLUTE)
+get_filename_component(CLIENTGEN_PROGRAM ${CLIENTGEN_PROGRAM} ABSOLUTE)
+get_filename_component(SCHEMA_GRAPHQL "${CLIENT_SOURCE_DIR}/${SCHEMA_GRAPHQL}" ABSOLUTE)
+get_filename_component(REQUEST_GRAPHQL "${CLIENT_SOURCE_DIR}/${REQUEST_GRAPHQL}" ABSOLUTE)
+
+file(MAKE_DIRECTORY ${CLIENT_BINARY_DIR})
+
+# Cleanup all of the stale files in the binary directory
+file(GLOB PREVIOUS_FILES ${CLIENT_BINARY_DIR}/*.h ${CLIENT_BINARY_DIR}/*.cpp
+     ${CLIENT_BINARY_DIR}/${CLIENT_TARGET}_client_files)
+foreach(PREVIOUS_FILE ${PREVIOUS_FILES})
+  file(REMOVE ${PREVIOUS_FILE})
+endforeach()
+
+set(CLIENTGEN_ARGS "--schema=${SCHEMA_GRAPHQL}" "--request=${REQUEST_GRAPHQL}" "--prefix=${CLIENT_PREFIX}" "--namespace=${CLIENT_NAMESPACE}")
+foreach(CLIENTGEN_ARG ${ADDITIONAL_CLIENTGEN_ARGS})
+  list(APPEND CLIENTGEN_ARGS ${CLIENTGEN_ARG})
+endforeach()
+
+# Regenerate the sources in the binary directory
+execute_process(
+  COMMAND ${CLIENTGEN_PROGRAM} ${CLIENTGEN_ARGS}
+  OUTPUT_FILE ${CLIENT_TARGET}_client_files
+  WORKING_DIRECTORY ${CLIENT_BINARY_DIR})
+
+# Get the up-to-date list of files in the binary directory
+set(FILE_NAMES "")
+file(GLOB NEW_FILES ${CLIENT_BINARY_DIR}/*.h ${CLIENT_BINARY_DIR}/*.cpp)
+foreach(NEW_FILE ${NEW_FILES})
+  get_filename_component(NEW_FILE ${NEW_FILE} NAME)
+  list(APPEND FILE_NAMES "${NEW_FILE}")
+endforeach()
+
+# Don't update the files in the source directory if no files were generated in the binary directory.
+if(NOT FILE_NAMES)
+  message(FATAL_ERROR "Schema generation failed!")
+endif()
+
+# Remove stale files in the source directory
+cmake_policy(SET CMP0057 NEW)
+file(GLOB OLD_FILES ${CLIENT_SOURCE_DIR}/*.h ${CLIENT_SOURCE_DIR}/*.cpp)
+foreach(OLD_FILE ${OLD_FILES})
+  get_filename_component(OLD_FILE ${OLD_FILE} NAME)
+  if(NOT OLD_FILE IN_LIST FILE_NAMES)
+    file(REMOVE "${CLIENT_SOURCE_DIR}/${OLD_FILE}")
+  endif()
+endforeach()
+
+# Copy new and modified files from the binary directory to the source directory
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
+    ${CLIENT_BINARY_DIR}/${CLIENT_TARGET}_client_files
+    ${NEW_FILES}
+  ${CLIENT_SOURCE_DIR})

samples/CMakeLists.txt

@@ -3,110 +3,7 @@
 
 cmake_minimum_required(VERSION 3.8.2)
 
-if(GRAPHQL_UPDATE_SAMPLES AND GRAPHQL_BUILD_CLIENTGEN)
-  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/client)
-
-  # query.today.graphql
-  add_custom_command(
-    OUTPUT
-      ${CMAKE_CURRENT_BINARY_DIR}/client/QueryClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/QueryClient.h
-    COMMAND clientgen --schema="${CMAKE_CURRENT_SOURCE_DIR}/today/schema.today.graphql" --request="${CMAKE_CURRENT_SOURCE_DIR}/query.today.graphql" --prefix="Query" --namespace="query"
-    COMMAND ${CMAKE_COMMAND} -E copy_if_different
-      QueryClient.cpp
-      QueryClient.h
-      ${CMAKE_CURRENT_SOURCE_DIR}/client
-    DEPENDS clientgen today/schema.today.graphql query.today.graphql
-    WORKING_DIRECTORY client
-    COMMENT "Generating QueryClient samples")
-
-  # mutate.today.graphql
-  add_custom_command(
-    OUTPUT
-      ${CMAKE_CURRENT_BINARY_DIR}/client/MutateClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/MutateClient.h
-    COMMAND clientgen --schema="${CMAKE_CURRENT_SOURCE_DIR}/today/schema.today.graphql" --request="${CMAKE_CURRENT_SOURCE_DIR}/mutate.today.graphql" --prefix="Mutate" --namespace="mutate"
-    COMMAND ${CMAKE_COMMAND} -E copy_if_different
-      MutateClient.cpp
-      MutateClient.h
-      ${CMAKE_CURRENT_SOURCE_DIR}/client
-    DEPENDS clientgen today/schema.today.graphql mutate.today.graphql
-    WORKING_DIRECTORY client
-    COMMENT "Generating MutateClient samples")
-
-  # subscribe.today.graphql
-  add_custom_command(
-    OUTPUT
-      ${CMAKE_CURRENT_BINARY_DIR}/client/SubscribeClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/SubscribeClient.h
-    COMMAND clientgen --schema="${CMAKE_CURRENT_SOURCE_DIR}/today/schema.today.graphql" --request="${CMAKE_CURRENT_SOURCE_DIR}/subscribe.today.graphql" --prefix="Subscribe" --namespace="subscribe"
-    COMMAND ${CMAKE_COMMAND} -E copy_if_different
-      SubscribeClient.cpp
-      SubscribeClient.h
-      ${CMAKE_CURRENT_SOURCE_DIR}/client
-    DEPENDS clientgen today/schema.today.graphql subscribe.today.graphql
-    WORKING_DIRECTORY client
-    COMMENT "Generating SubscribeClient samples")
-
-  # client.benchmark.today.graphql
-  add_custom_command(
-    OUTPUT
-      ${CMAKE_CURRENT_BINARY_DIR}/client/BenchmarkClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/BenchmarkClient.h
-    COMMAND clientgen --schema="${CMAKE_CURRENT_SOURCE_DIR}/today/schema.today.graphql" --request="${CMAKE_CURRENT_SOURCE_DIR}/client.benchmark.today.graphql" --prefix="Benchmark" --namespace="benchmark"
-    COMMAND ${CMAKE_COMMAND} -E copy_if_different
-      BenchmarkClient.cpp
-      BenchmarkClient.h
-      ${CMAKE_CURRENT_SOURCE_DIR}/client
-    DEPENDS clientgen today/schema.today.graphql client.benchmark.today.graphql
-    WORKING_DIRECTORY client
-    COMMENT "Generating BenchmarkClient samples")
-
-  add_custom_target(update_client_samples ALL
-    DEPENDS
-      ${CMAKE_CURRENT_BINARY_DIR}/client/QueryClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/QueryClient.h
-      ${CMAKE_CURRENT_BINARY_DIR}/client/MutateClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/MutateClient.h
-      ${CMAKE_CURRENT_BINARY_DIR}/client/SubscribeClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/SubscribeClient.h
-      ${CMAKE_CURRENT_BINARY_DIR}/client/BenchmarkClient.cpp
-      ${CMAKE_CURRENT_BINARY_DIR}/client/BenchmarkClient.h)
-endif()
-
+add_subdirectory(client)
 add_subdirectory(learn)
 add_subdirectory(today)
 add_subdirectory(validation)
-
-# todayclient
-add_library(todayclient STATIC
-  ${CMAKE_CURRENT_SOURCE_DIR}/client/QueryClient.cpp
-  ${CMAKE_CURRENT_SOURCE_DIR}/client/MutateClient.cpp
-  ${CMAKE_CURRENT_SOURCE_DIR}/client/SubscribeClient.cpp)
-target_link_libraries(todayclient PUBLIC graphqlclient)
-target_include_directories(todayclient PUBLIC
-  ${CMAKE_CURRENT_SOURCE_DIR}/../include
-  ${CMAKE_CURRENT_SOURCE_DIR}/../PEGTL/include
-  ${CMAKE_CURRENT_SOURCE_DIR}/client)
-
-if(GRAPHQL_UPDATE_SAMPLES AND GRAPHQL_BUILD_CLIENTGEN)
-  # wait for the sample update to complete
-  add_dependencies(todayclient update_client_samples)
-endif()
-
-# client_benchmark
-add_executable(client_benchmark
-  ${CMAKE_CURRENT_SOURCE_DIR}/client/BenchmarkClient.cpp
-  client/benchmark.cpp)
-target_link_libraries(client_benchmark PRIVATE
-  separategraphql
-  todayclient
-  graphqlclient)
-target_include_directories(client_benchmark PRIVATE
-  ${CMAKE_CURRENT_SOURCE_DIR}/../include
-  ${CMAKE_CURRENT_SOURCE_DIR}/../PEGTL/include
-  ${CMAKE_CURRENT_SOURCE_DIR}/client)
-
-if(WIN32 AND BUILD_SHARED_LIBS)
-  add_dependencies(client_benchmark copy_sample_dlls)
-endif()

samples/client/CMakeLists.txt

@@ -0,0 +1,41 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+cmake_minimum_required(VERSION 3.8.2)
+
+add_subdirectory(query)
+add_subdirectory(mutate)
+add_subdirectory(subscribe)
+
+add_subdirectory(benchmark)
+
+# client_benchmark
+add_executable(client_benchmark benchmark.cpp)
+target_link_libraries(client_benchmark PRIVATE
+  separategraphql
+  benchmark_client)
+
+if(WIN32 AND BUILD_SHARED_LIBS)
+  add_custom_command(OUTPUT copied_sample_dlls
+    COMMAND ${CMAKE_COMMAND} -E copy_if_different
+      $<TARGET_FILE:graphqlservice>
+      $<TARGET_FILE:graphqlintrospection>
+      $<TARGET_FILE:graphqljson>
+      $<TARGET_FILE:graphqlpeg>
+      $<TARGET_FILE:graphqlresponse>
+      $<TARGET_FILE:graphqlclient>
+      ${CMAKE_CURRENT_BINARY_DIR}
+    COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/copied_sample_dlls
+    DEPENDS
+      graphqlservice
+      graphqlintrospection
+      graphqljson
+      graphqlpeg
+      graphqlresponse
+      graphqlclient
+    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/../src)
+
+  add_custom_target(copy_sample_dlls DEPENDS copied_sample_dlls)
+
+  add_dependencies(client_benchmark copy_sample_dlls)
+endif()

samples/client/BenchmarkClient.cpp renamed to samples/client/benchmark/BenchmarkClient.cpp

@@ -0,0 +1,12 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+cmake_minimum_required(VERSION 3.8.2)
+
+include(${CMAKE_CURRENT_SOURCE_DIR}/../../../cmake/cppgraphqlgen-functions.cmake)
+
+if(GRAPHQL_UPDATE_SAMPLES AND GRAPHQL_BUILD_CLIENTGEN)
+  update_graphql_client_files(benchmark ../../today/schema.today.graphql client.benchmark.today.graphql Benchmark benchmark)
+endif()
+
+add_graphql_client_target(benchmark)

samples/client/BenchmarkClient.h renamed to samples/client/benchmark/BenchmarkClient.h

@@ -0,0 +1 @@
+BenchmarkClient.cpp