Dev Update: Color DImmable light + switch implemented

Implemeted color dimmable light and color dimmer switch HA devices + examples.
Removed unnecessary stored attribute cluster
Renamed on/off light and switch examples

Author: P-R-O-C-H-Y

libraries/Zigbee/examples/Zigbee_Light_Bulb/README.md renamed to libraries/Zigbee/examples/Zigbee_Color_Dimmable_Light/README.md

@@ -0,0 +1,127 @@
+// Copyright 2024 Espressif Systems (Shanghai) PTE LTD
+//
+// Licensed under the Apache License, Version 2.0 (the "License");
+// you may not use this file except in compliance with the License.
+// You may obtain a copy of the License at
+
+//     http://www.apache.org/licenses/LICENSE-2.0
+//
+// Unless required by applicable law or agreed to in writing, software
+// distributed under the License is distributed on an "AS IS" BASIS,
+// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+// See the License for the specific language governing permissions and
+// limitations under the License.
+
+/**
+ * @brief This example demonstrates simple Zigbee light bulb.
+ *
+ * The example demonstrates how to use ESP Zigbee stack to create a end device light bulb.
+ * The light bulb is a Zigbee end device, which is controlled by a Zigbee coordinator.
+ *
+ * Proper Zigbee mode must be selected in Tools->Zigbee mode
+ * and also the correct partition scheme must be selected in Tools->Partition Scheme.
+ *
+ * Please check the README.md for instructions and more detailed description.
+ * 
+ * Created by Jan Procházka (https://github.com/P-R-O-C-H-Y/)
+ */
+
+#ifndef ZIGBEE_MODE_ED
+#error "Zigbee end device mode is not selected in Tools->Zigbee mode"
+#endif
+
+#include "Zigbee_core.h"
+#include "ep/ep_color_dimmable_light.h"
+
+#include "esp_zigbee_core.h"
+#include "freertos/FreeRTOS.h"
+#include "freertos/task.h"
+#include "ha/esp_zigbee_ha_standard.h"
+
+#define LED_PIN RGB_BUILTIN
+#define BUTTON_PIN 9  // C6/H2 Boot button
+#define ZIGBEE_LIGHT_ENDPOINT       10                                   /* esp light bulb device endpoint, used to process light controlling commands */
+
+class MyZigbeeColorLight : public ZigbeeColorDimmableLight {
+public:
+    // Constructor that passes parameters to the base class constructor
+    MyZigbeeColorLight(uint8_t endpoint) : ZigbeeColorDimmableLight(endpoint) {}
+
+    // Override the set_on_off function
+    void setOnOff(bool value) override {
+      if (value == false) {
+        neopixelWrite(LED_PIN, 0, 0, 0);  // Turn off light
+      } else {
+        updateLight(); // Turn on light on last color and level
+      }
+    }
+
+    // Override the set_level function
+    void setLevel(uint8_t level) override {
+      if (level == 0) {
+        neopixelWrite(LED_PIN, 0, 0, 0);  // Turn off light and dont update ratio
+        return;
+      }
+      _ratio = (float)level / 255;
+      updateLight();
+    }
+
+    // Override the set_color function
+    void setColor(uint8_t red, uint8_t green, uint8_t blue) override {
+      _red = red;
+      _green = green;
+      _blue = blue;
+      updateLight();
+    }
+
+    void updateLight() {
+      neopixelWrite(LED_PIN, _red * _ratio, _green * _ratio, _blue * _ratio);  // Update light
+    }
+private:
+    // Add your custom attributes and methods here
+    float _ratio = 1.0;
+    uint8_t _red = 255;
+    uint8_t _green = 255;
+    uint8_t _blue = 255;
+
+};
+
+MyZigbeeColorLight zbColorLight = MyZigbeeColorLight(ZIGBEE_LIGHT_ENDPOINT);
+
+/********************* Arduino functions **************************/
+void setup() {
+  // Init RMT and leave light OFF
+  neopixelWrite(LED_PIN, 0, 0, 0);
+
+  // Init button for factory reset
+  pinMode(BUTTON_PIN, INPUT);
+
+  //Optional: set Zigbee device name and model
+  zbColorLight.setManufacturerAndModel("Espressif", "ZBColorLightBulb");
+
+  //Add endpoint to Zigbee Core
+  log_d("Adding ZigbeeLight endpoint to Zigbee Core");
+  Zigbee.addEndpoint(&zbColorLight);
+  
+  // When all EPs are registered, start Zigbee. By default acts as ZIGBEE_END_DEVICE
+  log_d("Calling Zigbee.begin()");
+  Zigbee.begin();
+}
+
+void loop() {
+  // Cheking button for factory reset
+  if (digitalRead(BUTTON_PIN) == LOW) {  // Push button pressed
+    // Key debounce handling
+    delay(100);
+    int startTime = millis();
+    while (digitalRead(BUTTON_PIN) == LOW) {
+      delay(50);
+      if((millis() - startTime) > 3000) {
+        // If key pressed for more than 3secs, factory reset Zigbee and reboot
+        Serial.printf("Reseting Zigbee to factory settings, reboot.\n");
+        Zigbee.factoryReset();
+      }
+    }
+  }
+  delay(100);
+}

libraries/Zigbee/examples/Zigbee_Color_Dimmable_Light/Zigbee_Color_Dimmable_Light.ino

@@ -0,0 +1,149 @@
+// Copyright 2024 Espressif Systems (Shanghai) PTE LTD
+//
+// Licensed under the Apache License, Version 2.0 (the "License");
+// you may not use this file except in compliance with the License.
+// You may obtain a copy of the License at
+//
+//     http://www.apache.org/licenses/LICENSE-2.0
+//
+// Unless required by applicable law or agreed to in writing, software
+// distributed under the License is distributed on an "AS IS" BASIS,
+// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+// See the License for the specific language governing permissions and
+// limitations under the License.
+
+/**
+ * @brief This example demonstrates simple Zigbee light switch.
+ *
+ * The example demonstrates how to use ESP Zigbee stack to control a light bulb.
+ * The light bulb is a Zigbee end device, which is controlled by a Zigbee coordinator (Switch).
+ * Button switch and Zigbee runs in separate tasks.
+ *
+ * Proper Zigbee mode must be selected in Tools->Zigbee mode
+ * and also the correct partition scheme must be selected in Tools->Partition Scheme.
+ *
+ * Please check the README.md for instructions and more detailed description.
+ * 
+ * Created by Jan Procházka (https://github.com/P-R-O-C-H-Y/)
+ */
+
+#ifndef ZIGBEE_MODE_ZCZR
+#error "Zigbee coordinator mode is not selected in Tools->Zigbee mode"
+#endif
+
+#include "Zigbee_core.h"
+#include "ep/ep_color_dimmer_switch.h"
+
+#include "esp_zigbee_core.h"
+#include "freertos/FreeRTOS.h"
+#include "freertos/task.h"
+#include "ha/esp_zigbee_ha_standard.h"
+
+#define SWITCH_ENDPOINT_NUMBER 5
+
+/* Switch configuration */
+#define GPIO_SWITCH GPIO_NUM_9 //Boot button for C6/H2
+
+/* Zigbee switch */
+ZigbeeColorDimmerSwitch zbSwitch = ZigbeeColorDimmerSwitch(SWITCH_ENDPOINT_NUMBER);
+
+/********************* Arduino functions **************************/
+void setup() {
+  
+  Serial.begin(115200);
+
+  // Init button switch
+  pinMode(GPIO_SWITCH, INPUT);
+
+  //Optional: set Zigbee device name and model
+  zbSwitch.setManufacturerAndModel("Espressif", "ZigbeeSwitch");
+
+  //Optional to allow multiple light to bind to the switch
+  zbSwitch.allowMultipleBinding(true);
+
+  //Add endpoint to Zigbee Core
+  Zigbee.addEndpoint(&zbSwitch);
+
+  //Open network for 180 seconds after boot
+  Zigbee.setRebootOpenNetwork(180);
+  
+  // When all EPs are registered, start Zigbee with ZIGBEE_COORDINATOR mode
+  Zigbee.begin(ZIGBEE_COORDINATOR);
+  
+  Serial.println("Waiting for Light to bound to the switch");
+  //Wait for switch to bound to a light:
+  while(!zbSwitch.is_bound()) 
+  {
+    Serial.printf(".");
+    delay(500);
+  }
+  Serial.println();
+}
+
+void loop() {
+  // Handle button switch in loop()
+  if (digitalRead(GPIO_SWITCH) == LOW) {  // Push button pressed
+
+    // Key debounce handling
+    while (digitalRead(GPIO_SWITCH) == LOW) {
+      delay(50);
+    }
+    // Toggle light
+    zbSwitch.lightToggle();
+  }
+  // Handle serial input to controll color and level of the light
+  if (Serial.available()) {
+    String command = Serial.readString();
+
+    if (command == "on") {
+      zbSwitch.lightOn();
+    } else if (command == "off") {
+      zbSwitch.lightOff();
+    } else if (command == "toggle") {
+      zbSwitch.lightToggle();
+    } else if (command == "red") {
+      zbSwitch.setLightColor(255, 0, 0);
+    } else if (command == "green") {
+      zbSwitch.setLightColor(0, 255, 0);
+    } else if (command == "blue") {
+      zbSwitch.setLightColor(0, 0, 255);
+    } else if (command == "white") {
+      zbSwitch.setLightColor(255, 255, 255);
+    } else if (command == "color") {
+      //wait for color value
+      Serial.println("Enter red value (0-255):");
+      while (!Serial.available()) {
+        delay(100);
+      }
+      int red = Serial.parseInt();
+      Serial.println("Enter green value (0-255):");
+      while (!Serial.available()) {
+        delay(100);
+      }
+      int green = Serial.parseInt();
+      Serial.println("Enter blue value (0-255):");
+      while (!Serial.available()) {
+        delay(100);
+      }
+      int blue = Serial.parseInt();
+      zbSwitch.setLightColor(red, green, blue);
+    } else if (command == "level") {
+      //wait for level value
+      Serial.println("Enter level value (0-255):");
+      while (!Serial.available()) {
+        delay(100);
+      }
+      int level = Serial.parseInt();
+      zbSwitch.setLightLevel(level);
+    } else {
+      Serial.println("Unknown command");
+    }
+  }
+
+  // print the bound lights every 30 seconds
+  static uint32_t last_print = 0;
+  if (millis() - last_print > 30000) {
+    last_print = millis();
+    zbSwitch.printBoundLights();
+  }
+}