Simplified E2asm (via E2-unknown)

[Cheatoid]

This requires E2-unknown branch in order to work.

Simplified E2asm makes running E2 code into fun experience. In terms of operation this resembles similar to how Lua C API works, by utilizing a stack and a basic set of functions/commands, you can run any E2 function at runtime.
It uses chat commands as interface and comes with 5 main commands (more commands can be added easily):
pushs: Pushes a string onto the stack.
pushn: Pushes a number onto the stack (supports hexadecimal 0x and binary 0b notations).
pop: Pops at least one value from the stack (optionally, specify an integer for different amount).
call: Invokes the function via dynamic dispatch. This command has two optional arguments for specifying amount of arguments (defaults to 0) and a return typeid (defaults to empty string, aka void).
dump: Dumps/Displays the contents of stack.

In case you are not familiar with such stack-based coding, here is an example for you to try, use chat to enter the following commands:

1. /pushs propSpawn (the function you want to call)
2. /pushs models/props_borealis/bluebarrel001.mdl (the first argument)
3. /pushn 0 (the second argument)
4. Either /call 2 or /call 2 e (pops two arguments, calling propSpawn, and either discard or save the result onto the stack)

---

@name Simplified E2asm [BetterWiremod edition]
@outputs [Args Stack]:table
@strict
if (first() | duped()) {
    Stack = table()
    function number string:parseNumber(Integer) {
        local Base = 10
        switch (This:sub(1, 2)) {
            case "0x", Base = 16 This = This:sub(3) break
            case "0b", Base = 2  This = This:sub(3) break
        }
        local Num = This:toNumber(Base)
        return Integer ? floor(Num) : Num
    }
    function array:removeEmptyStrings() {
        local I = This:count()
        while (I >= 1) {
            if (This[I, string]) {
                I--
            } else {
                This:remove(I)
            }
        }
    }
    function ccmd_pushs(Rest:string) {
        Stack:pushUnknown(unknown(Rest))
    }
    function ccmd_pushn(Rest:string) {
        Stack:pushUnknown(unknown(Rest:parseNumber(0)))
    }
    function ccmd_pop(Rest:string) {
        local Amount = 1
        if (Rest) { Amount = max(Rest:parseNumber(1), Amount) }
        while (Amount & Stack:pop()) { Amount-- }
    }
    function ccmd_dump() {
        foreach (Index:number, V:unknown = Stack) {
            print(format("Index: %d | %s", Index, V:toString()))
        }
    }
    function ccmd_call(Rest:string) {
        local Split = Rest:explode(" ")
        Split:removeEmptyStrings()
        local ArgCount = 0
        local ReturnTypeID = "" # empty string indicates void
        local SplitCount = Split:count()
        if (SplitCount >= 1) {
            ArgCount = Split[1, string]:parseNumber(1)
            if (SplitCount >= 2) {
                ReturnTypeID = Split[2, string]
            }
        }
        local StackSize = Stack:count()
        assert(StackSize > ArgCount, "Detected stack corruption (overpop prevented)")
        Args = table()
        for (I = StackSize, StackSize - ArgCount + 1, -1) {
            Args:unshiftUnknown(Stack[I])
            assert(Stack:remove(I), "Failed to pop stack element: " + I)
        }
        local FuncPtr = Stack:removeUnknown(StackSize - ArgCount)
        assert(FuncPtr:typeid() == "s", "Function identifier is not of type 'string'")
        local EIP = FuncPtr:string()
        try {
            if (ReturnTypeID) {
                Stack:pushUnknown(dynamicCall(EIP, Args, ReturnTypeID))
            } else {
                dynamicCall(EIP, Args)
            }
        } catch (EEE) {
            print("[Execution Engine Error] " + EEE)
            # Unwind stack
            Stack:pushUnknown(unknown(EIP))
            foreach (I:number, V:unknown = Args) { # Note: Do not discard I:number; it will break iterator!
                Stack:pushUnknown(V)
            }
        }
    }
    #[
    ccmd_pushs("propSpawn")
    ccmd_pushs("models/props_borealis/bluebarrel001.mdl")
    ccmd_pushn("0")
    ccmd_call("2 e")
    ccmd_dump()
    ]#
}
event chat(Ply:entity, Said:string, _) {
    if (Ply == owner()) {
        local Split = Said:trim():explode(" ")
        local Cmd = Split[1, string]
        if (Cmd[1] == "/" | Cmd[1] == "!") {
            # hideChat(1)
            Cmd = "ccmd_" + Cmd:sub(2):lower()
            try {
                Cmd(Split:concat(" ", 2):trimLeft())
            } catch (Err) {
                if (Err:sub(1, 19 + Cmd:length()) == "No such function: " + Cmd + "(") {
                    try {
                        Cmd()
                    } catch (Err2) {
                        if (Err2:sub(1, 19 + Cmd:length()) == "No such function: " + Cmd + "(") {
                            print("[ERROR] Command not found: " + Cmd)
                        } else {
                            print("[ERROR] " + Err2)
                        }
                    }
                } else {
                    # print("[ERROR] " + Err)
                }
            }
        }
    }
}

[Cheatoid]

Updated for the latest upstream changes, make sure to pull the latest version from the E2-unknown branch 😄
Most notably, make use of event chat, and also changed the inner for loop logic accordingly since there has been some kind of breaking change regarding table:remove(number) function (nowadays it seems to move entries down to fill the gap too, which is a different behavior when compared to original execution and version history; blame goes to wire).