Configuration setting for EMACS with lsp-mode

[gnikit]

Hi @ZedThree , I was wondering if you could post the part of your ~/.emacs configuration file that is responsible for configuring fortls and lsp-mode in EMACS. I am adding instructions for integrating fortls with different editors and I am having some trouble getting lsp-mode to work (I am really not an EMACS guy)

[ZedThree]

Here's the relevant bits from my .emacs config file. First bit is setting up the built-in package manager.

;; -*- mode: emacs-lisp; -*-

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Package manager stuff
(require 'package)

;; Do some basic hardening of the package system
;; See https://glyph.twistedmatrix.com/2015/11/editor-malware.html

;; Use https for packages
(setq package-archives
      '(("gnu" . "https://elpa.gnu.org/packages/")
        ("melpa" . "https://melpa.org/packages/")))

;; Always check certificates!
(setq tls-checktrust t)
;; Set trust roots
(let ((trustfile
       (replace-regexp-in-string
        "\\\\" "/"
        (replace-regexp-in-string
         "\n" ""
         (shell-command-to-string "python -m certifi")))))
  (setq tls-program
        (list
         (format "gnutls-cli%s --x509cafile %s -p %%p %%h"
                 (if (eq window-system 'w32) ".exe" "") trustfile)))
  (setq gnutls-verify-error t)
  (setq gnutls-trustfiles (list trustfile)))

;; Initialise packages now
(setq package-enable-at-startup nil)
(package-initialize)

;; Make sure we have use-package installed
(unless (package-installed-p 'use-package)
  (package-refresh-contents)
  (package-install 'use-package))

(eval-when-compile
  (require 'use-package))

;; Ensure all packages are installed
(setq use-package-always-ensure t)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Fortran

(use-package lsp-mode
  :init
  :hook
  (f90-mode . lsp)

  ;; Some of these taken from https://emacs-lsp.github.io/lsp-mode/page/performance/
  :config
  (setq read-process-output-max (* 1024 1024)
        gc-cons-threshold 100000000
        lsp-enable-xref t
        lsp-headerline-breadcrumb-enable nil)
  (define-key lsp-mode-map (kbd "C-c l") lsp-command-map)
  )

The lsp-mode docs also have some config: https://emacs-lsp.github.io/lsp-mode/tutorials/CPP-guide/#lsp-mode-configuration