Watermarking / inline annotation of LLM generated content vs prompt content

[aindilis]

Hi,

I was wondering whether some feature such as the following could be implemented:

1. Inserting perhaps XML or Org-mode tags indicating the beginning and ending of LLM generated content.

E.g.

Please list all apartment finding sites.

Certainly! Here is a list of apartment sites:

craigslist.org
...

Would become

<llm-prompt>Please list all apartment finding sites.</llm-prompt>

<llm-content model="claude-3-opus">
Certainly! Here is a list of apartment sites:

craigslist.org
...
</llm-content>

2. Making such context sensitive, so it would use the appropriate tags for the mode, e.g. Org-mode, or comment them out:

(in hypothetical file: apartments.el)

;; <llm-prompt>Please list all apartment finding sites.</llm-prompt>

;; <llm-content model="claude-3-opus">
;; Certainly! Here is a list of apartment sites:
;; 
;; craigslist.org
;; ...
;; </llm-content>

Thanks!

Andrew

[karthink]

You can use gptel-prompt-prefix-alist and gptel-response-prefix-alist to add text before a response/prompt. This is intended for use in gptel chat buffers. See #103 for an example.

A more general solution is to use gptel-pre-response-hook and gptel-post-response-functions to add this stuff. Here is an example:

(defun gptel-tag-response (beg end)
  (save-excursion
    (goto-char end)
    ;; ending tag
    (insert "</llm-content>\n\n<llm-prompt>")
    (goto-char beg)
    (skip-chars-backward " \n\r\t")
    ;; end of prompt tag
    (insert "</llm-prompt>")
    (skip-chars-forward " \n\r\t")
    ;; beginning of response tag
    (insert (format "<llm-content model=\"%s\">\n"
                    gptel-model))))

(add-hook 'gptel-post-response-functions #'gptel-tag-response)

Modify as needed.

[karthink]

Closing this now, please reopen if the above solution doesn't work.

[aindilis]

Hi @karthink,

Thank you for showing me how to do this!

It works well, however, when I ran it, I had problems with it not putting text annotations in the correct spot.

However, I am reopening as well because I realized a few more desirable features:

1. watermark using enriched text text properties (and other optional/configurable methods)
2. have the option for users and/or fact-checking programs like FEVER to annotate suspected or known hallucinations, or other LLM related metadata
3. allow the text properties to store or link to other metadata/properties/parameters, such as the LLM that was used, the prompt text, temperature, etc.

If you wish I can attempt to implement this in Elisp with Claude's help.

Best,
Andrew

[karthink]

None of these are features planned for gptel, so I'm moving this to discussions.

To watermark text you can use gptel-post-response-hook, or gptel--get-buffer-bounds, which see.

[wlauppe]

Hello @karthik I liked your solution, and used it for the last months to annotate the LLM responses.

(defun gptel-add-properties-block (beg end)
  (when (and gptel-annotate (not gptel-mode))
    (save-excursion
      (goto-char beg)
      (let ((current-time (current-time)))
        (insert (format ":PROPERTIES:\nmodel: %s\ndate: %s\ntime: %s\n:END:\n"
                        gptel-model
                        (format-time-string "%Y%m%d" current-time)
                        (format-time-string "%H:%M" current-time)))))))

(add-hook 'gptel-post-response-functions #'gptel-add-properties-block)

(defvar gptel-annotate t
  "When non-nil, gptel-add-properties-block will generate output.")

(setq gptel-annotate t)

(defun gptel-toggle-annotation ()
  "Toggle the value of gptel-annotate between nil and t."
  (interactive)
  (setq gptel-annotate (not gptel-annotate))
  (message "gptel-annotate is now %s" (if gptel-annotate "enabled" "disabled")))

that is the code, which nicely puts bocks like this at the beginning of LLM responses:

:PROPERTIES:
model: DeepSeek-R1
date: 20250225
time: 10:18
:END:

But there is a race condition If you change the Model to "Model B" before the first response is finished. It adds the wrong annotation with "Model B" to the first LLM response Do you know a solution? Do you have to save the model name at the beginning of the request? But where? A buffer local variable is not a solution. I often run 2 or more requests in parallel in the same buffer. @karthink as are a seasoned emacs lisp coding wizard: Do you have an idea how to accomplish this elegantly, to get the original model name, the request was made with in the 'gptel-post-response-functions hook?

The race condition problem has become more eminent, with long running "thinking"-model responses. For me now it is much more common to have multiple requests running in parallel.

[karthink]

Try this:

(defun gptel-add-properties-block (fsm)
  (when-let* ((info (gptel-fsm-info fsm))
              (position (plist-get info :position))
              (model (map-nested-elt info '(:data :model)))
              (buffer (plist-get info :buffer))
              (current-time (current-time)))
    (when (buffer-live-p buffer)
      (with-current-buffer buffer
        (when (and gptel-mode (derived-mode-p 'org-mode))
          (save-excursion
            (goto-char position)
            (insert (format ":PROPERTIES:\nmodel: %s\ndate: %s\ntime: %s\n:END:\n"
                            model
                            (format-time-string "%Y%m%d" current-time)
                            (format-time-string "%H:%M" current-time)))))))))

(cl-pushnew 'gptel-add-properties-block
            (alist-get 'DONE gptel-send--handlers))

Untested, sorry. If you want to understand how this works you can read the block of code concerning gptel-fsm, gptel-send--handlers and gptel-request--transitions in gptel.el.

[wlauppe]

Thanks a lot! The code works. If somebody stumbles over this with the same problem here is the complete code, just like the code i posted but without the race condition, which annotates all llm resposes in normal non chat mode. You can turn it on and of with gptel-toggle-annotation.

From what i gathered in the code. every request now has a "Finite State Machine (fsm)" attached, which saves the state, the request is in, and has the context including the model name of the request. Nice that this can also be used to save this problem.

(defun gptel-add-properties-block (fsm)
  (when-let* ((info (gptel-fsm-info fsm))
              (position (plist-get info :position))
              (model (map-nested-elt info '(:data :model)))
              (buffer (plist-get info :buffer))
              (current-time (current-time)))
    (when (buffer-live-p buffer)
      (with-current-buffer buffer
        (when (and (not gptel-mode) (derived-mode-p 'org-mode) gptel-annotate)
          (save-excursion
            (goto-char position)
	    (forward-line -1)  ;; Move up one line
            (insert (format ":PROPERTIES:\nmodel: %s\ndate: %s\ntime: %s\n:END:\n"
                            model
                            (format-time-string "%Y%m%d" current-time)
                            (format-time-string "%H:%M" current-time)))))))))

(cl-pushnew 'gptel-add-properties-block
            (alist-get 'DONE gptel-send--handlers))

(defvar gptel-annotate t
  "When non-nil, gptel-add-properties-block will generate output.")

(setq gptel-annotate t)
(defun gptel-toggle-annotation ()
  "Toggle the value of gptel-annotate between nil and t."
  (interactive)
  (setq gptel-annotate (not gptel-annotate))
  (message "gptel-annotate is now %s" (if gptel-annotate "enabled" "disabled")))     

[wlauppe]

there is an update outlined in:
#759

if you want a solution, that works also for google gemini, you need the following code.

(defun gptel-add-properties-block (fsm)
  (when-let* ((info (gptel-fsm-info fsm))
              (position (plist-get info :position))
              (model (plist-get info :model)) 
              (buffer (plist-get info :buffer))
              (current-time (current-time)))
    (when (buffer-live-p buffer)
      (with-current-buffer buffer
        (when (and (not gptel-mode) (derived-mode-p 'org-mode) gptel-annotate)
          (save-excursion
            (goto-char position)
	    (forward-line -1)  ;; Move up one line
            (insert (format ":PROPERTIES:\nmodel: %s\ndate: %s\ntime: %s\n:END:\n"
                            model
                            (format-time-string "%Y%m%d" current-time)
                            (format-time-string "%H:%M" current-time)))))))))

(defun my/gptel-record-model (fsm)
  (let ((info (gptel-fsm-info fsm)))
    (plist-put info :model gptel-model)))

(cl-pushnew 'my/gptel-record-model
            (alist-get 'WAIT gptel-send--handlers))

(cl-pushnew 'gptel-add-properties-block
            (alist-get 'DONE gptel-send--handlers))

(defvar gptel-annotate t
  "When non-nil, gptel-add-properties-block will generate output.")

(setq gptel-annotate t)

(defun gptel-toggle-annotation ()
  "Toggle the value of gptel-annotate between nil and t."
  (interactive)
  (setq gptel-annotate (not gptel-annotate))
  (message "gptel-annotate is now %s" (if gptel-annotate "enabled" "disabled")))