Using an array for bundles

[mattmc3]

Typically, with antidote you'll use a ~/.zsh_plugins.txt file to generate your static plugin load file. However, you might choose to skip that and use a variable instead. To use an array to collect your bundles with antidote your .zshrc might look something like this:

# clone antidote
[[ -e ${ZDOTDIR:-~}/.antidote ]] ||
  git clone --depth=1 https://github.com/mattmc3/antidote.git ${ZDOTDIR:-~}/.antidote

# config and source antidote
zstyle ':antidote:bundle' use-friendly-names 'yes'
autoload -Uz ${ZDOTDIR:-~}/.antidote/functions/antidote

# define bundles
local -a my_bundles=(
  # prompts
  'romkatv/powerlevel10k'

  # utils
  'romkatv/zsh-bench kind:path'

  # framework
  'belak/zsh-utils path:history'
  'belak/zsh-utils path:completion'
  'belak/zsh-utils path:editor'
  'belak/zsh-utils path:utility'

  # plugins
  'rupa/z'
  'zsh-users/zsh-autosuggestions'
  'zsh-users/zsh-history-substring-search'
)

# you can also use zsh code to assemble your bundle array
if [[ $OSTYPE == darwin* ]]; then
  my_bundles+=('zshzoo/macos')
fi

# now, if your .zshrc is newer than your static file, remake it
if [[ ! ${ZDOTDIR:-~}/.zsh_plugins.zsh -nt ${ZDOTDIR:-~}/.zshrc ]]; then
  printf "%s\n" $my_bundles | antidote bundle >${ZDOTDIR:-~}/.zsh_plugins.zsh
fi

# source your 'saved' static file
source ${ZDOTDIR:-~}/.zsh_plugins.zsh