Deriving Tileset Tile source_index and layer from RID

[MNchino]

Hi, I'm working with tilesets in Godotv4.0-alpha2. I have a platformer in which tilessets use the newly added "custom layer" to expose certain metadata properties.

A specific use here is that I have a tileset with wall tiles I CAN walljump on and I CANNOT walljump on. In order to differentiate one from the other, I use a custom layer called "type" with either the value "WALLJUMP" or "NO_WALLJUMP" on each tile.

Now when I collide with a tile, I need to figure out which type of tile I'm colliding with (Walljumpable or not walljumpable).
Here is a sample implementation:

func get_tile_from_body(body_id : RID, body : TileMap, body_shape : int):
#	TODO: this only uses one tile set source to identify tile.
#	Figure out a way to detect tile data from all used sources
	var source_index = 0;

#	TODO: this tileset expects everything to be on one layer
#	Figure out how to identify the layer of the colliding tile
	var tile_layer = 0;

	var tile_set_source : TileSetAtlasSource = body.tile_set.get_source(body.tile_set.get_source_id(source_index)) as TileSetAtlasSource
	var tile_coords : Vector2i = body.get_coords_for_body_rid(body_id)
	var atlas_coords : Vector2i = body.get_cell_atlas_coords(tile_layer, tile_coords, false)
	var alternative_tile : int = body.get_cell_alternative_tile(tile_layer,tile_coords,false)
	var tile_data : TileData = tile_set_source.get_tile_data(atlas_coords,alternative_tile)
	var tile_type = tile_data.get_custom_data('type')

	print("status: ", tile_type)

Here we have 2 problems:

1. If the tileset I'm colliding with has multiple image sources, we need to know which source it is beforehand
2. The layer (tile layer) of the tile I am colliding with must be known beforehand.

This is an issue if I am using a tileset with two or more image sources, which uses more than one layer.

Does anyone have any workaround with this? Or does a proposal need to be made?

[Proggle]

This is like a year later, but since this proposal is still open, I'll mention that I implemented the layer query function ( body.get_layer_for_body_rid(body_rid) ) when adding cuttable bushes, and it's now in the engine.

#6716

Here's the code I used based on that function.

func _on_body_shape_entered(body_rid, body, _body_shape_index, _local_shape_index):
	# get the coordinates of the tile we collided with
	if body.has_method("get_coords_for_body_rid"):
		var collidedTile=body.get_coords_for_body_rid(body_rid)
		var collidedLayer=body.get_layer_for_body_rid(body_rid)
		if(bushCutter): cutBushTile(body,collidedTile,collidedLayer)


func cutBushTile(body,collidedTile,collidedLayer):
	var cellSourceId=body.get_cell_source_id(collidedLayer,collidedTile,false)
	var tileData = body.get_cell_tile_data(collidedLayer,collidedTile,false)
	if tileData:
		#check if it is a bush tile
		if tileData.get_custom_data("TileType") == "BushTop":
			#there is no easy way to check the properties of a specific tile in a tileset, so we are
			#going to do a dumb hack, and *assume* that the tile located one row 
			#down in the tileset image is a bush base, and replace our bush with 
			#it, then immediately check if we are correct.  If we are correct,
			#do nothing.  If we are wrong, erase our mistake and pretend it 
			#never happened.
			
			body.set_cell(collidedLayer, collidedTile, cellSourceId, body.get_cell_atlas_coords(collidedLayer,collidedTile,false)+Vector2i.DOWN,0)
			
			#if we did it wrong, blank the tile.
			if(body.get_cell_tile_data(collidedLayer,collidedTile,false).get_custom_data("TileType") !="BushBottom"):
				body.erase_cell(collidedLayer, collidedTile)
			GlobalUtils.instantiate_scene_on_level(cutBushAnim, body.to_global(body.map_to_local(collidedTile)) )