Fix usage of ...trigger-for-incomplete-completions (#3815)

Ensure that the completion session is the same as the previous
incomplete completion before using trigger style
`lsp/completion-trigger-kind-trigger-for-incomplete-completions`.

Previously the internal function `lsp-completion--get-context` had no
notion of whether the current completion request was the using the
same context as the previous completion request. This internal
function is only called by `lsp-completion-at-point`.
`lsp-completion-at-point` does calculate whether this completion
request is using the same context as the last result. We therefore now
pass the information from `lsp-completion-at-point` down to
`lsp-completion--get-context` and use it therein when making a
determination about which trigger type of completion to use.

This addresses issue #3028 where completions would stop working with
the sourcekit-lsp language server for Swift. This language server in
particular sends back incomplete completions frequently and also
checks on its side to make sure any requested completion continuation
context is the same as it was when originally requested. If not it
cancels the request.

Author: crabbkw

CHANGELOG.org

@@ -56,6 +56,7 @@
     obsolete ~lsp-xml-format-quotes~.
   * Add [[https://github.com/oxalica/nil][nil]] support (additional server for Nix)
   * Add [[https://github.com/johnsoncodehk/volar/pull/1916][Volar 1.0]] support, refactor vue-language-server ~initializationOptions~, and remove multi server that is no longer needed.
+  * Ensure that incomplete completions only trigger when retriggering from the same completion session #3028
 ** Release 8.0.0
   * Add ~lsp-clients-angular-node-get-prefix-command~ to get the Angular server from another location which is still has ~/lib/node_modules~ in it.
   * Set ~lsp-clients-angular-language-server-command~ after the first connection to speed up subsequent connections.

lsp-completion.el

@@ -394,16 +394,17 @@ The MARKERS and PREFIX value will be attached to each candidate."
     (lsp:completion-item-documentation?)
     (lsp--render-element)))
 
-(defun lsp-completion--get-context (trigger-characters)
-  "Get completion context with provided TRIGGER-CHARACTERS."
+(defun lsp-completion--get-context (trigger-characters same-session?)
+  "Get completion context with provided TRIGGER-CHARACTERS and SAME-SESSION?."
   (let* ((triggered-by-char non-essential)
          (trigger-char (when triggered-by-char
                          (lsp-completion--looking-back-trigger-characterp
                           trigger-characters)))
          (trigger-kind (cond
                         (trigger-char
                          lsp/completion-trigger-kind-trigger-character)
-                        ((equal (cl-second lsp-completion--cache) :incomplete)
+                        ((and same-session?
+                              (equal (cl-second lsp-completion--cache) :incomplete))
                          lsp/completion-trigger-kind-trigger-for-incomplete-completions)
                         (t lsp/completion-trigger-kind-invoked))))
     (apply #'lsp-make-completion-context
@@ -457,7 +458,7 @@ The MARKERS and PREFIX value will be attached to each candidate."
                       (-let* ((resp (lsp-request-while-no-input
                                      "textDocument/completion"
                                      (plist-put (lsp--text-document-position-params)
-                                                :context (lsp-completion--get-context trigger-chars))))
+                                                :context (lsp-completion--get-context trigger-chars same-session?))))
                               (completed (and resp
                                               (not (and (lsp-completion-list? resp)
                                                         (lsp:completion-list-is-incomplete resp)))))

test/lsp-completion-test.el

@@ -80,11 +80,11 @@
              '("F" "daFo" "safo")
              '("F" "daFo" "safo"))))
 
-(ert-deftest lsp-completion-test-get-context ()
+(ert-deftest lsp-completion-test-get-context-trigger-characters-no-cache ()
   (setq lsp-completion--cache nil)
   (cl-labels ((do-get-context (arg)
                               (let ((non-essential arg))
-                                (lsp-completion--get-context '("_"))))
+                                (lsp-completion--get-context '("_") nil)))
               (do-test-trigger-kind (arg)
                                     (lsp:completion-context-trigger-kind
                                      (do-get-context arg)))
@@ -102,5 +102,32 @@
       (should (equal (do-test-trigger-kind t) 2))
       (should (equal (do-test-trigger-character t) "_")))))
 
+(ert-deftest lsp-completion-test-get-context-incomplete-completion ()
+  (setq lsp-completion--cache (list "not-used" :incomplete))
+  (cl-labels ((do-get-context (arg same-session?)
+                              (let ((non-essential arg))
+                                (lsp-completion--get-context '("_") same-session?)))
+              (do-test-trigger-kind (arg same-session?)
+                                    (lsp:completion-context-trigger-kind
+                                     (do-get-context arg same-session?))))
+    (mocklet ((lsp-completion--looking-back-trigger-characterp))
+      ;; When the user manually invokes completion,
+      (should (equal (do-test-trigger-kind nil nil) 1)) ;; and the session is different: expect a new completion
+      (should (equal (do-test-trigger-kind nil t) 3)) ;; and the session is the same: expect a continued completion
+
+      ;; When the user is typing a non-trigger character into the buffer,
+      (should (equal (do-test-trigger-kind t nil) 1)) ;; and the session is different: expect a new completion
+      (should (equal (do-test-trigger-kind t t) 3))) ;; and the session is the same: expect a continued completion
+
+    (mocklet ((lsp-completion--looking-back-trigger-characterp => "_"))
+      ;; When the user manually invokes completion,
+      (should (equal (do-test-trigger-kind nil nil) 1)) ;; and the session is different: expect a new completion
+      (should (equal (do-test-trigger-kind nil t) 3)) ;; and the session is the same: expect a continued completion
+
+      ;; When the user is typing a trigger-character into the buffer,
+      (should (equal (do-test-trigger-kind t nil) 2)) ;; and the session is different: expect a new trigger-character completion
+      (should (equal (do-test-trigger-kind t t) 2))) ;; and the session is the same: expect a new trigger-character completion
+    ))
+
 (provide 'lsp-completion-test)
 ;;; lsp-completion-test.el ends here