|
| 1 | +# - Try to find ESMF |
| 2 | +# |
| 3 | +# Uses ESMFMKFILE to find the filepath of esmf.mk. If this is NOT set, then this |
| 4 | +# module will attempt to find esmf.mk. If ESMFMKFILE exists, then |
| 5 | +# ESMF_FOUND=TRUE and all ESMF makefile variables will be set in the global |
| 6 | +# scope. Optionally, set ESMF_MKGLOBALS to a string list to filter makefile |
| 7 | +# variables. For example, to globally scope only ESMF_LIBSDIR and ESMF_APPSDIR |
| 8 | +# variables, use this CMake command in CMakeLists.txt: |
| 9 | +# |
| 10 | +# set(ESMF_MKGLOBALS "LIBSDIR" "APPSDIR") |
| 11 | + |
| 12 | +# Set ESMFMKFILE as defined by system env variable. If it's not explicitly set |
| 13 | +# try to find esmf.mk file in default locations (ESMF_ROOT, CMAKE_PREFIX_PATH, |
| 14 | +# etc) |
| 15 | +if(NOT DEFINED ESMFMKFILE) |
| 16 | + if(NOT DEFINED ENV{ESMFMKFILE}) |
| 17 | + find_path(ESMFMKFILE_PATH esmf.mk PATH_SUFFIXES lib lib64) |
| 18 | + if(ESMFMKFILE_PATH) |
| 19 | + set(ESMFMKFILE ${ESMFMKFILE_PATH}/esmf.mk) |
| 20 | + message(STATUS "Found esmf.mk file ${ESMFMKFILE}") |
| 21 | + endif() |
| 22 | + else() |
| 23 | + set(ESMFMKFILE $ENV{ESMFMKFILE}) |
| 24 | + endif() |
| 25 | +endif() |
| 26 | + |
| 27 | +# Only parse the mk file if it is found |
| 28 | +if(EXISTS ${ESMFMKFILE}) |
| 29 | + set(ESMFMKFILE ${ESMFMKFILE} CACHE FILEPATH "Path to esmf.mk file") |
| 30 | + set(ESMF_FOUND TRUE CACHE BOOL "esmf.mk file found" FORCE) |
| 31 | + |
| 32 | + # Read the mk file |
| 33 | + file(STRINGS "${ESMFMKFILE}" esmfmkfile_contents) |
| 34 | + # Parse each line in the mk file |
| 35 | + foreach(str ${esmfmkfile_contents}) |
| 36 | + # Only consider uncommented lines |
| 37 | + string(REGEX MATCH "^[^#]" def ${str}) |
| 38 | + # Line is not commented |
| 39 | + if(def) |
| 40 | + # Extract the variable name |
| 41 | + string(REGEX MATCH "^[^=]+" esmf_varname ${str}) |
| 42 | + # Extract the variable's value |
| 43 | + string(REGEX MATCH "=.+$" esmf_vardef ${str}) |
| 44 | + # Only for variables with a defined value |
| 45 | + if(esmf_vardef) |
| 46 | + # Get rid of the assignment string |
| 47 | + string(SUBSTRING ${esmf_vardef} 1 -1 esmf_vardef) |
| 48 | + # Remove whitespace |
| 49 | + string(STRIP ${esmf_vardef} esmf_vardef) |
| 50 | + # A string or single-valued list |
| 51 | + if(NOT DEFINED ESMF_MKGLOBALS) |
| 52 | + # Set in global scope |
| 53 | + set(${esmf_varname} ${esmf_vardef}) |
| 54 | + # Don't display by default in GUI |
| 55 | + mark_as_advanced(esmf_varname) |
| 56 | + else() # Need to filter global promotion |
| 57 | + foreach(m ${ESMF_MKGLOBALS}) |
| 58 | + string(FIND ${esmf_varname} ${m} match) |
| 59 | + # Found the string |
| 60 | + if(NOT ${match} EQUAL -1) |
| 61 | + # Promote to global scope |
| 62 | + set(${esmf_varname} ${esmf_vardef}) |
| 63 | + # Don't display by default in the GUI |
| 64 | + mark_as_advanced(esmf_varname) |
| 65 | + # No need to search for the current string filter |
| 66 | + break() |
| 67 | + endif() |
| 68 | + endforeach() |
| 69 | + endif() |
| 70 | + endif() |
| 71 | + endif() |
| 72 | + endforeach() |
| 73 | + |
| 74 | + # Construct ESMF_VERSION from ESMF_VERSION_STRING_GIT |
| 75 | + # ESMF_VERSION_MAJOR and ESMF_VERSION_MINOR are defined in ESMFMKFILE |
| 76 | + set(ESMF_VERSION 0) |
| 77 | + set(ESMF_VERSION_PATCH ${ESMF_VERSION_REVISION}) |
| 78 | + set(ESMF_BETA_RELEASE FALSE) |
| 79 | + if(ESMF_VERSION_BETASNAPSHOT MATCHES "^('T')$") |
| 80 | + set(ESMF_BETA_RELEASE TRUE) |
| 81 | + if(ESMF_VERSION_STRING_GIT MATCHES "^ESMF.*beta_snapshot") |
| 82 | + set(ESMF_BETA_SNAPSHOT ${ESMF_VERSION_STRING_GIT}) |
| 83 | + elseif(ESMF_VERSION_STRING_GIT MATCHES "^v.\..\..b") |
| 84 | + set(ESMF_BETA_SNAPSHOT ${ESMF_VERSION_STRING_GIT}) |
| 85 | + else() |
| 86 | + set(ESMF_BETA_SNAPSHOT 0) |
| 87 | + endif() |
| 88 | + message(STATUS "Detected ESMF Beta snapshot: ${ESMF_BETA_SNAPSHOT}") |
| 89 | + endif() |
| 90 | + set(ESMF_VERSION "${ESMF_VERSION_MAJOR}.${ESMF_VERSION_MINOR}.${ESMF_VERSION_PATCH}") |
| 91 | + |
| 92 | + # Find the ESMF library |
| 93 | + if(USE_ESMF_STATIC_LIBS) |
| 94 | + find_library(ESMF_LIBRARY_LOCATION NAMES libesmf.a PATHS ${ESMF_LIBSDIR} NO_DEFAULT_PATH) |
| 95 | + if(ESMF_LIBRARY_LOCATION MATCHES "ESMF_LIBRARY_LOCATION-NOTFOUND") |
| 96 | + message(WARNING "Static ESMF library (libesmf.a) not found in \ |
| 97 | + ${ESMF_LIBSDIR}. Try setting USE_ESMF_STATIC_LIBS=OFF") |
| 98 | + endif() |
| 99 | + if(NOT TARGET ESMF) |
| 100 | + add_library(ESMF STATIC IMPORTED) |
| 101 | + endif() |
| 102 | + else() |
| 103 | + find_library(ESMF_LIBRARY_LOCATION NAMES esmf PATHS ${ESMF_LIBSDIR} NO_DEFAULT_PATH) |
| 104 | + if(ESMF_LIBRARY_LOCATION MATCHES "ESMF_LIBRARY_LOCATION-NOTFOUND") |
| 105 | + message(WARNING "ESMF library not found in ${ESMF_LIBSDIR}.") |
| 106 | + endif() |
| 107 | + if(NOT TARGET ESMF) |
| 108 | + add_library(ESMF UNKNOWN IMPORTED) |
| 109 | + endif() |
| 110 | + endif() |
| 111 | + |
| 112 | + # Add ESMF include directories |
| 113 | + set(ESMF_INCLUDE_DIRECTORIES "") |
| 114 | + separate_arguments(_ESMF_F90COMPILEPATHS UNIX_COMMAND ${ESMF_F90COMPILEPATHS}) |
| 115 | + foreach(_ITEM ${_ESMF_F90COMPILEPATHS}) |
| 116 | + string(REGEX REPLACE "^-I" "" _ITEM "${_ITEM}") |
| 117 | + list(APPEND ESMF_INCLUDE_DIRECTORIES ${_ITEM}) |
| 118 | + endforeach() |
| 119 | + |
| 120 | + # Add ESMF link libraries |
| 121 | + string(STRIP "${ESMF_F90LINKRPATHS} ${ESMF_F90ESMFLINKRPATHS} ${ESMF_F90ESMFLINKPATHS} ${ESMF_F90LINKPATHS} ${ESMF_F90LINKLIBS} ${ESMF_F90LINKOPTS}" ESMF_INTERFACE_LINK_LIBRARIES) |
| 122 | + |
| 123 | + # Finalize find_package |
| 124 | + include(FindPackageHandleStandardArgs) |
| 125 | + |
| 126 | + find_package_handle_standard_args( |
| 127 | + ${CMAKE_FIND_PACKAGE_NAME} |
| 128 | + REQUIRED_VARS ESMF_LIBRARY_LOCATION |
| 129 | + ESMF_INTERFACE_LINK_LIBRARIES |
| 130 | + ESMF_F90COMPILEPATHS |
| 131 | + VERSION_VAR ESMF_VERSION) |
| 132 | + |
| 133 | + set_target_properties(ESMF PROPERTIES |
| 134 | + IMPORTED_LOCATION "${ESMF_LIBRARY_LOCATION}" |
| 135 | + INTERFACE_INCLUDE_DIRECTORIES "${ESMF_INCLUDE_DIRECTORIES}" |
| 136 | + INTERFACE_LINK_LIBRARIES "${ESMF_INTERFACE_LINK_LIBRARIES}") |
| 137 | + |
| 138 | +else() |
| 139 | + set(ESMF_FOUND FALSE CACHE BOOL "esmf.mk file NOT found" FORCE) |
| 140 | + message(WARNING "ESMFMKFILE ${ESMFMKFILE} not found. Try setting ESMFMKFILE \ |
| 141 | + to esmf.mk location.") |
| 142 | +endif() |
0 commit comments