[vcl] Better debug

Detecting if the response is a hit usingthe x-varnish header is flaky
and notably doesn't work in a multi-tier setup.

On top of this, HIT/MISS is a false dichotomy (https://info.varnish-software.com/blog/using-obj-hits)
and while I'd like something more detailed like
https://docs.varnish-software.com/tutorials/hit-miss-logging/ (tech
version of the blog), I recognize that it's "a lot" of VCL, so this
commit only differentiates between hits, misses and passes, the latter
being pretty useful to identify while debugging.

Author: gquintard

app/code/Magento/PageCache/etc/varnish6.vcl

@@ -219,7 +219,9 @@ sub vcl_backend_response {
 }
 
 sub vcl_deliver {
-    if (resp.http.x-varnish ~ " ") {
+    if (obj.uncacheable) {
+        set resp.http.X-Magento-Cache-Debug = "UNCACHEABLE";
+    } else if (obj.hits) {
         set resp.http.X-Magento-Cache-Debug = "HIT";
         set resp.http.Grace = req.http.grace;
     } else {

dev/tests/varnish/README.md

@@ -0,0 +1,11 @@
+Files in this directory are Varnish Test Cases (VTC) and check the behavior of the VCL file shipped by `magento2`.
+
+Varnish needs to be installed, but then the test scenarios can be run individually or all at once:
+
+``` shell
+varnishtest *.vtc
+```
+
+Documentation:
+- varnishtest itself: https://varnish-cache.org/docs/trunk/reference/varnishtest.html
+- VTC syntax: https://varnish-cache.org/docs/trunk/reference/vtc.html

dev/tests/varnish/debug.vtc

@@ -0,0 +1,53 @@
+varnishtest "X-Magento-Cache-Debug header"
+
+server s1 {
+    # first request will be the probe, handle it and be on our way
+    rxreq
+    expect req.url == "/health_check.php"
+    txresp
+
+    # the probe expects the connection to close
+    close
+    accept
+
+    rxreq
+    txresp -hdr "answer-to: POST"
+
+    rxreq
+    txresp -hdr "answer-to: GET"
+} -start
+
+# generate usable VCL pointing towards s1
+# mostly, we replace the place-holders, but we also jack up the probe
+# interval to avoid further interference
+shell {
+    # testdir is automatically set to the directory containing the present vtc
+    sed ${testdir}/../../../app/code/Magento/PageCache/etc/varnish6.vcl > ${tmpdir}/output.vcl \
+        -e 's@\.interval = 5s;@.interval = 5m; .initial = 10;@' \
+        -e 's@/\* {{ host }} \*/@${s1_addr}@' \
+        -e 's@/\* {{ port }} \*/@${s1_port}@' \
+        -e 's@/\* {{ ssl_offloaded_header }} \*/@unused@' \
+        -e 's@/\* {{ grace_period }} \*/@0@'
+}
+
+varnish v1 -arg "-f" -arg "${tmpdir}/output.vcl" -start
+
+# make surethe probe request fired
+delay 1
+
+client c1 {
+    txreq -method "POST"
+    rxresp
+    expect resp.http.answer-to == "POST"
+    expect resp.http.X-Magento-Cache-Debug == "UNCACHEABLE"
+
+    txreq
+    rxresp
+    expect resp.http.answer-to == "GET"
+    expect resp.http.X-Magento-Cache-Debug == "MISS"
+
+    txreq
+    rxresp
+    expect resp.http.answer-to == "GET"
+    expect resp.http.X-Magento-Cache-Debug == "HIT"
+} -run