Initial Commit

Author: jchv

.gitignore

@@ -0,0 +1,2 @@
+result
+

LICENSE.md

@@ -0,0 +1,26 @@
+# Unlicense
+
+This is free and unencumbered software released into the public domain.
+
+Anyone is free to copy, modify, publish, use, compile, sell, or
+distribute this software, either in source code form or as a compiled
+binary, for any purpose, commercial or non-commercial, and by any
+means.
+
+In jurisdictions that recognize copyright laws, the author or authors
+of this software dedicate any and all copyright interest in the
+software to the public domain. We make this dedication for the benefit
+of the public at large and to the detriment of our heirs and
+successors. We intend this dedication to be an overt act of
+relinquishment in perpetuity of all present and future rights to this
+software under copyright law.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
+IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY CLAIM, DAMAGES OR
+OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
+ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
+OTHER DEALINGS IN THE SOFTWARE.
+
+For more information, please refer to <http://unlicense.org/>

README.md

@@ -0,0 +1,32 @@
+# Nix flake for Binary Ninja
+This is an unofficial, experimental Nix flake for running Binary Ninja on NixOS.
+
+More testing is needed; currently only `x86-64_linux` is tested, and only a bit.
+Additionally, more variants (e.g. an FHS variant) might be desirable.
+
+## License
+
+### Binary Ninja
+
+Please note that Binary Ninja is not free software. This flake does not grant
+you a license to use Binary Ninja.
+
+When using the `binary-ninja-free` package, a copy of Binary Ninja will be
+downloaded from the Vector 35 servers. Prior to using this flake, you must
+agree to the
+[Binary Ninja Free License terms](https://docs.binary.ninja/about/license.html#free-license).
+For all other editions, you must acquire a current copy of Binary Ninja for your
+platform and add it to the Nix store, using, for example, the following command:
+
+```console
+$ nix-store --add-fixed sha256 ./binary-linux-commercial.zip
+```
+
+Of course, your usage of personal, commercial and enterprise Binary Ninja is
+governed by your respective agreements.
+
+### Nix Flake
+
+This Nix flake is in the public domain, or in jurisdictions where this is not
+recognized, is available under the terms of the Unlicense. See LICENSE.md for
+more information.

flake.lock

@@ -0,0 +1,29 @@
+{
+  description = "Flake for building Binary Ninja";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs =
+    { nixpkgs, flake-utils, ... }:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        lib = pkgs.lib;
+        sources = pkgs.callPackage ./sources.nix { };
+        editions = lib.mapAttrs' (binaryNinjaEdition: value: {
+          name = "binary-ninja-${binaryNinjaEdition}";
+          value = pkgs.callPackage ./package.nix { inherit binaryNinjaEdition; };
+        }) sources.editions;
+        packages = editions // {
+          default = editions.binary-ninja-free;
+        };
+      in
+      {
+        inherit packages;
+      }
+    );
+}

flake.nix

@@ -0,0 +1,67 @@
+{
+  stdenv,
+  callPackage,
+  autoPatchelfHook,
+  makeWrapper,
+  requireFile,
+  unzip,
+  libGL,
+  glib,
+  fontconfig,
+  xorg,
+  dbus,
+  xkeyboard_config,
+  libxkbcommon,
+  wayland-scanner,
+  kdePackages,
+
+  binaryNinjaEdition ? "personal",
+}:
+let
+  sources = callPackage ./sources.nix { };
+  platformSources = sources.editions.${binaryNinjaEdition};
+  source =
+    if builtins.hasAttr stdenv.hostPlatform.system platformSources then
+      platformSources.${stdenv.hostPlatform.system}
+    else
+      throw "No source for system ${stdenv.hostPlatform.system}";
+in
+stdenv.mkDerivation {
+  pname = "binary-ninja";
+  inherit (sources) version;
+  nativeBuildInputs = [
+    makeWrapper
+    autoPatchelfHook
+    kdePackages.wrapQtAppsHook
+  ];
+  buildInputs = [
+    unzip
+    libGL
+    glib
+    fontconfig
+    xorg.libXi
+    xorg.libXrender
+    xorg.xcbutilimage
+    xorg.xcbutilrenderutil
+    kdePackages.qtbase
+    kdePackages.qtdeclarative
+    libxkbcommon
+    dbus
+    wayland-scanner.out
+  ];
+  src = source;
+  buildPhase = ":";
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    mkdir -p $out/opt
+    cp -r * $out/opt
+    chmod +x $out/opt/binaryninja
+    makeWrapper $out/opt/binaryninja \
+          $out/bin/binaryninja \
+          --prefix "QT_XKB_CONFIG_ROOT" ":" "${xkeyboard_config}/share/X11/xkb"
+
+    runHook postInstall
+  '';
+}

hashes.js

@@ -0,0 +1,46 @@
+{
+  lib,
+  requireFile,
+  fetchurl,
+}:
+let
+  data = builtins.fromJSON (builtins.readFile ./hashes.js);
+  version = lib.head (lib.splitString " " data.version);
+  editions = [
+    "free"
+    "personal"
+    "commercial"
+    "enterprise"
+  ];
+  mkFreeSource =
+    name:
+    fetchurl {
+      url = "https://cdn.binary.ninja/installers/${name}";
+      sha256 = data.hashes.${name};
+    };
+  mkSource =
+    name:
+    requireFile {
+      inherit name;
+      url = "https://binary.ninja/recover/";
+      sha256 = data.hashes.${name};
+    };
+  mkEditionNames = edition: {
+    aarch64-darwin = "binaryninja_${edition}_macosx.dmg";
+    aarch64-linux = "binaryninja_${edition}_linux_arm.zip";
+    x86_64-darwin = "binaryninja_${edition}_macosx.dmg";
+    x86_64-linux = "binaryninja_${edition}_linux.zip";
+    x86_64-windows = "binaryninja_${edition}_win64.exe";
+  };
+in
+{
+  inherit version;
+  editions = builtins.listToAttrs (
+    map (edition: {
+      name = edition;
+      value = lib.mapAttrs (name: file: if edition == "free" then mkFreeSource file else mkSource file) (
+        mkEditionNames edition
+      );
+    }) editions
+  );
+}