Comment on commits

[RomeoV]

In the Julia package development world, one can trigger workflows (such as new package version registration) by commenting on a commit.

The workflow is something like

• create commit that bumps the version of a package
• navigate to the commit's github interface
• add a comment referencing e.g. @ JuliaRegistrator register

There is already functionality for commenting on other github "topics" like issues, PRs, etc, but I wasn't able to find a way to comment on a new commit.

In the forge-repo, I found the forge--submit-create-post function, which seems to do the comment creation for issues.

https://github.com/magit/forge/blob/main/lisp/forge-github.el#L551-L555

I've tried to get a toy version to work with my goal:

(let ((topic "mytopic"))
    (forge--ghub-post topic "/repos/:owner/:repo/commit/0c411e12c583410243cdb567abb112096794d9d9/comments"
        `((body . "mybody"))
        :callback  (forge--post-submit-callback)
        :errorback (forge--post-submit-errorback)))

but haven't been able to make it work. Any insights are appreciated! Thanks.

[tarsius]

Here you go:

(let ((rev "92a7ffc92b2bda6b6931a0586da28f7f8ea8d1a6"))
  ;; First try formatting the resource.
  (forge--format-resource
   ;; This must be a `forge-object', "mytopic" is not.
   ;; `default-directory' must be inside the appropriate repository.
   (forge-get-repository t)
   ;; Note that it is "commits" not "commit".
   (format "/repos/:owner/:repo/commits/%s/comments" rev))
  ;; If that works, try making a request.
  (forge--ghub-post (forge-get-repository t)
    (format "/repos/:owner/:repo/commits/%s/comments" rev)
    '((body . "a comment"))
    :callback  (forge--post-submit-callback)
    :errorback (forge--post-submit-errorback)))
;; Because I ran this from *scratch* I got:
;;   error in process filter: delete-file: Wrong type argument: stringp, nil
;;   error in process filter: Wrong type argument: stringp, nil
;; But the request worked and the comment appeared on Github.

[RomeoV]

Not sure I understand -- one can already view comments on issues, no? I would expect if one fetches after running the code above, you would able to see your own comment.

[RomeoV]

Anyways, no rush though. I think this snippet does what I'm looking for at this point!

[tarsius]

I would expect if one fetches after running the code above, you would able to see your own comment.

No, that doesn't just magically implement itself. 😝

First we have to start fetching that data and store it in the database. This involves changes to the database schemata, so we have to bump the version and provide an upgrade path. It also involves changes to ghub and forge, so that has to be synchronized as well. Then we have to decide how to inject that information into the buffer that displays a commit and implement that.

[RomeoV]

Ah sorry just now realized that my in my comment above I got confused between commenting on issues (which works) and commenting on commits, which I see that there needs to be extra implementation effort.

[RomeoV]

In case someone else needs to solve my exact issue, here's a function which wraps the code above, and also gets the current revision. You can use it be e.g. navigating to a revision by pressing <return> in the log overview, and then calling the function.

(defun romeov/julia-registrator-register-current-commit ()
  "Comment on upstream commit to activate the Julia Registrator."
  (interactive)
  (require 'magit)
  (let ((rev magit-buffer-revision-hash))
    ;; First try formatting the resource.
    (forge--format-resource
    ;; This must be a `forge-object', "mytopic" is not.
    ;; `default-directory' must be inside the appropriate repository.
    (forge-get-repository t)
    ;; Note that it is "commits" not "commit".
    (format "/repos/:owner/:repo/commits/%s/comments" rev))
    ;; If that works, try making a request.
    (forge--ghub-post (forge-get-repository t)
        (format "/repos/:owner/:repo/commits/%s/comments" rev)
        '((body . "@JuliaRegistrator register"))
        :callback  (forge--post-submit-callback)
        :errorback (forge--post-submit-errorback))))
;; This yields
;;   error in process filter: Wrong type argument: arrayp, nil
;; but it's not an issue.