Simple profile changing script

[gimmemabrewski]

I use kde and he hasn't made a plasmoid yet so I wrote a little script so I could switch through the different profiles using keyboard shortcuts. I figured I would share 😛.

#!/bin/zsh
tmp="/tmp/erupt-74832928747"
if [[ -e $tmp ]]; then source $tmp; kill -s KILL $eproc; fi
eproc=$$
typeset eproc > $tmp
profiles=("${(@f)$(eruptionctl profiles list)}")
current_profile=${${(s: :)$(eruptionctl status profile)}[3]}
slot=$(eruptionctl status slot)
for i in {1..$#profiles}; do
    if [[ ${${(s^: ^)profiles[$i]}[-1]} == $current_profile ]]; then break; fi
done
profile_index=$i
case $1 in
-up) if [[ $profile_index -eq $#profiles ]]; then profile_index=1; else profile_index=$((profile_index+1)); fi ;;
-down) if [[ $profile_index -eq 1 ]]; then profile_index=$#profiles; else profile_index=$((profile_index-1)); fi ;;
esac

eruptionctl switch profile ${${(s^: ^)profiles[$profile_index]}[-1]}
gdbus call --session \
    --dest=org.freedesktop.Notifications \
    --object-path=/org/freedesktop/Notifications \
    --method=org.freedesktop.Notifications.Notify \
    "Eruption" 68392 "input-keyboard" "Eruption Profile Changed\n" \
    "\ \n<i>Slot: </i><b>${${(s^: ^)slot}[2]}</b>\n<i>Profile:</i> ${${(s^: /^)profiles[$profile_index]}[1]}<b></b>" \
    '[]' '{"urgency": <2>}' 0
sleep 3
gdbus call --session \
    --dest=org.freedesktop.Notifications \
    --object-path=/org/freedesktop/Notifications \
    --method=org.freedesktop.Notifications.CloseNotification 68392
rm -f $tmp
exit

For those that run across this and aren't sure how to use it. Copy/paste this, save it somewhere, and make it executable. Go to your keyboard shortcut settings. Make 2 shortcuts for up and down. For the triggers I used 'ctrl+volume up/volume down' but whatever floats your boat. For the command arguments use '-up' and '-down' (ex: profile-switch -up). Make sure you use the full path to the script if you didn't save it in your $PATH or are unsure! Hopefully someone finds this handy 😄

P.S. You need zsh installed unless you want to rewrite it in bash lol

EDIT: changed ugency to 2 in gdbus so it shows up when notifications are off