OCaml: Add implIntf (#4732)

*This is the first of a series of PR I aim to do to improve the ocaml-lsp
experience in lsp-mode*

This PR exposes `lsp-ocaml-find-alternate-file` that allows to find the file
interface corresponding to an implementation or the implementation corresponding
to an interface.

This function is quite simple for the moment since I first needed to make sure
that the LSP requests were working as expected.

Following PRs will add more possibilities

Author: mattiasdrp

clients/lsp-ocaml.el

@@ -25,6 +25,7 @@
 ;;; Code:
 
 (require 'lsp-mode)
+(require 'find-file)
 
 (defgroup lsp-ocaml nil
   "LSP support for OCaml, using ocaml-language-server."
@@ -60,10 +61,14 @@
 (define-obsolete-variable-alias 'lsp-merlin 'lsp-ocaml-lsp-server "lsp-mode 6.1")
 (define-obsolete-variable-alias 'lsp-merlin-command 'lsp-ocaml-lsp-server-command "lsp-mode 6.1")
 
+;;; -------------------
+;;; OCaml-lsp custom variables
+;;; -------------------
+
 (defcustom lsp-ocaml-lsp-server-command
   '("ocamllsp")
-  "Command to start ocaml-language-server."
-  :group 'lsp-ocaml
+  "Command to start ocaml-lsp-server."
+  :group 'lsp-ocaml-lsp-server
   :type '(choice
           (string :tag "Single string value")
           (repeat :tag "List of string values"
@@ -79,7 +84,7 @@
 
 (defcustom lsp-cut-signature 'space
   "If non-nil, signatures returned on hover will not be split on newline."
-  :group 'lsp-ocaml
+  :group 'lsp-ocaml-lsp-server
   :type '(choice (symbol :tag "Default behaviour" 'cut)
                  (symbol :tag "Display all the lines with spaces" 'space)))
 
@@ -129,6 +134,78 @@ An example of function using STORABLE is:
               ntype)))
       type)))
 
+;;; -------------------
+;;; OCaml-lsp extensions interface
+;;; -------------------
+
+;;; The following functions are used to create an interface between custom OCaml-lsp requests and lsp-mode
+
+(defun lsp-ocaml--switch-impl-intf ()
+  "Switch to the file(s) that the current file can switch to.
+
+OCaml-lsp custom protocol documented here
+https://github.com/ocaml/ocaml-lsp/blob/master/ocaml-lsp-server/docs/ocamllsp/switchImplIntf-spec.md"
+  (-if-let* ((params (lsp-make-ocaml-lsp-switch-impl-intf-params
+                      :uri (lsp--buffer-uri)))
+             (uris (lsp-request "ocamllsp/switchImplIntf" params)))
+      uris
+    (lsp--warn "Your version of ocaml-lsp doesn't support the switchImplIntf extension")))
+
+;;; -------------------
+;;; OCaml-lsp general utilities
+;;; -------------------
+
+(defun lsp-ocaml--has-one-element-p (lst)
+  "Returns t if LST contains only one element."
+  (and lst (= (length lst) 1)))
+
+;;; -------------------
+;;; OCaml-lsp URI utilities
+;;; -------------------
+
+(defun lsp-ocaml--load-uri (uri &optional other-window)
+  "Check if URI exists and open its buffer or create a new one.
+
+If OTHER-WINDOW is not nil, open the buffer in an other window."
+  (let ((path (lsp--uri-to-path uri)))
+    (cond
+
+     ;; A buffer already exists with PATH
+     ((bufferp (get-file-buffer path))
+      (ff-switch-to-buffer (get-file-buffer path) other-window)
+      path)
+
+     ;; PATH is an existing file
+     ((file-exists-p path)
+      (ff-find-file path other-window nil)
+      path)
+
+     ;; PATH is not an existing file
+     (t
+      nil))))
+
+(defun lsp-ocaml--find-alternate-uri ()
+  "Return the URI corresponding to the alternate file if there's only one or prompt for a choice."
+  (let ((uris (lsp-ocaml--switch-impl-intf)))
+    (if (lsp-ocaml--has-one-element-p uris)
+        (car uris)
+      (let* ((filenames (mapcar #'f-filename uris))
+             (selected-file (completing-read "Choose an alternate file " filenames)))
+        (nth (cl-position selected-file filenames :test #'string=) uris)))))
+
+;;; -------------------
+;;; OCaml-lsp extensions
+;;; -------------------
+
+;;; The following functions are interactive implementations of the OCaml-lsp requests
+
+(defun lsp-ocaml-find-alternate-file ()
+  "Return the URI corresponding to the alternate file if there's only one or prompt for a choice."
+  (interactive)
+  (let ((uri (lsp-ocaml--find-alternate-uri)))
+    (unless (lsp-ocaml--load-uri uri nil)
+      (message "No alternate file %s could be found for %s" (f-filename uri) (buffer-name)))))
+
 (lsp-consistency-check lsp-ocaml)
 
 (provide 'lsp-ocaml)

docs/manual-language-docs/lsp-ocaml.md

@@ -0,0 +1,13 @@
+---
+author: mattiasdrp
+template: comment.html
+root_file: docs/manual-language-docs/lsp-ocaml.md
+---
+
+## ocaml-lsp-server
+
+### Commands
+
+#### `lsp-ocaml-find-alternate-file`
+
+Find the interface corresponding to an implementation or the implementation corresponding to an interface.

lsp-protocol.el

@@ -433,6 +433,8 @@ See `-let' for a description of the destructuring mechanism."
 (lsp-interface (csharp-ls:CSharpMetadata (:textDocument))
                (csharp-ls:CSharpMetadataResponse (:source :projectName :assemblyName :symbolName)))
 
+(lsp-interface (ocaml-lsp:SwitchImplIntfParams (:uri) nil))
+
 (lsp-interface (rls:Cmd (:args :binary :env :cwd) nil))
 
 (lsp-interface (rust-analyzer:AnalyzerStatusParams (:textDocument))