SPI error on RAK3172 (STM32WLx)

[mikechristiansen]

Hi, not sure if this is a bug or not so I started a discussion instead.

When running the example transmit code, I get a -707 SPI error on radio.begin.
This is the serial output.
[STM32WL] Initializing ... RLB_DBG:
RadioLib Info
Version: "7.1.2.0"
Platform: "Arduino STM32 (official)"
Compiled: "Apr 2 2025" "21:09:19"
RLB_DBG: -707 at .pio/libdeps/custom_rak3172/RadioLib/src/Module.cpp:279
RLB_DBG: Found SX126x: RADIOLIB_SX126X_REG_VERSION_STRING:
RLB_DBG: 00000320: 53 58 31 32 36 31 20 54 4b 46 20 31 41 31 31 00 SX1261 TKF 1A11.
RLB_DBG:
RLB_DBG: M SX126x
RLB_DBG: -707 at .pio/libdeps/custom_rak3172/RadioLib/src/Module.cpp:279
success!
success!
[STM32WL] Transmitting packet ... RLB_DBG: Timeout in 993 ms
success!
[STM32WL] Datarate: 618.56 bps
[STM32WL] Transmitting packet ... RLB_DBG: Timeout in 993 ms
success!
[STM32WL] Datarate: 618.56 bps

Code here - Modified baud rate and switch table from here

RadioLib/examples/STM32WLx/STM32WLx_Transmit_Blocking/STM32WLx_Transmit_Blocking.ino

Line 4 in ec78500

This example transmits packets using STM32WL MCU with integrated

`/*
  RadioLib STM32WLx Blocking Transmit Example

  This example transmits packets using STM32WL MCU with integrated
  (SX126x) LoRa radio.

  Each packet contains up to 256 bytes of data, in the form of:
  - Arduino String
  - null-terminated char array (C-string)
  - arbitrary binary data (byte array)
  
  This example assumes Nucleo WL55JC1 is used. For other Nucleo boards
  or standalone STM32WL, some configuration such as TCXO voltage and
  RF switch control may have to be adjusted.

  Using blocking transmit is not recommended, as it will lead
  to inefficient use of processor time!
  Instead, interrupt transmit is recommended.

  For default module settings, see the wiki page
  https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx126x---lora-modem

  For full API reference, see the GitHub Pages
  https://jgromes.github.io/RadioLib/
*/

// include the library
#include <RadioLib.h>

// no need to configure pins, signals are routed to the radio internally
STM32WLx radio = new STM32WLx_Module();

// set RF switch configuration for Nucleo WL55JC1
// NOTE: other boards may be different!
//       Some boards may not have either LP or HP.
//       For those, do not set the LP/HP entry in the table.
static const uint32_t rfswitch_pins[] = {PB8, PC13, RADIOLIB_NC, RADIOLIB_NC, RADIOLIB_NC};
static const Module::RfSwitchMode_t rfswitch_table[] = {
  {STM32WLx::MODE_IDLE,  {LOW,  LOW}},
  {STM32WLx::MODE_RX,    {HIGH, LOW}},
  //{STM32WLx::MODE_TX_LP, {LOW,  HIGH}},
  {STM32WLx::MODE_TX_HP, {LOW,  HIGH}},
  END_OF_MODE_TABLE,
};

void setup() {
  Serial.begin(115200);

  // set RF switch control configuration
  // this has to be done prior to calling begin()
  radio.setRfSwitchTable(rfswitch_pins, rfswitch_table);

  // initialize STM32WL with default settings, except frequency
  Serial.print(F("[STM32WL] Initializing ... "));
  int state = radio.begin(868.0);
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) { delay(10); }
  }

  // set appropriate TCXO voltage for Nucleo WL55JC1
  state = radio.setTCXO(1.7);
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) { delay(10); }
  }
}

// counter to keep track of transmitted packets
int count = 0;

void loop() {
  Serial.print(F("[STM32WL] Transmitting packet ... "));

  // you can transmit C-string or Arduino string up to
  // 256 characters long
  String str = "Hello World! #" + String(count++);
  int state = radio.transmit(str);

  // you can also transmit byte array up to 256 bytes long
  /*
    byte byteArr[] = {0x01, 0x23, 0x45, 0x56, 0x78, 0xAB, 0xCD, 0xEF};
    int state = radio.transmit(byteArr, 8);
  */

  if (state == RADIOLIB_ERR_NONE) {
    // the packet was successfully transmitted
    Serial.println(F("success!"));

    // print measured data rate
    Serial.print(F("[STM32WL] Datarate:\t"));
    Serial.print(radio.getDataRate());
    Serial.println(F(" bps"));

  } else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
    // the supplied packet was longer than 256 bytes
    Serial.println(F("too long!"));

  } else if (state == RADIOLIB_ERR_TX_TIMEOUT) {
    // timeout occured while transmitting packet
    Serial.println(F("timeout!"));

  } else {
    // some other error occurred
    Serial.print(F("failed, code "));
    Serial.println(state);

  }

  // wait for a second before transmitting again
  delay(1000);
}

`

Im looking into these debugs as I get only a very weak LORA packet from my FANET weather project, initially suspecting the RF switch, then I found I have the -707 SPI error. https://github.com/mikechristiansen/WS-RAK3172l-fanet/blob/main/src/main.cpp

I have confirmed my TCXO settings, and if I change them I get several more -707 errors and the module wont start.

Appreciate any help!
Regards, Mike.

[StevenCellist]

In the code you linked, I don't see any TCXO setup. Also, it is definitely much better to include the TCXO voltage in the begin() function, which you do neither in the code here, nor in your linked code.
Also, how did you confirm that your module has a TCXO? By trial and error in code, or by looking at the markings on your module? Not that I clearly understand all the P/TP/TI differences, but there's a RAK post that tries to explain which ones have XTAL and which ones have TCXO.

[mikechristiansen]

Thanks for taking a look,
I thought this line setup the TCXO?

// set appropriate TCXO voltage for Nucleo WL55JC1
  state = radio.setTCXO(1.7);

Is there further setup required? I assumed the example code would have included it?

My module is the RAK3172 TEI, the T is for TCXO, and the I is for Ipex.
RAK3172-TE with IPEX with ±0.5ppm TCXO 900MHz

Cheers, Mike.

[StevenCellist]

Setting up the TCXO voltage in the begin() function will likely help kickstart the radio; your log already shows two -707 errors during the initialization. But I also meant that the link you shared to your own repository does not include this TCXO voltage.